[gentoo-commits] gentoo-x86 commit in gnome-extra/gnome-power-manager: gnome-power-manager-2.26.4-r1.ebuild ChangeLog

[Remi Cardona (remi)]

remi        09/10/26 16:06:59

  Modified:             ChangeLog
  Added:                gnome-power-manager-2.26.4-r1.ebuild
  Log:
  gnome-extra/gnome-power-manager: backport patches from upstream, add randr patch
  (Portage version: 2.2_rc46/cvs/Linux i686)

Revision  Changes    Path
1.110                gnome-extra/gnome-power-manager/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/gnome-extra/gnome-power-manager/ChangeLog?rev=1.110&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/gnome-extra/gnome-power-manager/ChangeLog?rev=1.110&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/gnome-extra/gnome-power-manager/ChangeLog?r1=1.109&r2=1.110

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/gnome-extra/gnome-power-manager/ChangeLog,v
retrieving revision 1.109
retrieving revision 1.110
diff -u -r1.109 -r1.110
--- ChangeLog	28 Sep 2009 19:37:52 -0000	1.109
+++ ChangeLog	26 Oct 2009 16:06:59 -0000	1.110
@@ -1,6 +1,19 @@
 # ChangeLog for gnome-extra/gnome-power-manager
 # Copyright 1999-2009 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/gnome-extra/gnome-power-manager/ChangeLog,v 1.109 2009/09/28 19:37:52 eva Exp $
+# $Header: /var/cvsroot/gentoo-x86/gnome-extra/gnome-power-manager/ChangeLog,v 1.110 2009/10/26 16:06:59 remi Exp $
+
+*gnome-power-manager-2.26.4-r1 (26 Oct 2009)
+
+  26 Oct 2009; Rémi Cardona <remi@g.o>
+  -files/gnome-power-manager-2.26.1-fix-xrandr-1.3-detection.patch,
+  +gnome-power-manager-2.26.4-r1.ebuild,
+  +files/gnome-power-manager-2.26.4-Check-for-XRR-functions-using-library-ve
+  rsion-instea.patch,
+  +files/gnome-power-manager-2.26.4-Remove-an-unused-include-to-fix-compile.
+  patch,
+  +files/gnome-power-manager-2.26.4-Use-a-larger-DPMS-idletime-timeout-to-mi
+  tigate-an-XS.patch:
+  backport patches from upstream, add randr patch
 
   28 Sep 2009; Gilles Dartiguelongue <eva@g.o>
   gnome-power-manager-2.24.4-r2.ebuild, gnome-power-manager-2.26.4.ebuild:



1.1                  gnome-extra/gnome-power-manager/gnome-power-manager-2.26.4-r1.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/gnome-extra/gnome-power-manager/gnome-power-manager-2.26.4-r1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/gnome-extra/gnome-power-manager/gnome-power-manager-2.26.4-r1.ebuild?rev=1.1&content-type=text/plain

Index: gnome-power-manager-2.26.4-r1.ebuild
===================================================================
# Copyright 1999-2009 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/gnome-extra/gnome-power-manager/gnome-power-manager-2.26.4-r1.ebuild,v 1.1 2009/10/26 16:06:59 remi Exp $

EAPI="2"

inherit autotools eutils gnome2 virtualx

DESCRIPTION="Gnome Power Manager"
HOMEPAGE="http://www.gnome.org/projects/gnome-power-manager/"
SRC_URI="${SRC_URI}
	mirror://gentoo/${P}-cpufreq-patches.tar.bz2"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="doc policykit test"

# See bug #196490 & bug #575500
#RESTRICT="test"

RDEPEND=">=dev-libs/glib-2.6.0
	>=x11-libs/gtk+-2.11.0
	>=gnome-base/gnome-keyring-0.6.0
	>=sys-apps/hal-0.5.9
	>=dev-libs/dbus-glib-0.71
	>=gnome-base/libglade-2.5.0
	>=x11-libs/libnotify-0.4.3
	>=x11-libs/libwnck-2.10.0
	>=x11-libs/cairo-1.0.0
	>=gnome-base/gnome-panel-2
	>=gnome-base/gconf-2.10
	>=media-libs/libcanberra-0.10[gtk]
	>=sys-apps/devicekit-001
	>=sys-apps/devicekit-power-005
	>=dev-libs/libunique-1

	>=x11-apps/xrandr-1.2
	x11-libs/libX11
	x11-libs/libXext

	policykit? (
		>=sys-auth/policykit-0.8
		>=sys-apps/hal-0.5.12_rc1-r2[policykit]
		>=gnome-extra/policykit-gnome-0.8 )"
DEPEND="${RDEPEND}
	sys-devel/gettext
	app-text/scrollkeeper
	app-text/docbook-xml-dtd:4.3
	>=dev-util/pkgconfig-0.9
	>=dev-util/intltool-0.35
	>=app-text/gnome-doc-utils-0.3.2
	doc? (
		app-text/xmlto
		app-text/docbook-sgml-utils
		app-text/docbook-xml-dtd:4.4
		app-text/docbook-sgml-dtd:4.1
		app-text/docbook-xml-dtd:4.1.2 )"

# docbook-sgml-utils and docbook-sgml-dtd-4.1 used for creating man pages
# (files under ${S}/man).
# docbook-xml-dtd-4.4 and -4.1.2 are used by the xml files under ${S}/docs.

DOCS="AUTHORS ChangeLog NEWS README TODO"

pkg_setup() {
	G2CONF="${G2CONF}
		$(use_enable test tests)
		$(use_enable doc docbook-docs)
		$(use_enable policykit)
		$(use_enable policykit gconf-defaults)
		--enable-compile-warnings=minimum
		--with-dpms-ext
		--enable-legacy-buttons
		--enable-applets"
}

src_prepare() {
	gnome2_src_prepare

	# Drop debugger CFLAGS
	sed -e 's:^CPPFLAGS="$CPPFLAGS -g"$::g' -i configure.ac \
		|| die "sed 2 failed"

	# Drop test that needs a running daemon
	sed 's:^\(.*gpm_inhibit_test (test);\)://\1:' -i src/gpm-self-test.c \
		|| die "sed 3 failed"

	# Skip crazy compilation warnings, bug #263078
	epatch "${FILESDIR}/${PN}-2.26.0-gcc44-options.patch"

	# Backport patches from upstream, add patch to stop using RANDR_MAJOR/MINOR
	epatch "${FILESDIR}/${PN}-2.26.4-Use-a-larger-DPMS-idletime-timeout-to-mitigate-an-XS.patch"
	epatch "${FILESDIR}/${PN}-2.26.4-Remove-an-unused-include-to-fix-compile.patch"
	epatch "${FILESDIR}/${PN}-2.26.4-Check-for-XRR-functions-using-library-version-instea.patch"

	# Resurrect cpufreq in capplet, bug #263891
	epatch "${WORKDIR}/${PN}-2.26.0-cpufreq-libhal-glib.patch"
	epatch "${WORKDIR}/${PN}-2.26.0-cpufreq-support.patch"
	epatch "${WORKDIR}/${PN}-2.26.0-cpufreq-ui.patch"
	epatch "${WORKDIR}/${PN}-2.26.3-cpufreq-po.patch"

	# Fix uninstalled cpufreq schemas, bug #266995
	epatch "${WORKDIR}/${PN}-2.26.0-cpufreq-schemas.patch"

	intltoolize --force --copy --automake || die "intltoolize failed"

	# Make it libtool-1 compatible
	rm -v m4/lt* m4/libtool.m4 || die "removing libtool macros failed"
	eautoreconf

	if ! use doc; then
		# Remove the docbook2man rules here since it's not handled by a proper
		# parameter in configure.in.
		sed -e 's:@HAVE_DOCBOOK2MAN_TRUE@.*::' \
			-i "${S}/man/Makefile.in" || die "sed 1 failed"
	fi

	# glibc splits this out, whereas other libc's do not tend to
	use elibc_glibc || sed -e 's/-lresolv//' -i configure || die "sed 4 failed"
}

src_test() {
	unset DBUS_SESSION_BUS_ADDRESS
	Xemake check || die "Test phase failed"
}

pkg_postinst() {
	gnome2_pkg_postinst
	elog
	elog "To enable frequency scaling interface, use the following command:"
	elog "	gconftool-2 /apps/gnome-power-manager/ui/cpufreq_show"
	elog "Note that this will conflict with other power managment utility"
	elog "like app-laptop/laptop-mode-tools."
	elog
}