[gentoo-commits] gentoo-x86 commit in net-misc/nx: ChangeLog nx-3.5.0.24.ebuild

[Bernard Cafarelli (voyageur)]

voyageur    14/05/21 06:48:53

  Modified:             ChangeLog
  Added:                nx-3.5.0.24.ebuild
  Log:
  Version bump
  
  (Portage version: 2.2.10/cvs/Linux x86_64, signed Manifest commit with key C74525F2)

Revision  Changes    Path
1.85                 net-misc/nx/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/nx/ChangeLog?rev=1.85&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/nx/ChangeLog?rev=1.85&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/nx/ChangeLog?r1=1.84&r2=1.85

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-misc/nx/ChangeLog,v
retrieving revision 1.84
retrieving revision 1.85
diff -u -r1.84 -r1.85
--- ChangeLog	6 Jan 2014 12:36:47 -0000	1.84
+++ ChangeLog	21 May 2014 06:48:53 -0000	1.85
@@ -1,6 +1,11 @@
 # ChangeLog for net-misc/nx
 # Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-misc/nx/ChangeLog,v 1.84 2014/01/06 12:36:47 voyageur Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-misc/nx/ChangeLog,v 1.85 2014/05/21 06:48:53 voyageur Exp $
+
+*nx-3.5.0.24 (21 May 2014)
+
+  21 May 2014; Bernard Cafarelli <voyageur@g.o> +nx-3.5.0.24.ebuild:
+  Version bump
 
 *nx-3.5.0.22 (06 Jan 2014)
 



1.1                  net-misc/nx/nx-3.5.0.24.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/nx/nx-3.5.0.24.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/nx/nx-3.5.0.24.ebuild?rev=1.1&content-type=text/plain

Index: nx-3.5.0.24.ebuild
===================================================================
# Copyright 1999-2014 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-misc/nx/nx-3.5.0.24.ebuild,v 1.1 2014/05/21 06:48:53 voyageur Exp $

EAPI=5
inherit autotools eutils multilib readme.gentoo

DESCRIPTION="NX compression technology core libraries"
HOMEPAGE="http://www.nomachine.com/developers.php
	http://www.x2go.org/doku.php/wiki:libs:nx-libs"

SRC_URI="http://code.x2go.org/releases/source/nx-libs/nx-libs-${PV}-full.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~ppc ~x86"
IUSE="elibc_glibc"

RDEPEND="elibc_glibc? ( || ( net-libs/libtirpc <sys-libs/glibc-2.14 ) )
	media-libs/freetype:2
	>=media-libs/libpng-1.2.8
	>=sys-libs/zlib-1.2.3
	virtual/jpeg"

DEPEND="${RDEPEND}
		x11-misc/gccmakedep
		x11-misc/imake
		x11-proto/inputproto"

S=${WORKDIR}/nx-libs-${PV}

DOC_CONTENTS="If you get problems with rendering gtk+ apps, enable the xlib-xcb
useflag on x11-libs/cairo."

src_prepare() {
	# For nxcl/qtnx
	cd "${S}"/nxproxy
	epatch "${FILESDIR}"/${PN}-3.2.0-nxproxy_read_from_stdin.patch

	cd "${S}"
	# -fPIC
	epatch "${FILESDIR}"/1.5.0/nxcomp-1.5.0-pic.patch
	# Drop force -O3, set AR/RANLIB and
	# run autoreconf in all neeed folders
	epatch "${FILESDIR}"/${PN}-3.5.0.17-cflags_ar_ranlib.patch
	for i in nxcomp nxcompext nxcompshad nxproxy; do
		cd "${S}"/${i}
		eautoreconf ${i}
		cd "${S}"
	done

	# From xorg-x11-6.9.0-r3.ebuild
	cd "${S}/nx-X11"
	HOSTCONF="config/cf/host.def"
	echo "#define CcCmd $(tc-getCC)" >> ${HOSTCONF}
	echo "#define OptimizedCDebugFlags ${CFLAGS} GccAliasingArgs" >> ${HOSTCONF}
	echo "#define OptimizedCplusplusDebugFlags ${CXXFLAGS} GccAliasingArgs" >> ${HOSTCONF}
	# Respect LDFLAGS
	echo "#define ExtraLoadFlags ${LDFLAGS}" >> ${HOSTCONF}
	echo "#define SharedLibraryLoadFlags -shared ${LDFLAGS}" >> ${HOSTCONF}
}

src_configure() {
	cd "${S}"/nxproxy
	econf
}

src_compile() {
	cd "${S}/nx-X11"
	FAST=1 emake World WORLDOPTS="" MAKE="make" \
		AR="$(tc-getAR) clq" RANLIB="$(tc-getRANLIB)" \
		CC="$(tc-getCC)" CXX="$(tc-getCXX)"

	cd "${S}"/nxproxy
	emake
}

src_install() {
	NX_ROOT=/usr/$(get_libdir)/NX

	for x in nxagent nxauth nxproxy; do
		make_wrapper $x ./$x ${NX_ROOT}/bin ${NX_ROOT}/$(get_libdir) ||
			die " $x wrapper creation failed"
	done

	into ${NX_ROOT}
	dobin "${S}"/nx-X11/programs/Xserver/nxagent
	dobin "${S}"/nx-X11/programs/nxauth/nxauth
	dobin "${S}"/nxproxy/nxproxy

	for lib in X11 Xau Xcomposite Xdamage Xdmcp Xext Xfixes Xinerama Xpm Xrandr Xrender Xtst;
	do
		dolib.so "${S}"/nx-X11/lib/${lib}/libNX_${lib}.so*
	done

	dolib.so "${S}"/nxcomp/libXcomp.so*
	dolib.so "${S}"/nxcompext/libXcompext.so*
	dolib.so "${S}"/nxcompshad/libXcompshad.so*

	insinto /etc/nxagent
	newins etc/keystrokes.cfg keystroke.cfg
	doicon nx-X11/programs/Xserver/hw/nxagent/x2go.xpm

	readme.gentoo_create_doc
}