[gentoo-commits] gentoo-x86 commit in kde-base/cantor: ChangeLog cantor-4.10.5.ebuild

[Johannes Huber (johu)]

johu        13/07/02 16:48:17

  Modified:             ChangeLog
  Added:                cantor-4.10.5.ebuild
  Log:
  Version bump KDE SC 4.10.5
  
  (Portage version: 2.2.0_alpha186/cvs/Linux x86_64, signed Manifest commit with key F3CFD2BD)

Revision  Changes    Path
1.128                kde-base/cantor/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/kde-base/cantor/ChangeLog?rev=1.128&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/kde-base/cantor/ChangeLog?rev=1.128&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/kde-base/cantor/ChangeLog?r1=1.127&r2=1.128

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/kde-base/cantor/ChangeLog,v
retrieving revision 1.127
retrieving revision 1.128
diff -u -r1.127 -r1.128
--- ChangeLog	2 Jul 2013 09:29:25 -0000	1.127
+++ ChangeLog	2 Jul 2013 16:48:16 -0000	1.128
@@ -1,6 +1,11 @@
 # ChangeLog for kde-base/cantor
 # Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/kde-base/cantor/ChangeLog,v 1.127 2013/07/02 09:29:25 ago Exp $
+# $Header: /var/cvsroot/gentoo-x86/kde-base/cantor/ChangeLog,v 1.128 2013/07/02 16:48:16 johu Exp $
+
+*cantor-4.10.5 (02 Jul 2013)
+
+  02 Jul 2013; Johannes Huber <johu@g.o> +cantor-4.10.5.ebuild:
+  Version bump KDE SC 4.10.5
 
   02 Jul 2013; Agostino Sarubbo <ago@g.o> -cantor-4.10.3.ebuild:
   Remove old



1.1                  kde-base/cantor/cantor-4.10.5.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/kde-base/cantor/cantor-4.10.5.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/kde-base/cantor/cantor-4.10.5.ebuild?rev=1.1&content-type=text/plain

Index: cantor-4.10.5.ebuild
===================================================================
# Copyright 1999-2013 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/kde-base/cantor/cantor-4.10.5.ebuild,v 1.1 2013/07/02 16:48:16 johu Exp $

EAPI=5

KDE_HANDBOOK="optional"
inherit kde4-base

DESCRIPTION="KDE4 interface for doing mathematics and scientific computing"
KEYWORDS=" ~amd64 ~arm ~ppc ~ppc64 ~x86 ~amd64-linux ~x86-linux"
IUSE="analitza debug postscript qalculate +R"

# TODO Add Sage Mathematics Software backend (http://www.sagemath.org)
RDEPEND="
	analitza? ( $(add_kdebase_dep analitza) )
	qalculate? (
		sci-libs/cln
		sci-libs/libqalculate
	)
	postscript? ( app-text/libspectre )
	R? ( dev-lang/R )
	dev-qt/qtxmlpatterns:4
"
DEPEND="${RDEPEND}
	>=dev-cpp/eigen-2.0.3:2
"

RESTRICT="test"

src_configure() {
	mycmakeargs=(
		$(cmake-utils_use_with analitza)
		$(cmake-utils_use_with postscript LibSpectre)
		$(cmake-utils_use_with qalculate)
		$(cmake-utils_use_with R)
	)
	kde4-base_src_configure
}

pkg_postinst() {
	kde4-base_pkg_postinst

	if ! use analitza && ! use qalculate && ! use R; then
		echo
		ewarn "You have decided to build ${PN} with no backend."
		ewarn "To have this application functional, please do one of below:"
		ewarn "    # emerge -va1 '='${CATEGORY}/${P} with 'analitza', 'qalculate' or 'R' USE flag enabled"
		ewarn "    # emerge -vaDu sci-mathematics/maxima"
		echo
	fi
}