[gentoo-commits] gentoo-x86 commit in app-shells/autojump: autojump-21.1.0.ebuild ChangeLog

[Michael Weber (xmw)]

xmw         12/11/24 11:10:09

  Modified:             ChangeLog
  Added:                autojump-21.1.0.ebuild
  Log:
  Version bump
  
  (Portage version: 2.2.0_alpha142/cvs/Linux x86_64, signed Manifest commit with key 62EEF090)

Revision  Changes    Path
1.6                  app-shells/autojump/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-shells/autojump/ChangeLog?rev=1.6&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-shells/autojump/ChangeLog?rev=1.6&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-shells/autojump/ChangeLog?r1=1.5&r2=1.6

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/app-shells/autojump/ChangeLog,v
retrieving revision 1.5
retrieving revision 1.6
diff -u -r1.5 -r1.6
--- ChangeLog	27 Jun 2012 17:39:56 -0000	1.5
+++ ChangeLog	24 Nov 2012 11:10:09 -0000	1.6
@@ -1,6 +1,11 @@
 # ChangeLog for app-shells/autojump
 # Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-shells/autojump/ChangeLog,v 1.5 2012/06/27 17:39:56 xarthisius Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-shells/autojump/ChangeLog,v 1.6 2012/11/24 11:10:09 xmw Exp $
+
+*autojump-21.1.0 (24 Nov 2012)
+
+  24 Nov 2012; Michael Weber <xmw@g.o> +autojump-21.1.0.ebuild:
+  Version bump
 
   27 Jun 2012; Kacper Kowalik <xarthisius@g.o> autojump-20.9.ebuild:
   Fix PYTHON invocation



1.1                  app-shells/autojump/autojump-21.1.0.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-shells/autojump/autojump-21.1.0.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-shells/autojump/autojump-21.1.0.ebuild?rev=1.1&content-type=text/plain

Index: autojump-21.1.0.ebuild
===================================================================
# Copyright 1999-2012 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/app-shells/autojump/autojump-21.1.0.ebuild,v 1.1 2012/11/24 11:10:09 xmw Exp $

EAPI=4

PYTHON_DEPEND="python? *"
SUPPORT_PYTHON_ABIS="1"

inherit python vcs-snapshot

DESCRIPTION="change directory command that learns"
HOMEPAGE="http://github.com/joelthelion/autojump"
SRC_URI="https://github.com/joelthelion/${PN}/archive/release-v${PV}.tar.gz -> ${P}.tar.gz"

LICENSE="GPL-3"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="bash-completion gtk python test zsh-completion"

RDEPEND="gtk? ( dev-python/pygtk:2 )
	bash-completion? ( >=app-shells/bash-4 )
	zsh-completion? ( app-shells/zsh app-shells/zsh-completion )"
DEPEND="test? ( dev-lang/python )"

src_prepare() {
	#https://github.com/joelthelion/autojump/issues/129
	sed -e '/def test_db_load_migrate/,/autojump.CONFIG_DIR = ORIG_CONFIG_DIR/d' \
		-i tests/runtests.py || die
}

src_test() {
	#https://github.com/joelthelion/autojump/issues/130
	mkdir -p "${HOME}"/.local/share/autojump || die

	"$(PYTHON)" ./tests/runtests.py
}

src_compile() { :; }

src_install() {
	dobin bin/autojump

	if use gtk ; then
		dobin bin/jumpapplet
		insinto /usr/share/${PN}
		doins bin/icon.png
	fi

	insinto /etc/profile.d
	doins bin/${PN}.sh

	if use bash-completion ; then
		doins bin/${PN}.bash
	fi

	if use zsh-completion ; then
		doins bin/${PN}.zsh
		insinto /usr/share/zsh/site-functions
		doins bin/_j
	fi

	if use python ; then
		install_python() {
			insinto "$(python_get_sitedir)"
			doins tools/autojump_ipython.py
		}
		python_execute_function -q install_python

		einfo "This tool provides \"j\" for ipython, please add"
		einfo "\"imporrt autojump_ipython\" to your ipy_user_conf.py."
	fi

	doman docs/${PN}.1
	dodoc README.md
}