[gentoo-commits] repo/gentoo:master commit in: app-text/ansifilter/

[Michael Palimaka]

commit:     bfebc14dbad98a949658715d40321f4882b729ba
Author:     Michael Palimaka <kensington <AT> gentoo <DOT> org>
AuthorDate: Mon Feb  8 09:28:30 2021 +0000
Commit:     Michael Palimaka <kensington <AT> gentoo <DOT> org>
CommitDate: Mon Feb  8 09:28:58 2021 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=bfebc14d

app-text/ansifilter: version bump 2.18

Package-Manager: Portage-3.0.13, Repoman-3.0.2
Signed-off-by: Michael Palimaka <kensington <AT> gentoo.org>

 app-text/ansifilter/Manifest               |  1 +
 app-text/ansifilter/ansifilter-2.18.ebuild | 64 ++++++++++++++++++++++++++++++
 2 files changed, 65 insertions(+)

diff --git a/app-text/ansifilter/Manifest b/app-text/ansifilter/Manifest
index efe97c563b6..a09138f4672 100644
--- a/app-text/ansifilter/Manifest
+++ b/app-text/ansifilter/Manifest
@@ -1 +1,2 @@
 DIST ansifilter-2.17.tar.bz2 436116 BLAKE2B 94a1788cffa66343643f48a18748d5359b090803cde723a02bc38f908c262631f1cd2eb150b6a743d66caa04983ea444ba150cf34ce07bdb456979e19631582f SHA512 ab9d590189482f2a27affd62b456c96b947b04d8c8b1214f1ea967971c8ed7df8a7c15d1079f957164d01916d144dcd5dc4b0ac05b452f9f4b8095273d3d3162
+DIST ansifilter-2.18.tar.bz2 436432 BLAKE2B 43c592e83a967ee86404332a464d57d202a73651b2e29da2d1d21163d295b6efba96ecb5861dacfa89b8f567c0367f7a32b8e658f8cefad82c5982f2f2bf70bb SHA512 ef7febed1fc31f5c7503648e4fc0a7aefc3da8e30ea649bd6f03eac2904667fb779049106ccb77ad16fbf655e979f6651b25b84ab126c940c66bedee115a28e2

diff --git a/app-text/ansifilter/ansifilter-2.18.ebuild b/app-text/ansifilter/ansifilter-2.18.ebuild
new file mode 100644
index 00000000000..f1a848e9dc4
--- /dev/null
+++ b/app-text/ansifilter/ansifilter-2.18.ebuild
@@ -0,0 +1,64 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit toolchain-funcs qmake-utils
+
+DESCRIPTION="Handles text files containing ANSI terminal escape codes"
+HOMEPAGE="http://www.andre-simon.de/"
+SRC_URI="http://www.andre-simon.de/zip/${P}.tar.bz2"
+
+LICENSE="GPL-3+"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~ppc64 ~s390 ~sparc ~x86 ~x64-macos"
+IUSE="qt5"
+
+RDEPEND="
+	qt5? (
+		dev-qt/qtcore:5
+		dev-qt/qtgui:5
+		dev-qt/qtwidgets:5
+	)"
+DEPEND="${RDEPEND}"
+
+DOCS=( ChangeLog.adoc README.adoc  )
+
+src_prepare() {
+	default
+
+	# bug 431452
+	rm src/qt-gui/moc_mydialog.cpp || die
+
+	sed -e "s/-O2//" -i src/makefile || die
+}
+
+src_configure() {
+	if use qt5 ; then
+		pushd src/qt-gui > /dev/null || die
+		eqmake5
+		popd > /dev/null || die
+	fi
+}
+
+src_compile() {
+	emake -f makefile CXX="$(tc-getCXX)"
+
+	if use qt5 ; then
+		pushd src/qt-gui > /dev/null || die
+		emake
+		popd > /dev/null || die
+	fi
+}
+
+src_install() {
+	dobin src/${PN}
+	if use qt5 ; then
+		dobin src/qt-gui/${PN}-gui
+		insinto /usr/share/applications
+		doins ${PN}.desktop
+	fi
+
+	doman man/${PN}.1
+	einstalldocs
+}