[gentoo-commits] gentoo-x86 commit in net-libs/nodejs: nodejs-0.11.12.ebuild ChangeLog

[Patrick Lauer (patrick)]

patrick     14/03/31 06:29:58

  Modified:             ChangeLog
  Added:                nodejs-0.11.12.ebuild
  Log:
  Bump #505506
  
  (Portage version: 2.2.8-r1/cvs/Linux x86_64, unsigned Manifest commit)

Revision  Changes    Path
1.116                net-libs/nodejs/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-libs/nodejs/ChangeLog?rev=1.116&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-libs/nodejs/ChangeLog?rev=1.116&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-libs/nodejs/ChangeLog?r1=1.115&r2=1.116

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-libs/nodejs/ChangeLog,v
retrieving revision 1.115
retrieving revision 1.116
diff -u -r1.115 -r1.116
--- ChangeLog	14 Mar 2014 02:33:51 -0000	1.115
+++ ChangeLog	31 Mar 2014 06:29:58 -0000	1.116
@@ -1,6 +1,11 @@
 # ChangeLog for net-libs/nodejs
 # Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-libs/nodejs/ChangeLog,v 1.115 2014/03/14 02:33:51 patrick Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-libs/nodejs/ChangeLog,v 1.116 2014/03/31 06:29:58 patrick Exp $
+
+*nodejs-0.11.12 (31 Mar 2014)
+
+  31 Mar 2014; Patrick Lauer <patrick@g.o> +nodejs-0.11.12.ebuild:
+  Bump #505506
 
 *nodejs-0.11.11-r1 (14 Mar 2014)
 



1.1                  net-libs/nodejs/nodejs-0.11.12.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-libs/nodejs/nodejs-0.11.12.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-libs/nodejs/nodejs-0.11.12.ebuild?rev=1.1&content-type=text/plain

Index: nodejs-0.11.12.ebuild
===================================================================
# Copyright 1999-2014 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-libs/nodejs/nodejs-0.11.12.ebuild,v 1.1 2014/03/31 06:29:58 patrick Exp $

EAPI=5

# has known failures. sigh.
RESTRICT="test"

PYTHON_COMPAT=( python2_{6,7} )

inherit python-any-r1 pax-utils

DESCRIPTION="Evented IO for V8 Javascript"
HOMEPAGE="http://nodejs.org/"
SRC_URI="http://nodejs.org/dist/v${PV}/node-v${PV}.tar.gz"

LICENSE="Apache-1.1 Apache-2.0 BSD BSD-2 MIT"
SLOT="0"
KEYWORDS="~amd64 ~arm ~x86 ~x64-macos"
IUSE="+npm +snapshot"

RDEPEND="dev-libs/openssl"
DEPEND="${RDEPEND}"

S=${WORKDIR}/node-v${PV}

src_prepare() {
	# fix compilation on Darwin
	# http://code.google.com/p/gyp/issues/detail?id=260
	sed -i -e "/append('-arch/d" tools/gyp/pylib/gyp/xcode_emulation.py || die

	# make sure we use python2.* while using gyp
	sed -i -e  "s/python/python2/" deps/npm/node_modules/node-gyp/gyp/gyp || die

	# less verbose install output (stating the same as portage, basically)
	sed -i -e "/print/d" tools/install.py || die
}

src_configure() {
	local myconf=""
	! use npm && myconf="--without-npm"
	! use snapshot && myconf="${myconf} --without-snapshot"

	# Use target arch detection logic, see v8-3.18 ebuilds
	case ${CHOST} in
		i?86-*)
			myarch="ia32"
			myconf+=" -Dv8_target_arch=ia32" ;;
		x86_64-*)
			if [[ $ABI = x86 ]] ; then
				myarch="ia32"
			else
				myarch="x64"
			fi ;;
		arm*-*)
			myarch="arm"
			;;
		*) die "Unrecognized CHOST: ${CHOST}"
	esac

	"${PYTHON}" configure --prefix="${EPREFIX}"/usr \
		--openssl-use-sys --shared-zlib --without-dtrace ${myconf} || die
}

src_compile() {
	emake out/Makefile
	emake -C out "mksnapshot.${myarch}"
	pax-mark m "out/Release/mksnapshot.${myarch}"
	emake
}

src_install() {
	"${PYTHON}" tools/install.py install "${D}" /usr

	use npm && dohtml -r "${ED}"/usr/lib/node_modules/npm/html/*
	rm -rf "${ED}"/usr/lib/node_modules/npm/doc "${ED}"/usr/lib/node_modules/npm/html
	rm -rf "${ED}"/usr/lib/dtrace

	pax-mark -m "${ED}"/usr/bin/node
}

src_test() {
	"${PYTHON}" tools/test.py --mode=release simple message || die
}