[gentoo-commits] repo/gentoo:master commit in: net-misc/nextcloud-client/

[Bernard Cafarelli]

commit:     03c3b61c6ad3bd81dddf230d67d0ec51e9dcf5ee
Author:     Florian Schmaus <flow <AT> gentoo <DOT> org>
AuthorDate: Tue Feb  8 17:32:35 2022 +0000
Commit:     Bernard Cafarelli <voyageur <AT> gentoo <DOT> org>
CommitDate: Wed Feb  9 12:22:46 2022 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=03c3b61c

net-misc/nextcloud-client: add 3.4.2

Closes: https://bugs.gentoo.org/832942
Signed-off-by: Florian Schmaus <flow <AT> gentoo.org>
Closes: https://github.com/gentoo/gentoo/pull/24132
Signed-off-by: Bernard Cafarelli <voyageur <AT> gentoo.org>

 net-misc/nextcloud-client/Manifest                 |  1 +
 .../nextcloud-client/nextcloud-client-3.4.2.ebuild | 92 ++++++++++++++++++++++
 2 files changed, 93 insertions(+)

diff --git a/net-misc/nextcloud-client/Manifest b/net-misc/nextcloud-client/Manifest
index 2a22cf29490a..d3691d4ad7b5 100644
--- a/net-misc/nextcloud-client/Manifest
+++ b/net-misc/nextcloud-client/Manifest
@@ -1,2 +1,3 @@
 DIST nextcloud-client-3.1.3.tar.gz 19552683 BLAKE2B 321ddc6bd5f9428abe1eafe25d426c26c99307c5e7d204bc60fd1bafe773fbed9cb54264f7b1ec7766078b8c06a2399c916a8bd9291e0e28e5b6b3ed8725a7a4 SHA512 ca0a70e65be67e10a7cb45f2b30f6b82230f30c2e3afcd16a222a8ed6fb8df4eff5e78fe0b6e3f4c6a18ff963896ccd6d8282c9829bd75a943324d4ab0068a99
 DIST nextcloud-client-3.3.6.tar.gz 14106065 BLAKE2B b4f1179787a835f7fa203dfeaa2091eb1368f15ea6252dbf2ddd2d1a46786752f3a896574283c9ebc3faeaa024272c20fa67e4ee08b8ebca319d224ad4eb19f5 SHA512 d6c16ebd8af0d97f412102cfa9f7b7d4ca502ff5d025618f3a98a33a068dce9d0b71ee71e7b3c3a02219929584559a1237d57b1a7aa27ad8234653b56530c9f0
+DIST nextcloud-client-3.4.2.tar.gz 14329069 BLAKE2B 5a23e9a7535aff3591d73d2b17abf71cb6302b9acfa41a1de051d42d9acb4cf4d76ed1dff3c73ec989a066c51d4fe9e94d6e71718f9fc0533d0c0e2bb0949060 SHA512 9788fd658c9e7c3b26eb3c41934ee75222aba0afd38e1fd71f8f04472bf4971e5cc7c12469f0b3f909f4dc1e5aa1a063ae1324f6a8b6052cdf9b3c8c1cc8c909

diff --git a/net-misc/nextcloud-client/nextcloud-client-3.4.2.ebuild b/net-misc/nextcloud-client/nextcloud-client-3.4.2.ebuild
new file mode 100644
index 000000000000..fe6451351219
--- /dev/null
+++ b/net-misc/nextcloud-client/nextcloud-client-3.4.2.ebuild
@@ -0,0 +1,92 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit cmake xdg
+
+DESCRIPTION="Desktop Syncing Client for Nextcloud"
+HOMEPAGE="https://github.com/nextcloud/desktop"
+SRC_URI="https://github.com/nextcloud/desktop/archive/v${PV/_/-}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="CC-BY-3.0 GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~x86"
+IUSE="doc dolphin nautilus test webengine"
+RESTRICT="!test? ( test )"
+
+COMMON_DEPEND=">=dev-db/sqlite-3.34:3
+	>=dev-libs/openssl-1.1.0:0=
+	dev-libs/qtkeychain:=[qt5(+)]
+	dev-qt/qtcore:5
+	dev-qt/qtdbus:5
+	dev-qt/qtdeclarative:5
+	dev-qt/qtgui:5
+	dev-qt/qtnetwork:5[ssl]
+	dev-qt/qtquickcontrols2:5
+	dev-qt/qtsvg:5
+	dev-qt/qtwebsockets:5
+	dev-qt/qtwidgets:5
+	sys-libs/zlib
+	dolphin? (
+		kde-frameworks/kcoreaddons:5
+		kde-frameworks/kio:5
+	)
+	nautilus? ( dev-python/nautilus-python )
+	webengine? ( dev-qt/qtwebengine:5[widgets] )"
+
+DEPEND="${COMMON_DEPEND}
+	dev-qt/linguist-tools:5
+	dev-qt/qtconcurrent:5
+	dev-qt/qtxml:5
+	gnome-base/librsvg
+	doc? (
+		dev-python/sphinx
+		dev-tex/latexmk
+		dev-texlive/texlive-latexextra
+		virtual/latex-base
+	)
+	dolphin? ( kde-frameworks/extra-cmake-modules )
+	test? (
+		dev-util/cmocka
+		dev-qt/qttest:5
+	)"
+
+RDEPEND="${COMMON_DEPEND}"
+
+S="${WORKDIR}/desktop-${PV/_/-}"
+
+src_prepare() {
+	# We do not package libcloudproviders
+	sed -e "s/pkg_check_modules.*cloudproviders/#&/" -i CMakeLists.txt || die
+
+	# Keep tests in ${T}
+	sed -i -e "s#\"/tmp#\"${T}#g" test/test*.cpp || die
+
+	cmake_src_prepare
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DCMAKE_INSTALL_DOCDIR=/usr/share/doc/${PF}
+		-DBUILD_UPDATER=OFF
+		$(cmake_use_find_package doc Sphinx)
+		$(cmake_use_find_package doc PdfLatex)
+		$(cmake_use_find_package webengine Qt5WebEngine)
+		$(cmake_use_find_package webengine Qt5WebEngineWidgets)
+		-DBUILD_SHELL_INTEGRATION_DOLPHIN=$(usex dolphin)
+		-DBUILD_SHELL_INTEGRATION_NAUTILUS=$(usex nautilus)
+		-DUNIT_TESTING=$(usex test)
+	)
+
+	cmake_src_configure
+}
+
+pkg_postinst() {
+	xdg_pkg_postinst
+
+	if ! use doc ; then
+		elog "Documentation and man pages not installed"
+		elog "Enable doc USE-flag to generate them"
+	fi
+}