[gentoo-commits] repo/gentoo:master commit in: media-libs/libsndfile/

[David Seifert]

commit:     1cea7541f807c4f7c5014ec8b1aa88e865150ed7
Author:     David Seifert <soap <AT> gentoo <DOT> org>
AuthorDate: Sat Oct 14 19:23:04 2017 +0000
Commit:     David Seifert <soap <AT> gentoo <DOT> org>
CommitDate: Sat Oct 14 19:23:04 2017 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=1cea7541

media-libs/libsndfile: Add live ebuild

Package-Manager: Portage-2.3.11, Repoman-2.3.3

 media-libs/libsndfile/libsndfile-9999.ebuild | 71 ++++++++++++++++++++++++++++
 1 file changed, 71 insertions(+)

diff --git a/media-libs/libsndfile/libsndfile-9999.ebuild b/media-libs/libsndfile/libsndfile-9999.ebuild
new file mode 100644
index 00000000000..eb28af81fd5
--- /dev/null
+++ b/media-libs/libsndfile/libsndfile-9999.ebuild
@@ -0,0 +1,71 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+PYTHON_COMPAT=( python{2_7,3_4,3_5,3_6} pypy{,3} )
+
+inherit python-any-r1 multilib-minimal
+
+DESCRIPTION="A C library for reading and writing files containing sampled sound"
+HOMEPAGE="http://www.mega-nerd.com/libsndfile"
+
+if [[ ${PV} == *9999 ]]; then
+	inherit autotools git-r3
+	EGIT_REPO_URI="https://github.com/erikd/libsndfile.git"
+
+	DEPEND="
+		${PYTHON_DEPS}
+		sys-devel/autogen"
+else
+	SRC_URI="http://www.mega-nerd.com/libsndfile/files/${P}.tar.gz"
+	KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~sh ~sparc ~x86 ~amd64-fbsd ~x86-fbsd ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~sparc-solaris ~x64-solaris ~x86-solaris"
+fi
+
+LICENSE="LGPL-2.1"
+SLOT="0"
+IUSE="alsa minimal sqlite static-libs test"
+
+RDEPEND="
+	!minimal? (
+		>=media-libs/flac-1.2.1-r5[${MULTILIB_USEDEP}]
+		>=media-libs/libogg-1.3.0[${MULTILIB_USEDEP}]
+		>=media-libs/libvorbis-1.3.3-r1[${MULTILIB_USEDEP}]
+	)
+	alsa? ( media-libs/alsa-lib )
+	sqlite? ( >=dev-db/sqlite-3.2 )"
+DEPEND="
+	${DEPEND}
+	${RDEPEND}
+	virtual/pkgconfig
+	test? ( ${PYTHON_DEPS} )"
+
+pkg_setup() {
+	if use test || [[ ${PV} == *9999 ]]; then
+		python-any-r1_pkg_setup
+	fi
+}
+
+src_prepare() {
+	default
+
+	[[ ${PV} == *9999 ]] && eautoreconf
+}
+
+multilib_src_configure() {
+	ECONF_SOURCE="${S}" econf \
+		--disable-octave \
+		$(use_enable static-libs static) \
+		$(use_enable !minimal external-libs) \
+		$(multilib_native_enable full-suite) \
+		$(multilib_native_use_enable alsa) \
+		$(multilib_native_use_enable sqlite) \
+		PYTHON="${EPYTHON}"
+}
+
+multilib_src_install_all() {
+	einstalldocs
+
+	# package provides .pc files
+	find "${D}" -name '*.la' -delete || die
+}