[gentoo-commits] gentoo-x86 commit in sys-auth/pam_ssh: pam_ssh-2.1.ebuild ChangeLog

[Mike Frysinger (vapier)]

vapier      15/07/07 08:44:52

  Modified:             ChangeLog
  Added:                pam_ssh-2.1.ebuild
  Log:
  Version bump #503424 by David Heidelberg.
  
  (Portage version: 2.2.20/cvs/Linux x86_64, signed Manifest commit with key D2E96200)

Revision  Changes    Path
1.57                 sys-auth/pam_ssh/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-auth/pam_ssh/ChangeLog?rev=1.57&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-auth/pam_ssh/ChangeLog?rev=1.57&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-auth/pam_ssh/ChangeLog?r1=1.56&r2=1.57

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/sys-auth/pam_ssh/ChangeLog,v
retrieving revision 1.56
retrieving revision 1.57
diff -u -r1.56 -r1.57
--- ChangeLog	23 Dec 2013 09:14:48 -0000	1.56
+++ ChangeLog	7 Jul 2015 08:44:52 -0000	1.57
@@ -1,6 +1,12 @@
 # ChangeLog for sys-auth/pam_ssh
-# Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/sys-auth/pam_ssh/ChangeLog,v 1.56 2013/12/23 09:14:48 vapier Exp $
+# Copyright 1999-2015 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/sys-auth/pam_ssh/ChangeLog,v 1.57 2015/07/07 08:44:52 vapier Exp $
+
+*pam_ssh-2.1 (07 Jul 2015)
+
+  07 Jul 2015; Mike Frysinger <vapier@g.o>
+  +files/pam_ssh-2.1-dot-ssh-check.patch, +pam_ssh-2.1.ebuild:
+  Version bump #503424 by David Heidelberg.
 
   23 Dec 2013; Mike Frysinger <vapier@g.o> pam_ssh-1.98.ebuild:
   Mark alpha/ia64 stable #459960.



1.1                  sys-auth/pam_ssh/pam_ssh-2.1.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-auth/pam_ssh/pam_ssh-2.1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-auth/pam_ssh/pam_ssh-2.1.ebuild?rev=1.1&content-type=text/plain

Index: pam_ssh-2.1.ebuild
===================================================================
# Copyright 1999-2015 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/sys-auth/pam_ssh/pam_ssh-2.1.ebuild,v 1.1 2015/07/07 08:44:52 vapier Exp $

EAPI="5"

inherit pam eutils flag-o-matic readme.gentoo

DESCRIPTION="Uses ssh-agent to provide single sign-on"
HOMEPAGE="http://pam-ssh.sourceforge.net/"
SRC_URI="mirror://sourceforge/pam-ssh/${P}.tar.xz"

LICENSE="BSD-2 BSD ISC"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~amd64-linux ~ia64-linux ~x86-linux"
IUSE=""

# Only supports OpenSSH via `ssh-agent` #282993
DEPEND="virtual/pam
	dev-libs/openssl:0="
RDEPEND="${DEPEND}
	net-misc/openssh"

DOC_CONTENTS="
	You can enable pam_ssh for system authentication by enabling
	the pam_ssh USE flag on sys-auth/pambase.
"

src_prepare() {
	epatch "${FILESDIR}"/${P}-dot-ssh-check.patch #503424#c5
}

src_configure() {
	# hide all the otherwise-exported symbols that may clash with
	# other software loading the PAM modules (see bug #274924 as an
	# example).
	append-ldflags -Wl,--version-script="${FILESDIR}"/pam_symbols.ver

	# Set the cache var so the configure script doesn't go probing hardcoded
	# file system paths and picking up the wrong thing.
	export ac_cv_openssldir=''

	# Avoid cross-compiling funkiness and requiring openssh at build time.
	export PATH_SSH_AGENT="${EPREFIX}/usr/bin/ssh-agent"

	econf \
		"--with-pam-dir=$(getpam_mod_dir)"
}

src_install() {
	default
	prune_libtool_files --modules
	readme.gentoo_create_doc
}