[gentoo-commits] repo/gentoo:master commit in: dev-python/gevent/

[Michał Górny]

commit:     2bb4b0280557296871dcc801d05f7c68cbc8cb57
Author:     Michał Górny <mgorny <AT> gentoo <DOT> org>
AuthorDate: Fri May 29 06:29:42 2020 +0000
Commit:     Michał Górny <mgorny <AT> gentoo <DOT> org>
CommitDate: Fri May 29 07:24:58 2020 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=2bb4b028

dev-python/gevent: Bump to 20.5.2

Signed-off-by: Michał Górny <mgorny <AT> gentoo.org>

 dev-python/gevent/Manifest             |  1 +
 dev-python/gevent/gevent-20.5.2.ebuild | 89 ++++++++++++++++++++++++++++++++++
 2 files changed, 90 insertions(+)

diff --git a/dev-python/gevent/Manifest b/dev-python/gevent/Manifest
index a18a9daf589..ca643ae958f 100644
--- a/dev-python/gevent/Manifest
+++ b/dev-python/gevent/Manifest
@@ -1,2 +1,3 @@
 DIST gevent-1.4.0.tar.gz 5169595 BLAKE2B 0c78f67bc94d15419b8eadf8825d9657c6a7a82756308216e1ca94d5465c25836cb736b8b370a12d1003eb8614effd4110d8ed47ee2b0d7febc2bda4038adc0a SHA512 6771f4f2932055270e4f5a79ae815e93fd0f471defa7f437dc84907ea8b44672e05ae5eb6958f8d90580b2471785dce4044d9d1bbea0dd0c34c1381d88af0344
 DIST gevent-20.5.1.tar.gz 5566653 BLAKE2B 1d9a474681573ec2e9d3c0d40fbae8a91b8cfb80c3ff8b3cf0e119b0484458941224302afb59f16c3272e1d770b1c1e92a3f648754a81d2e894e35ed8a335c31 SHA512 c6f9360efa86e598b7b240cd15e24ee0711dc314bb14f8bcaee7b0768b34a0f090d66296819f4c2eb95fe1565fe1c0f3472fb47444c31cfebc348b420811aed5
+DIST gevent-20.5.2.tar.gz 5567755 BLAKE2B 9cac45f92c7c1841cca4eb52a54f71406beb3e83136170610bba326a32722de3c5ebd3b777a45b73ab5e1012eb0dc49d861b042bab0c6194e61f44e6011ede2e SHA512 24f00a599f26d673947f0ed5582f8b55d1b214677578d7c5c2f8d8c106f89a98951db523597c470bcd788de9f6b7abcd3f25f7aff27788227f6d8c7ca7c183c1

diff --git a/dev-python/gevent/gevent-20.5.2.ebuild b/dev-python/gevent/gevent-20.5.2.ebuild
new file mode 100644
index 00000000000..faeb72ae729
--- /dev/null
+++ b/dev-python/gevent/gevent-20.5.2.ebuild
@@ -0,0 +1,89 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+DISTUTILS_USE_SETUPTOOLS=rdepend
+PYTHON_COMPAT=( python2_7 python3_{6,7,8,9} )
+PYTHON_REQ_USE="ssl(+),threads(+)"
+
+inherit distutils-r1 flag-o-matic
+
+DESCRIPTION="Coroutine-based network library"
+HOMEPAGE="http://gevent.org/ https://pypi.org/project/gevent/"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~mips ~ppc ~ppc64 ~s390 ~sparc ~x86 ~amd64-linux ~x86-linux"
+IUSE="doc examples test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	>=dev-libs/libev-4.23
+	>=net-dns/c-ares-1.12
+	>=dev-python/greenlet-0.4.14
+	virtual/python-greenlet[${PYTHON_USEDEP}]"
+DEPEND="${RDEPEND}
+	test? (
+		dev-python/psutil[${PYTHON_USEDEP}]
+		dev-python/requests[${PYTHON_USEDEP}]
+		dev-python/zope-event[${PYTHON_USEDEP}]
+		dev-python/zope-interface[${PYTHON_USEDEP}]
+		$(python_gen_cond_dep '
+			dev-python/futures[${PYTHON_USEDEP}]
+			dev-python/mock[${PYTHON_USEDEP}]
+		' -2)
+	)"
+
+distutils_enable_sphinx doc
+
+# Tests take long and fail terribly a few times.
+# It also seems that they require network access.
+#RESTRICT="test"
+
+python_prepare_all() {
+	export LIBEV_EMBED="false"
+	export CARES_EMBED="false"
+	export EMBED="false"
+
+	distutils-r1_python_prepare_all
+}
+
+python_configure_all() {
+	append-flags -fno-strict-aliasing
+}
+
+python_test() {
+	cd src/gevent/tests || die
+	# TODO: figure out how to make them work and not hang
+#	GEVENT_RESOLVER=ares \
+#		"${EPYTHON}" -m gevent.tests \
+#		-uall,-network \
+#		--config known_failures.py \
+#		--ignore tests_that_dont_use_resolver.txt || die
+#	GEVENT_RESOLVER=dnspython \
+#		"${EPYTHON}" -m gevent.tests \
+#		-uall,-network \
+#		--config known_failures.py \
+#		--ignore tests_that_dont_use_resolver.txt || die
+#	GEVENT_RESOLVER=thread \
+#		"${EPYTHON}" -m gevent.tests \
+#		--verbose \
+#		-uall,-network \
+#		--config known_failures.py \
+#		--ignore tests_that_dont_use_resolver.txt || die
+	GEVENT_FILE=thread \
+		"${EPYTHON}" -m gevent.tests \
+		--verbose \
+		-uall,-network \
+		--config known_failures.py \
+		test__*subprocess*.py || die
+}
+
+python_install_all() {
+	local DOCS=( AUTHORS README.rst )
+	use examples && dodoc -r examples
+
+	distutils-r1_python_install_all
+}