Get Gentoo!
gentoo.org sites
gentoo.org Wiki Bugs Forums Packages
Planet Archives Sources
Infra Status

Gentoo Archives: gentoo-commits

From: "Julian Ospald (hasufell)" <hasufell@g.o>
To: gentoo-commits@l.g.o
Subject: [gentoo-commits] gentoo-x86 commit in media-gfx/inkscape: ChangeLog inkscape-0.48.4-r1.ebuild
Date: Wed, 01 May 2013 13:33:27
Message-Id: 20130501133323.104F92171D@flycatcher.gentoo.org
1 hasufell 13/05/01 13:33:22
2
3 Modified: ChangeLog
4 Added: inkscape-0.48.4-r1.ebuild
5 Log:
6 convert to python-single-r1 wrt #467234 and fix build with automake-1.13 wrt #467228
7
8 (Portage version: 2.2.0_alpha173/cvs/Linux x86_64, signed Manifest commit with key E73C35B3)
9
10 Revision Changes Path
11 1.197 media-gfx/inkscape/ChangeLog
12
13 file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-gfx/inkscape/ChangeLog?rev=1.197&view=markup
14 plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-gfx/inkscape/ChangeLog?rev=1.197&content-type=text/plain
15 diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-gfx/inkscape/ChangeLog?r1=1.196&r2=1.197
16
17 Index: ChangeLog
18 ===================================================================
19 RCS file: /var/cvsroot/gentoo-x86/media-gfx/inkscape/ChangeLog,v
20 retrieving revision 1.196
21 retrieving revision 1.197
22 diff -u -r1.196 -r1.197
23 --- ChangeLog 27 Dec 2012 17:25:24 -0000 1.196
24 +++ ChangeLog 1 May 2013 13:33:22 -0000 1.197
25 @@ -1,6 +1,14 @@
26 # ChangeLog for media-gfx/inkscape
27 -# Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
28 -# $Header: /var/cvsroot/gentoo-x86/media-gfx/inkscape/ChangeLog,v 1.196 2012/12/27 17:25:24 ago Exp $
29 +# Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
30 +# $Header: /var/cvsroot/gentoo-x86/media-gfx/inkscape/ChangeLog,v 1.197 2013/05/01 13:33:22 hasufell Exp $
31 +
32 +*inkscape-0.48.4-r1 (01 May 2013)
33 +
34 + 01 May 2013; Julian Ospald <hasufell@g.o> +inkscape-0.48.4-r1.ebuild,
35 + +files/inkscape-0.48.4-automake-1.3.patch,
36 + +files/inkscape-0.48.4-epython.patch:
37 + convert to python-single-r1 wrt #467234 and fix build with automake-1.13 wrt
38 + #467228
39
40 27 Dec 2012; Agostino Sarubbo <ago@g.o> -inkscape-0.48.3.1.ebuild:
41 Remove old
42
43
44
45 1.1 media-gfx/inkscape/inkscape-0.48.4-r1.ebuild
46
47 file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-gfx/inkscape/inkscape-0.48.4-r1.ebuild?rev=1.1&view=markup
48 plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-gfx/inkscape/inkscape-0.48.4-r1.ebuild?rev=1.1&content-type=text/plain
49
50 Index: inkscape-0.48.4-r1.ebuild
51 ===================================================================
52 # Copyright 1999-2013 Gentoo Foundation
53 # Distributed under the terms of the GNU General Public License v2
54 # $Header: /var/cvsroot/gentoo-x86/media-gfx/inkscape/inkscape-0.48.4-r1.ebuild,v 1.1 2013/05/01 13:33:22 hasufell Exp $
55
56 EAPI=5
57
58 GCONF_DEBUG=no
59
60 PYTHON_COMPAT=( python2_6 python2_7 )
61 PYTHON_REQ_USE="xml"
62 inherit autotools eutils flag-o-matic gnome2 toolchain-funcs python-single-r1
63
64 MY_P="${P/_/}"
65 S="${WORKDIR}/${MY_P}"
66 SRC_URI="mirror://sourceforge/${PN}/${MY_P}.tar.bz2"
67
68 DESCRIPTION="A SVG based generic vector-drawing program"
69 HOMEPAGE="http://www.inkscape.org/"
70
71 LICENSE="GPL-2 LGPL-2.1"
72 SLOT="0"
73 KEYWORDS="~amd64 ~hppa ~ppc ~ppc64 ~x86 ~amd64-linux ~x86-linux ~sparc-solaris ~x86-solaris"
74 IUSE="dia gnome postscript inkjar lcms nls spell wmf"
75
76 RESTRICT="test"
77
78 COMMON_DEPEND="
79 ${PYTHON_DEPS}
80 >=app-text/poppler-0.12.3-r3[cairo,xpdf-headers(+)]
81 dev-cpp/glibmm
82 >=dev-cpp/gtkmm-2.18.0:2.4
83 >=dev-libs/boehm-gc-6.4
84 >=dev-libs/glib-2.6.5
85 >=dev-libs/libsigc++-2.0.12
86 >=dev-libs/libxml2-2.6.20
87 >=dev-libs/libxslt-1.0.15
88 dev-libs/popt
89 dev-python/lxml[${PYTHON_USEDEP}]
90 media-gfx/imagemagick[cxx]
91 media-libs/fontconfig
92 media-libs/freetype:2
93 media-libs/libpng:0
94 app-text/libwpd:0.9
95 app-text/libwpg:0.2
96 sci-libs/gsl
97 x11-libs/libX11
98 >=x11-libs/gtk+-2.10.7:2
99 >=x11-libs/pango-1.4.0
100 gnome? ( >=gnome-base/gnome-vfs-2.0 )
101 lcms? ( media-libs/lcms:2 )
102 spell? (
103 app-text/aspell
104 app-text/gtkspell:2
105 )"
106
107 # These only use executables provided by these packages
108 # See share/extensions for more details. inkscape can tell you to
109 # install these so we could of course just not depend on those and rely
110 # on that.
111 RDEPEND="
112 ${COMMON_DEPEND}
113 dev-python/numpy[${PYTHON_USEDEP}]
114 media-gfx/uniconvertor
115 dia? ( app-office/dia )
116 postscript? ( app-text/ghostscript-gpl )
117 wmf? ( media-libs/libwmf )"
118
119 DEPEND="${COMMON_DEPEND}
120 dev-libs/boost
121 sys-devel/gettext
122 virtual/pkgconfig
123 >=dev-util/intltool-0.29"
124
125 DOCS="AUTHORS ChangeLog NEWS README*"
126
127 src_prepare() {
128 gnome2_src_prepare
129 epatch "${FILESDIR}"/${PN}-0.48.0-spell.patch \
130 "${FILESDIR}"/${PN}-0.48.2-libwpg.patch \
131 "${FILESDIR}"/${PN}-0.48.3.1-desktop.patch \
132 "${FILESDIR}"/${PN}-0.48.4-epython.patch \
133 "${FILESDIR}"/${PN}-0.48.4-fix-member-decl.patch \
134 "${FILESDIR}"/${PN}-0.48.4-automake-1.3.patch
135
136 sed -i \
137 -e "s#@EPYTHON@#${EPYTHON}#" \
138 src/extension/implementation/script.cpp || die
139
140 eautoreconf
141
142 # bug 421111
143 python_fix_shebang share/extensions
144 }
145
146 src_configure() {
147 G2CONF="${G2CONF}
148 --without-perl
149 --enable-poppler-cairo
150 $(use_with gnome gnome-vfs)
151 $(use_with inkjar)
152 $(use_enable lcms)
153 $(use_enable nls)
154 $(use_with spell aspell)
155 $(use_with spell gtkspell)"
156
157 # aliasing unsafe wrt #310393
158 append-flags -fno-strict-aliasing
159 gnome2_src_configure
160 }
161
162 src_compile() {
163 emake AR="$(tc-getAR)"
164 }
165
166 src_install() {
167 gnome2_src_install
168 python_optimize "${ED}"/usr/share/${PN}/extensions
169 }
Report Message
Find on MARC Find on Google Groups