[gentoo-commits] repo/gentoo:master commit in: dev-python/commonmark/

[Michał Górny]

commit:     e3b94b580710615d8fdfa85508c7e52112a7c382
Author:     Michał Górny <mgorny <AT> gentoo <DOT> org>
AuthorDate: Wed May 11 17:20:45 2022 +0000
Commit:     Michał Górny <mgorny <AT> gentoo <DOT> org>
CommitDate: Wed May 11 17:54:38 2022 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=e3b94b58

dev-python/commonmark: EAPI 8, PEP517

Signed-off-by: Michał Górny <mgorny <AT> gentoo.org>

 dev-python/commonmark/commonmark-0.9.1-r1.ebuild | 45 ++++++++++++++++++++++++
 1 file changed, 45 insertions(+)

diff --git a/dev-python/commonmark/commonmark-0.9.1-r1.ebuild b/dev-python/commonmark/commonmark-0.9.1-r1.ebuild
new file mode 100644
index 000000000000..40240b1e76ac
--- /dev/null
+++ b/dev-python/commonmark/commonmark-0.9.1-r1.ebuild
@@ -0,0 +1,45 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{8..10} pypy3 )
+
+inherit distutils-r1
+
+DESCRIPTION="Python parser for the CommonMark Markdown spec"
+HOMEPAGE="
+	https://pypi.org/project/commonmark/
+	https://github.com/readthedocs/commonmark.py/
+"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~amd64-linux ~x86-linux"
+IUSE="test"
+RESTRICT="!test? ( test )"
+
+BDEPEND="
+	test? (
+		>=dev-python/hypothesis-3.7.1[${PYTHON_USEDEP}]
+	)
+"
+
+python_test() {
+	local -x PYTHONIOENCODING='utf8'
+	"${EPYTHON}" commonmark/tests/run_spec_tests.py || die
+}
+
+src_prepare() {
+	default
+	# Fix file collision with app-text/cmark, see bug #627034
+	sed -i -e "s:'cmark\( = commonmark.cmark\:main'\):'cmark.py\1:" \
+		setup.py || die
+}
+
+pkg_postinst() {
+	ewarn "/usr/bin/cmark has been renamed to /usr/bin/cmark.py due file"
+	ewarn "collision with app-text/cmark (see bug #627034)"
+}