[gentoo-commits] gentoo-x86 commit in dev-python/pylint: pylint-0.25.1.ebuild ChangeLog

[Patrick Lauer (patrick)]

patrick     12/02/08 04:52:28

  Modified:             ChangeLog
  Added:                pylint-0.25.1.ebuild
  Log:
  Bump for #401991
  
  (Portage version: 2.2.0_alpha85/cvs/Linux x86_64)

Revision  Changes    Path
1.86                 dev-python/pylint/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/pylint/ChangeLog?rev=1.86&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/pylint/ChangeLog?rev=1.86&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/pylint/ChangeLog?r1=1.85&r2=1.86

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/dev-python/pylint/ChangeLog,v
retrieving revision 1.85
retrieving revision 1.86
diff -u -r1.85 -r1.86
--- ChangeLog	18 Oct 2011 19:11:54 -0000	1.85
+++ ChangeLog	8 Feb 2012 04:52:28 -0000	1.86
@@ -1,6 +1,11 @@
 # ChangeLog for dev-python/pylint
-# Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-python/pylint/ChangeLog,v 1.85 2011/10/18 19:11:54 radhermit Exp $
+# Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/dev-python/pylint/ChangeLog,v 1.86 2012/02/08 04:52:28 patrick Exp $
+
+*pylint-0.25.1 (08 Feb 2012)
+
+  08 Feb 2012; Patrick Lauer <patrick@g.o> +pylint-0.25.1.ebuild:
+  Bump for #401991
 
   18 Oct 2011; Tim Harder <radhermit@g.o> -pylint-0.21.3.ebuild,
   -pylint-0.22.0.ebuild:



1.1                  dev-python/pylint/pylint-0.25.1.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/pylint/pylint-0.25.1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/pylint/pylint-0.25.1.ebuild?rev=1.1&content-type=text/plain

Index: pylint-0.25.1.ebuild
===================================================================
# Copyright 1999-2012 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-python/pylint/pylint-0.25.1.ebuild,v 1.1 2012/02/08 04:52:28 patrick Exp $

EAPI="3"
PYTHON_DEPEND="*:2.5"
SUPPORT_PYTHON_ABIS="1"
RESTRICT_PYTHON_ABIS="2.4"

inherit distutils

DESCRIPTION="Python code static checker"
HOMEPAGE="http://www.logilab.org/projects/pylint/ http://pypi.python.org/pypi/pylint"
SRC_URI="ftp://ftp.logilab.org/pub/${PN}/${P}.tar.gz mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~ia64 ~ppc ~sparc ~x86 ~amd64-linux ~x86-linux ~x64-macos ~x86-macos"
IUSE="examples"

# Versions specified in __pkginfo__.py.
RDEPEND=">=dev-python/logilab-common-0.53.0
	>=dev-python/astng-0.21.1"
DEPEND="${RDEPEND}
	dev-python/setuptools"

DISTUTILS_USE_SEPARATE_SOURCE_DIRECTORIES="1"
DOCS="doc/*.txt"

src_test() {
	testing() {
		# Test suite broken with Python 3.
		[[ "${PYTHON_ABI}" == 3.* ]] && return

		PYTHONPATH="build/lib" pytest -v
	}
	python_execute_function -s testing
}

src_install() {
	distutils_src_install

	doman man/{pylint,pyreverse}.1 || die "doman failed"

	if use examples; then
		docinto examples
		dodoc examples/* || die "dodoc failed"
	fi

	delete_tests() {
		rm -fr "${ED}$(python_get_sitedir)/pylint/test"
	}
	python_execute_function -q delete_tests
}

pkg_postinst() {
	distutils_pkg_postinst

	# Optional dependency on "tk" USE flag would break support for Jython.
	elog "pylint-gui script requires dev-lang/python with \"tk\" USE flag enabled."
}