[gentoo-commits] gentoo-x86 commit in dev-python/pandas: ChangeLog metadata.xml pandas-0.13.0.ebuild

[Justin Lecher (jlec)]

jlec        14/01/22 07:59:04

  Modified:             ChangeLog metadata.xml
  Added:                pandas-0.13.0.ebuild
  Log:
  dev-python/pandas: Version Bump, #498856
  
  (Portage version: 2.2.8-r1/cvs/Linux x86_64, signed Manifest commit with key B9D4F231BD1558AB!)

Revision  Changes    Path
1.21                 dev-python/pandas/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/pandas/ChangeLog?rev=1.21&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/pandas/ChangeLog?rev=1.21&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/pandas/ChangeLog?r1=1.20&r2=1.21

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/dev-python/pandas/ChangeLog,v
retrieving revision 1.20
retrieving revision 1.21
diff -u -r1.20 -r1.21
--- ChangeLog	27 Oct 2013 08:05:32 -0000	1.20
+++ ChangeLog	22 Jan 2014 07:59:04 -0000	1.21
@@ -1,6 +1,12 @@
 # ChangeLog for dev-python/pandas
-# Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-python/pandas/ChangeLog,v 1.20 2013/10/27 08:05:32 mgorny Exp $
+# Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/dev-python/pandas/ChangeLog,v 1.21 2014/01/22 07:59:04 jlec Exp $
+
+*pandas-0.13.0 (22 Jan 2014)
+
+  22 Jan 2014; Justin Lecher <jlec@g.o> +pandas-0.13.0.ebuild,
+  metadata.xml:
+  Version Bump, #498856
 
   27 Oct 2013; Michał Górny <mgorny@g.o> pandas-0.12.0.ebuild:
   Remove redundant python_export_best (done by the eclass).



1.6                  dev-python/pandas/metadata.xml

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/pandas/metadata.xml?rev=1.6&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/pandas/metadata.xml?rev=1.6&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/pandas/metadata.xml?r1=1.5&r2=1.6

Index: metadata.xml
===================================================================
RCS file: /var/cvsroot/gentoo-x86/dev-python/pandas/metadata.xml,v
retrieving revision 1.5
retrieving revision 1.6
diff -u -r1.5 -r1.6
--- metadata.xml	8 Aug 2013 18:08:49 -0000	1.5
+++ metadata.xml	22 Jan 2014 07:59:04 -0000	1.6
@@ -1,17 +1,17 @@
 <?xml version="1.0" encoding="UTF-8"?>
 <!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
 <pkgmetadata>
-<herd>sci</herd>
-<longdescription lang="en">
+  <herd>sci</herd>
+  <longdescription lang="en">
   Pandas is a Python package providing fast, flexible, and expressive
   data structures designed to make working with "relational" or
   "labeled" data both easy and intuitive. It aims to be the
   fundamental high-level building block for doing practical, real
   world data analysis in Python. 
 </longdescription>
-<use>
-  <flag name="excel">Pull a few Python packages for Microsoft Excel i/o</flag>
-  <flag name="html">Enable HTML i/o via <pkg>dev-python/beautifulsoup</pkg></flag>
-  <flag name="R">Enable support for R via <pkg>dev-python/rpy</pkg></flag>
-</use>
+  <use>
+    <flag name="excel">Pull a few Python packages for Microsoft Excel i/o</flag>
+    <flag name="html">Enable HTML i/o via <pkg>dev-python/beautifulsoup</pkg></flag>
+    <flag name="R">Enable support for R via <pkg>dev-python/rpy</pkg></flag>
+  </use>
 </pkgmetadata>



1.1                  dev-python/pandas/pandas-0.13.0.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/pandas/pandas-0.13.0.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/pandas/pandas-0.13.0.ebuild?rev=1.1&content-type=text/plain

Index: pandas-0.13.0.ebuild
===================================================================
# Copyright 1999-2014 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-python/pandas/pandas-0.13.0.ebuild,v 1.1 2014/01/22 07:59:04 jlec Exp $

EAPI=5

PYTHON_COMPAT=( python{2_6,2_7,3_2,3_3} )

inherit distutils-r1 virtualx

DESCRIPTION="Powerful data structures for data analysis and statistics"
HOMEPAGE="http://pandas.sourceforge.net/"
SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"

SLOT="0"
LICENSE="BSD"
KEYWORDS="~amd64 ~x86 ~amd64-linux ~x86-linux"
IUSE="doc examples excel html test R"

REQUIRED_USE="
	excel? ( !python_targets_python3_2 )
	doc? ( !python_targets_python3_2 )
	R? ( !python_targets_python3_2 )
"

CDEPEND="
	dev-python/numpy[${PYTHON_USEDEP}]
	dev-python/python-dateutil[${PYTHON_USEDEP}]"
DEPEND="${CDEPEND}
	doc? (
		dev-python/beautifulsoup:4[${PYTHON_USEDEP}]
		dev-python/ipython[${PYTHON_USEDEP}]
		dev-python/html5lib[${PYTHON_USEDEP}]
		dev-python/lxml[${PYTHON_USEDEP}]
		dev-python/matplotlib[${PYTHON_USEDEP}]
		>=dev-python/openpyxl-1.6.1[${PYTHON_USEDEP}]
		dev-python/pytables[${PYTHON_USEDEP}]
		dev-python/pytz[${PYTHON_USEDEP}]
		dev-python/rpy[$(python_gen_usedep 'python2_7')]
		sci-libs/scipy[${PYTHON_USEDEP}]
		dev-python/sphinx[${PYTHON_USEDEP}]
		dev-python/xlrd[$(python_gen_usedep 'python2*')]
		dev-python/xlwt[$(python_gen_usedep 'python2*')]
		sci-libs/scikits_timeseries[$(python_gen_usedep 'python2*')]
		x11-misc/xclip )
	test? ( dev-python/nose[${PYTHON_USEDEP}] )"
# dev-python/statsmodels invokes a circular dep
#  hence rm from doc? ( ), again
RDEPEND="${CDEPEND}
	dev-python/numexpr[${PYTHON_USEDEP}]
	dev-python/bottleneck[${PYTHON_USEDEP}]
	dev-python/matplotlib[${PYTHON_USEDEP}]
	dev-python/pytables[${PYTHON_USEDEP}]
	dev-python/pytz[${PYTHON_USEDEP}]
	sci-libs/scipy[${PYTHON_USEDEP}]
	excel? (
		>=dev-python/openpyxl-1.6.1[${PYTHON_USEDEP}]
		dev-python/xlrd[$(python_gen_usedep 'python2*')]
		dev-python/xlwt[$(python_gen_usedep 'python2*')]
	)
	html? (
		dev-python/beautifulsoup:4[${PYTHON_USEDEP}]
		|| ( dev-python/lxml[${PYTHON_USEDEP}]
			 dev-python/html5lib[${PYTHON_USEDEP}] )
	)
	R? ( dev-python/rpy[$(python_gen_usedep 'python2_7')] )"

python_prepare_all() {
	if use doc; then
		# Prevent un-needed download during build
		sed -e 's:^intersphinx_mapping:#intersphinx_mapping:' \
			-e "s:^    'statsmodels:#    'statsmodels:" \
			-e "s:^    'python:#    'python:" \
			-e "s:^}:#}:" \
			-i doc/source/conf.py || die
	fi
	distutils-r1_python_prepare_all
}

python_compile_all() {
	# To build docs the need be located in $BUILD_DIR,
	# else PYTHONPATH points to unusable modules.
	if use doc; then
		cd "${BUILD_DIR}"/lib || die
		cp -ar "${S}"/doc . && cd doc || die
		LANG=C PYTHONPATH=. "${EPYTHON}" make.py html || die
	fi
}

python_test() {
	# test can't survive py2.6, alternately patch to skip under unittest2
	if [[ ${EPYTHON} == "python2.6" ]]; then
		rm $(find "${BUILD_DIR}" -name test_array.py) || die
	fi
	cd "${BUILD_DIR}"/lib || die
	PYTHONPATH=. MPLCONFIGDIR=. HOME=. \
		VIRTUALX_COMMAND="nosetests --verbosity=3 pandas" \
		virtualmake || die
}

python_install_all() {
	if use doc; then
		cd  "${BUILD_DIR}"/lib || die
		dohtml -r doc/build/html/*
		einfo "An initial build of docs is absent of references to statsmodels"
		einfo "due to circular dependency. To have them included, emerge"
		einfo "statsmodels next and re-emerge pandas with USE doc"
	fi

	if use examples; then
		# example python modules not to be compressed
		docompress -x /usr/share/doc/${PF}/examples
		insinto /usr/share/doc/${PF}
		doins -r "${S}"/examples
	fi
	distutils-r1_python_install_all
}