[gentoo-commits] repo/gentoo:master commit in: media-sound/bluez-alsa/

[Lars Wendler]

commit:     c4967e60c5f845596d70a690dfdda5261de55ba4
Author:     Lars Wendler <polynomial-c <AT> gentoo <DOT> org>
AuthorDate: Wed Jun  9 07:32:03 2021 +0000
Commit:     Lars Wendler <polynomial-c <AT> gentoo <DOT> org>
CommitDate: Wed Jun  9 07:38:10 2021 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=c4967e60

media-sound/bluez-alsa: Bump to version 3.1.0

Signed-off-by: Lars Wendler <polynomial-c <AT> gentoo.org>

 media-sound/bluez-alsa/Manifest                |  1 +
 media-sound/bluez-alsa/bluez-alsa-3.1.0.ebuild | 95 ++++++++++++++++++++++++++
 2 files changed, 96 insertions(+)

diff --git a/media-sound/bluez-alsa/Manifest b/media-sound/bluez-alsa/Manifest
index d44d76abd81..c294ef4f454 100644
--- a/media-sound/bluez-alsa/Manifest
+++ b/media-sound/bluez-alsa/Manifest
@@ -1 +1,2 @@
 DIST bluez-alsa-3.0.0.tar.gz 157776 BLAKE2B 68cc67dcfd303e624333d7dafa53a3ce0f91f55e58a9a1a51f17153eadfdca5acc1b12b2e41a11c4780909fe8283e0a9c859a7d755e38dd9aeebbf4ae9e0daf2 SHA512 094c91636c3f1803b3eb88e295683acc604be9f86d00022c196784b4ec88aa4a6cc20bdff0fdab2a7e5af3efe95ed8bd8c5486a8cd7896ec572bfa9e8e0f13d0
+DIST bluez-alsa-3.1.0.tar.gz 179984 BLAKE2B b0bd5008d1bcc972577d8626970834934cc9424b4dff5c9ede1b1bfb0ac6c62c50dd8a7b94bdaa8884354379fb4fe06d758f620b2f42207d85f68da5064b3499 SHA512 8b2644cb2114569cc896869f22352386a9362eeacae823423a63d9b21198f561d4af796700fcd3267556bb69ff2575569474a1da8e3a645b5a2e779882c27cbf

diff --git a/media-sound/bluez-alsa/bluez-alsa-3.1.0.ebuild b/media-sound/bluez-alsa/bluez-alsa-3.1.0.ebuild
new file mode 100644
index 00000000000..80ea97b69db
--- /dev/null
+++ b/media-sound/bluez-alsa/bluez-alsa-3.1.0.ebuild
@@ -0,0 +1,95 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+inherit autotools bash-completion-r1 multilib-minimal systemd
+
+DESCRIPTION="Bluetooth Audio ALSA Backend"
+HOMEPAGE="https://github.com/Arkq/bluez-alsa"
+
+if [[ ${PV} == "9999" ]] ; then
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/Arkq/${PN}"
+else
+	SRC_URI="https://github.com/Arkq/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+	KEYWORDS="~amd64 ~arm64 ~x86"
+fi
+
+LICENSE="MIT"
+SLOT="0"
+IUSE="aac aptx debug hcitop lame ldac man mpg123 ofono static-libs test unwind upower"
+RESTRICT="!test? ( test )"
+
+# bluez-alsa does not directly link to upower but
+# is using the upower interface via dbus calls.
+RDEPEND="
+	>=dev-libs/glib-2.26[${MULTILIB_USEDEP}]
+	>=media-libs/alsa-lib-1.1.2[${MULTILIB_USEDEP}]
+	>=media-libs/sbc-1.2[${MULTILIB_USEDEP}]
+	>=net-wireless/bluez-5.0[${MULTILIB_USEDEP}]
+	sys-apps/dbus[${MULTILIB_USEDEP}]
+	sys-libs/readline:0=
+	aac? ( >=media-libs/fdk-aac-0.1.1:=[${MULTILIB_USEDEP}] )
+	aptx? ( media-libs/libopenaptx )
+	lame? ( media-sound/lame[${MULTILIB_USEDEP}] )
+	mpg123? ( media-sound/mpg123[${MULTILIB_USEDEP}] )
+	hcitop? (
+		dev-libs/libbsd
+		sys-libs/ncurses:0=
+	)
+	ldac? ( >=media-libs/libldac-2.0.0 )
+	ofono? ( net-misc/ofono )
+	unwind? ( sys-libs/libunwind[${MULTILIB_USEDEP}] )
+	upower? ( sys-power/upower )
+"
+DEPEND="${RDEPEND}
+	test? ( dev-libs/check )"
+BDEPEND="
+	virtual/pkgconfig
+	man? ( app-text/pandoc )
+"
+
+src_prepare() {
+	default
+	eautoreconf
+}
+
+multilib_src_configure() {
+	local myeconfargs=(
+		--enable-cli
+		--enable-rfcomm
+		--with-bash-completion="$(get_bashcompdir)"
+		$(use_enable aac)
+		$(use_enable debug)
+		$(use_enable lame mp3lame)
+		$(use_enable man manpages)
+		$(use_enable mpg123)
+		$(use_enable static-libs static)
+		$(use_enable test)
+		$(multilib_native_use_enable aptx)
+		$(multilib_native_use_enable hcitop)
+		$(multilib_native_use_enable ldac)
+		$(multilib_native_use_enable ofono)
+		$(multilib_native_use_enable upower)
+		$(multilib_native_use_with aptx libopenaptx)
+		$(use_with unwind libunwind)
+	)
+	ECONF_SOURCE="${S}" econf "${myeconfargs[@]}"
+}
+
+multilib_src_install_all() {
+	default
+	find "${ED}" -type f -name "*.la" -delete || die
+
+	newinitd "${FILESDIR}"/bluealsa-init.d bluealsa
+	newconfd "${FILESDIR}"/bluealsa-conf.d-2 bluealsa
+	systemd_dounit "${FILESDIR}"/bluealsa.service
+
+	# Add config file to alsa datadir as well to preserve changes in /etc
+	insinto "/usr/share/alsa/alsa.conf.d/"
+	doins "src/asound/20-bluealsa.conf"
+}
+
+pkg_postinst() {
+	elog "Users can use this service when they are members of the \"audio\" group."
+}