[gentoo-commits] repo/gentoo:master commit in: gnome-base/gnome-settings-daemon/

[Mart Raudsepp]

commit:     c5c91467a2d67ef958be90a482e1410f454e1ea1
Author:     Mart Raudsepp <leio <AT> gentoo <DOT> org>
AuthorDate: Tue Sep 25 21:02:06 2018 +0000
Commit:     Mart Raudsepp <leio <AT> gentoo <DOT> org>
CommitDate: Fri Sep 28 13:49:06 2018 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=c5c91467

gnome-base/gnome-settings-daemon: bump to 3.26.2, try to support elogind

Signed-off-by: Mart Raudsepp <leio <AT> gentoo.org>
Package-Manager: Portage-2.3.49, Repoman-2.3.11

 gnome-base/gnome-settings-daemon/Manifest          |   2 +
 .../gnome-settings-daemon-3.26.2-r1.ebuild         | 131 +++++++++++++++++++++
 gnome-base/gnome-settings-daemon/metadata.xml      |   5 +-
 3 files changed, 136 insertions(+), 2 deletions(-)

diff --git a/gnome-base/gnome-settings-daemon/Manifest b/gnome-base/gnome-settings-daemon/Manifest
index 9bde0ee5da1..41b217ebda9 100644
--- a/gnome-base/gnome-settings-daemon/Manifest
+++ b/gnome-base/gnome-settings-daemon/Manifest
@@ -1,2 +1,4 @@
 DIST gnome-settings-daemon-3.24.4-patchset.tar.xz 5224 BLAKE2B f01db03ce3980a74324972871643e573bc51a184fe12e7a40796b7ca1bbfac37ecad1fae2f8a62fba0038a672dc4958b242316dc3dc97a59b37a2e4e4f5e9973 SHA512 fe5bf846774b126e8ed89bc8043e8c02b567cc55d602c5becd84a14c7a414fc663ae1767a552b585defb462ffe88b4838f87445c9599fda37f197e8f2eaad8cb
 DIST gnome-settings-daemon-3.24.4.tar.xz 1632700 BLAKE2B 616aad6984df726c438117ab98e8c5a35bd02a6ebbc3c24fc46b50e8b3ca3f3d5bede0588cfe9bbdfcaccc70ff5799feeabf020ec4beb03d653ae81abc6325f8 SHA512 4a3b1069d80263a92ae2c2a420f7dc70a1ff92346d5cbeb1e7dd4af0419e039ebe958550594d87929c0333c19aa9a3ef7ca9b9751109a9da64a40d81ba067cc0
+DIST gnome-settings-daemon-3.26.2-patchset.tar.xz 42408 BLAKE2B 3b54dd1b161f4137eeb7c110be70444e3b8eb602a7d1c12ec6aaa32d887d46c3e1dc61df2a04895b7c6e2d67a68edeced5f758f688533caa9900deace7b6d542 SHA512 3ab36a03e2892ad193f420722025753990158ac450c686b9fba490cda4e7e1be69574dd4d3b9c8ed5e238f23933065abc28aee480ff1e2e5dad28e364c04fc0b
+DIST gnome-settings-daemon-3.26.2.tar.xz 1589696 BLAKE2B f1fd18e80caf5badb0da1f07cbe994b73a99ace004bf3b568114d6cd6110ebd092ee3a023a1ec818f3946f6f7cdb7ee21417782e271c8aa9ebd9d1d4c35ea286 SHA512 7785ebcb7df466c50557b75a3092f568e375adcf5a40f73e31d5cc69fa63bc556a4447a96e6e612c3bf523735e67168afae0b9c1fab32912d41014436d33b7ff

diff --git a/gnome-base/gnome-settings-daemon/gnome-settings-daemon-3.26.2-r1.ebuild b/gnome-base/gnome-settings-daemon/gnome-settings-daemon-3.26.2-r1.ebuild
new file mode 100644
index 00000000000..fc862199ab3
--- /dev/null
+++ b/gnome-base/gnome-settings-daemon/gnome-settings-daemon-3.26.2-r1.ebuild
@@ -0,0 +1,131 @@
+# Copyright 1999-2018 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+GNOME2_EAUTORECONF="yes"
+GNOME2_LA_PUNT="yes"
+#PYTHON_COMPAT=( python{2_7,3_4,3_5,3_6} ) # https://bugzilla.gnome.org/show_bug.cgi?id=783186
+PYTHON_COMPAT=( python2_7 )
+
+inherit gnome2 python-any-r1 udev virtualx
+
+DESCRIPTION="Gnome Settings Daemon"
+HOMEPAGE="https://git.gnome.org/browse/gnome-settings-daemon"
+SRC_URI+=" https://dev.gentoo.org/~leio/distfiles/${P}-patchset.tar.xz"
+
+LICENSE="GPL-2+"
+SLOT="0"
+IUSE="+colord +cups debug elogind input_devices_wacom networkmanager policykit smartcard systemd test +udev wayland"
+REQUIRED_USE="
+	^^ ( elogind systemd )
+	input_devices_wacom? ( udev )
+	smartcard? ( udev )
+	wayland? ( udev )
+"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~ia64 ~ppc ~ppc64 ~sparc ~x86 ~x86-fbsd ~amd64-linux ~x86-linux ~x86-solaris"
+
+COMMON_DEPEND="
+	>=dev-libs/glib-2.53.0:2
+	>=x11-libs/gtk+-3.15.3:3[X,wayland?]
+	>=gnome-base/gnome-desktop-3.11.1:3=
+	>=gnome-base/gsettings-desktop-schemas-3.23.3
+	>=gnome-base/librsvg-2.36.2:2
+	media-fonts/cantarell
+	media-libs/alsa-lib
+	media-libs/fontconfig
+	media-libs/libcanberra[gtk3]
+	>=media-sound/pulseaudio-2
+	>=sys-power/upower-0.99:=
+	x11-libs/cairo
+	x11-libs/gdk-pixbuf:2
+	>=x11-libs/libnotify-0.7.3:=
+	x11-libs/libX11
+	x11-libs/libxkbfile
+	x11-libs/libXi
+	x11-libs/libXext
+	x11-libs/libXfixes
+	x11-libs/libXtst
+	x11-libs/libXxf86misc
+	x11-misc/xkeyboard-config
+
+	>=app-misc/geoclue-2.3.1:2.0
+	>=dev-libs/libgweather-3.9.5:2=
+	>=sci-geosciences/geocode-glib-3.10
+	>=sys-auth/polkit-0.103
+
+	colord? (
+		>=media-libs/lcms-2.2:2
+		>=x11-misc/colord-1.0.2:= )
+	cups? ( >=net-print/cups-1.4[dbus] )
+	input_devices_wacom? (
+		>=dev-libs/libwacom-0.7
+		>=x11-libs/pango-1.20
+		x11-drivers/xf86-input-wacom
+		virtual/libgudev:= )
+	networkmanager? ( >=net-misc/networkmanager-1.0 )
+	smartcard? ( >=dev-libs/nss-3.11.2 )
+	udev? ( virtual/libgudev:= )
+	wayland? ( dev-libs/wayland )
+"
+# logind needed for power and session management, bug #464944
+# gnome-session-3.25.4 adapts to Orientation and XRANDR components removal (moved to mutter)
+RDEPEND="${COMMON_DEPEND}
+	gnome-base/dconf
+	elogind? ( sys-auth/elogind )
+	systemd? ( sys-apps/systemd )
+	!<gnome-base/gnome-session-3.25.4
+"
+DEPEND="${COMMON_DEPEND}
+	test? (
+		${PYTHON_DEPS}
+		$(python_gen_any_dep 'dev-python/pygobject:3[${PYTHON_USEDEP}]')
+		$(python_gen_any_dep 'dev-python/dbusmock[${PYTHON_USEDEP}]')
+		gnome-base/gnome-session )
+	dev-libs/libxml2:2
+	dev-util/glib-utils
+	sys-devel/gettext
+	>=dev-util/intltool-0.40
+	virtual/pkgconfig
+	x11-base/xorg-proto
+"
+
+# Tests go a bit better in 3.26, but still fail some for me; revisit with 3.28+
+RESTRICT="!test? ( test )"
+
+PATCHES=(
+	# upstream gnome-3-26 branch up to its abandonment in February 2018 (many unreleased fixes); requires eautoreconf
+	# Make colord and wacom optional; requires eautoreconf
+	# Allow specifying udevrulesdir via configure, bug 509484; requires eautoreconf
+	# Fix build system to require gudev with wayland, bug #627966; requires eautoreconf
+	"${WORKDIR}"/patches/
+)
+
+python_check_deps() {
+	if use test; then
+		has_version "dev-python/pygobject:3[${PYTHON_USEDEP}]" &&
+		has_version "dev-python/dbusmock[${PYTHON_USEDEP}]"
+	fi
+}
+
+pkg_setup() {
+	use test && python-any-r1_pkg_setup
+}
+
+src_configure() {
+	gnome2_src_configure \
+		--disable-static \
+		--with-udevrulesdir="$(get_udevdir)"/rules.d \
+		$(use_enable colord color) \
+		$(use_enable cups) \
+		$(use_enable debug) \
+		$(use_enable debug more-warnings) \
+		$(use_enable networkmanager network-manager) \
+		$(use_enable smartcard smartcard-support) \
+		$(use_enable udev gudev) \
+		$(use_enable input_devices_wacom wacom) \
+		$(use_enable wayland)
+}
+
+src_test() {
+	virtx emake check
+}

diff --git a/gnome-base/gnome-settings-daemon/metadata.xml b/gnome-base/gnome-settings-daemon/metadata.xml
index 7ddc604ee2f..3b84b19df41 100644
--- a/gnome-base/gnome-settings-daemon/metadata.xml
+++ b/gnome-base/gnome-settings-daemon/metadata.xml
@@ -6,8 +6,9 @@
 		<name>Gentoo GNOME Desktop</name>
 	</maintainer>
 	<use>
-		<flag name="colord">Support color management using
-			<pkg>x11-misc/colord</pkg></flag>
+		<flag name="colord">Support color management using <pkg>x11-misc/colord</pkg></flag>
+		<flag name="elogind">Rely on <pkg>sys-auth/elogind</pkg> as runtime logind provider</flag>
+		<flag name="systemd">Rely on <pkg>sys-apps/systemd</pkg> as runtime logind provider</flag>
 		<flag name="openrc-force">Skip systemd dependency (#480336),
 			enabling this flag will become your setup to be fully
 			unsupported by upstream and downstream Gnome team. Do not