[gentoo-commits] repo/gentoo:master commit in: www-client/opera/

[Stephan Hartmann]

commit:     8f95f81c9a70f5cc12c7dd2414ae583f6ee921ff
Author:     Stephan Hartmann <sultan <AT> gentoo <DOT> org>
AuthorDate: Wed Jun  9 20:46:00 2021 +0000
Commit:     Stephan Hartmann <sultan <AT> gentoo <DOT> org>
CommitDate: Wed Jun  9 20:46:00 2021 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=8f95f81c

www-client/opera: remove old

Package-Manager: Portage-3.0.18, Repoman-3.0.2
Signed-off-by: Stephan Hartmann <sultan <AT> gentoo.org>

 www-client/opera/Manifest                   |   2 -
 www-client/opera/opera-76.0.4017.175.ebuild | 132 ----------------------------
 2 files changed, 134 deletions(-)

diff --git a/www-client/opera/Manifest b/www-client/opera/Manifest
index f48dfbb4aad..d33c68691cd 100644
--- a/www-client/opera/Manifest
+++ b/www-client/opera/Manifest
@@ -1,4 +1,2 @@
-DIST opera-ffmpeg-codecs-90.0.4412.3.tar.xz 1392160 BLAKE2B 61f32ac1ac3ec12f39324e1e91aef59f9693e36d19abeb92b223e7b95411d5b2a7c2e7ecac87c5a59d374a61bc2ea0f6b2738d01860a1df013d1111876acb888 SHA512 4f56c70bb6e57c978c4997f30473454ccf51308818bf9debadfa0fe4d68ce10c7e333fb49ae4152b355f442b06cfcfb4c0fa130db4de9937374dc5c589c56a70
 DIST opera-ffmpeg-codecs-91.0.4472.19.tar.xz 1383552 BLAKE2B f278bcef8ec013e24bb5293f50cb82be8b9381d181d6e837e8ed0f5b5f7fbdbde4d6e16e30787def46c333f2d6fb7573c7fbdf09697400d9429b3bc154a8da92 SHA512 58c419e469f257e5d3a7ec2fb18885a61aa8f4d6a56f8f6922fb4d4cecbfd9267d7cd72a451d1b23ee88bad0bebd83affa0850a1bbf7b2b26dac398752c7e905
-DIST opera-stable_76.0.4017.175_amd64.deb 74332528 BLAKE2B dc2d81a7402f35e644ddac6cb4b1ec0f622974f52d2000900e130e1c2d83ac9d5682e42bc5ab35961a19b025b941766d899d3a446b19a2e36db73a3dd2eddf0f SHA512 5277d86984c9fc3ef2cd44dee2e2188942adf9418f7f07ee6d80d79e27d1ed345347e8f2c7ae0394cdcc1629d16bb8a800bed953fd6edfbe1dcea6a02f5416e5
 DIST opera-stable_77.0.4054.60_amd64.deb 74302224 BLAKE2B c704d104fd5eb6a48cd7c7fe35c7f8c40326655aa5e0c351906e86d25227a31b9e74e66c4b7b28b43120d9def3f890db17997af92a462bebfa08c2669c8ca215 SHA512 bb8bbab8c564e277ce60774a9719f0b4b0faef0ce12ebf59b165069e73073b4baa6f676b60f63bbe907e3211ad106f0412bc2b87fe07ae9c90fd90fde0232650

diff --git a/www-client/opera/opera-76.0.4017.175.ebuild b/www-client/opera/opera-76.0.4017.175.ebuild
deleted file mode 100644
index ea73c8d6e29..00000000000
--- a/www-client/opera/opera-76.0.4017.175.ebuild
+++ /dev/null
@@ -1,132 +0,0 @@
-# Copyright 1999-2021 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=7
-CHROMIUM_LANGS="
-	be bg bn ca cs da de el en-GB en-US es-419 es fil fi fr-CA fr hi hr hu id
-	it ja ko lt lv ms nb nl pl pt-BR pt-PT ro ru sk sr sv sw ta te th tr uk vi
-	zh-CN zh-TW
-"
-inherit chromium-2 multilib pax-utils unpacker xdg
-
-DESCRIPTION="A fast and secure web browser"
-HOMEPAGE="https://www.opera.com/"
-LICENSE="OPERA-2018"
-SLOT="0"
-
-SRC_URI_BASE=(
-	"https://download1.operacdn.com/pub/${PN}"
-	"https://download2.operacdn.com/pub/${PN}"
-	"https://download3.operacdn.com/pub/${PN}"
-	"https://download4.operacdn.com/pub/${PN}"
-)
-
-if [[ ${PN} == opera ]]; then
-	MY_PN=${PN}-stable
-	SRC_URI_BASE=( "${SRC_URI_BASE[@]/%//desktop}" )
-else
-	MY_PN=${PN}
-fi
-
-KEYWORDS="-* amd64"
-
-FFMPEG_VERSION="90.0.4412.3"
-
-SRC_URI="${SRC_URI_BASE[@]/%//${PV}/linux/${MY_PN}_${PV}_amd64.deb}
-	proprietary-codecs? (
-		https://dev.gentoo.org/~sultan/distfiles/www-client/opera/opera-ffmpeg-codecs-${FFMPEG_VERSION}.tar.xz
-	)"
-
-IUSE="+proprietary-codecs suid"
-RESTRICT="bindist mirror strip"
-
-RDEPEND="
-	app-accessibility/at-spi2-atk:2
-	app-accessibility/at-spi2-core:2
-	dev-libs/atk
-	dev-libs/expat
-	dev-libs/glib:2
-	dev-libs/nspr
-	dev-libs/nss
-	gnome-base/gsettings-desktop-schemas
-	media-libs/alsa-lib
-	media-libs/mesa[gbm]
-	net-misc/curl
-	net-print/cups
-	sys-apps/dbus
-	x11-libs/cairo
-	x11-libs/gdk-pixbuf
-	x11-libs/gtk+:3
-	x11-libs/libdrm
-	x11-libs/libxcb
-	x11-libs/libxkbcommon
-	x11-libs/libX11
-	x11-libs/libXcomposite
-	x11-libs/libXdamage
-	x11-libs/libXext
-	x11-libs/libXfixes
-	x11-libs/libXrandr
-	x11-libs/pango
-"
-
-QA_PREBUILT="*"
-S=${WORKDIR}
-OPERA_HOME="opt/opera${PN#opera}"
-
-pkg_pretend() {
-	# Protect against people using autounmask overzealously
-	use amd64 || die "opera only works on amd64"
-}
-
-pkg_setup() {
-	chromium_suid_sandbox_check_kernel_config
-}
-
-src_unpack() {
-	:
-}
-
-src_install() {
-	dodir /
-	cd "${ED}" || die
-	unpacker
-
-	# move to /opt, bug #573052
-	mkdir -p "${OPERA_HOME%${PN}}"
-	mv "usr/lib/x86_64-linux-gnu/${PN}" "${OPERA_HOME%${PN}}" || die
-	rm -r "usr/lib" || die
-
-	# disable auto update
-	rm "${OPERA_HOME}/${PN%-*}_autoupdate"{,.licenses,.version} || die
-
-	rm -r "usr/share/lintian" || die
-
-	# fix docs
-	mv usr/share/doc/${MY_PN} usr/share/doc/${PF} || die
-	gzip -d usr/share/doc/${PF}/changelog.gz || die
-
-	# fix desktop file
-	sed -i \
-		-e 's|^TargetEnvironment|X-&|g' \
-		usr/share/applications/${PN}.desktop || die
-
-	# remove unused language packs
-	pushd "${OPERA_HOME}/localization" > /dev/null || die
-	chromium_remove_language_paks
-	popd > /dev/null || die
-
-	# setup opera symlink
-	rm "usr/bin/${PN}" || die
-	dosym "../../${OPERA_HOME}/${PN}" "/usr/bin/${PN}"
-
-	# install proprietary codecs
-	rm "${OPERA_HOME}/resources/ffmpeg_preload_config.json" || die
-	if use proprietary-codecs; then
-		mv lib_extra "${OPERA_HOME}"
-	fi
-
-	# pax mark opera, bug #562038
-	pax-mark m "${OPERA_HOME}/opera"
-	# enable suid sandbox if requested
-	use suid && fperms 4711 "${OPERA_HOME}/opera_sandbox"
-}