[gentoo-commits] gentoo-x86 commit in dev-libs/ace: ace-5.7.2.ebuild ChangeLog

[Patrick Lauer (patrick)]

patrick     09/09/01 09:36:05

  Modified:             ChangeLog
  Added:                ace-5.7.2.ebuild
  Log:
  Bump to 5.7.2, fixes #281651. Thanks to Priit Laes for the ebuild patch.
  (Portage version: 2.2_rc40/cvs/Linux x86_64)

Revision  Changes    Path
1.58                 dev-libs/ace/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-libs/ace/ChangeLog?rev=1.58&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-libs/ace/ChangeLog?rev=1.58&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-libs/ace/ChangeLog?r1=1.57&r2=1.58

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/dev-libs/ace/ChangeLog,v
retrieving revision 1.57
retrieving revision 1.58
diff -u -r1.57 -r1.58
--- ChangeLog	14 Dec 2008 11:56:46 -0000	1.57
+++ ChangeLog	1 Sep 2009 09:36:04 -0000	1.58
@@ -1,6 +1,11 @@
 # ChangeLog for dev-libs/ace
-# Copyright 2002-2008 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-libs/ace/ChangeLog,v 1.57 2008/12/14 11:56:46 mrness Exp $
+# Copyright 1999-2009 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/dev-libs/ace/ChangeLog,v 1.58 2009/09/01 09:36:04 patrick Exp $
+
+*ace-5.7.2 (01 Sep 2009)
+
+  01 Sep 2009; Patrick Lauer <patrick@g.o> +ace-5.7.2.ebuild:
+  Bump to 5.7.2, fixes #281651. Thanks to Priit Laes for the ebuild patch.
 
 *ace-5.6.5-r2 (14 Dec 2008)
 



1.1                  dev-libs/ace/ace-5.7.2.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-libs/ace/ace-5.7.2.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-libs/ace/ace-5.7.2.ebuild?rev=1.1&content-type=text/plain

Index: ace-5.7.2.ebuild
===================================================================
# Copyright 1999-2009 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-libs/ace/ace-5.7.2.ebuild,v 1.1 2009/09/01 09:36:04 patrick Exp $

inherit toolchain-funcs eutils

DESCRIPTION="The Adaptive Communications Environment"
HOMEPAGE="http://www.cs.wustl.edu/~schmidt/ACE.html"
SRC_URI="!tao? ( http://download.dre.vanderbilt.edu/previous_versions/ACE-${PV}.tar.bz2 )
	tao? (
		!ciao? ( http://download.dre.vanderbilt.edu/previous_versions/ACE+TAO-${PV}.tar.bz2 )
		ciao? ( http://download.dre.vanderbilt.edu/previous_versions/ACE+TAO+CIAO-${PV}.tar.bz2 )
	)"
LICENSE="BSD as-is"
SLOT="0"
KEYWORDS="~x86 ~sparc ~ppc ~alpha ~amd64"
IUSE="X ipv6 tao ciao"

COMMON_DEPEND="dev-libs/openssl"
# TODO probably more
RDEPEND="${COMMON_DEPEND}
	X? ( x11-libs/libXt x11-libs/libXaw )"

DEPEND="${COMMON_DEPEND}
	X? ( x11-proto/xproto )"

S="${WORKDIR}/ACE_wrappers"

src_compile() {
	export ACE_ROOT="${S}"
	mkdir build
	cd build

	ECONF_SOURCE="${S}"
	econf \
		--enable-lib-all \
		$(use_with X) \
		$(use_enable ipv6) \
		|| die "econf died"
	# --with-qos needs ACE_HAS_RAPI
	emake static_libs=1 || die "emake failed"
}

src_install() {
	cd build
	emake ACE_ROOT="${S}" DESTDIR="${D}" install || die "failed to install"
	# punt gperf stuff
	rm -rf "${D}/usr/bin" "${D}/usr/share"
	# remove PACKAGE_* definitions from installed config.h (#192676)
	sed -i -e "s:^[ \t]*#define[ \t]\+PACKAGE_.*$:/\* & \*/:g" "${D}/usr/include/ace/config.h"

	# Install some docs
	cd "${S}"
	dodoc README NEWS ChangeLog AUTHORS VERSION Release || die
}

src_test() {
	cd "${S}/build"
	emake ACE_ROOT="${S}" check || die "self test failed"
}

pkg_postinst() {

	local CC_MACHINE=$($(tc-getCC) -dumpmachine)
	if [ -d "/usr/$(get_libdir)/gcc-lib/${CC_MACHINE}/$(gcc-fullversion)/include/ace" ]; then
	ewarn "moving /usr/$(get_libdir)/gcc-lib/${CC_MACHINE}/$(gcc-fullversion)/include/ace to"
	ewarn "ace.old"
	ewarn "This is required, as anything trying to compile against ACE will"
	ewarn "have problems with conflicting OS.h files if this is not done."
		mv "/usr/$(get_libdir)/gcc-lib/${CC_MACHINE}/$(gcc-fullversion)/include/ace" \
			"/usr/$(get_libdir)/gcc-lib/${CC_MACHINE}/$(gcc-fullversion)/include/ace.old"
	fi
}