[gentoo-commits] gentoo-x86 commit in dev-libs/ustr: ustr-1.0.4-r5.ebuild ChangeLog

[Sven Vermeulen (swift)]

swift       14/06/02 19:17:53

  Modified:             ChangeLog
  Added:                ustr-1.0.4-r5.ebuild
  Log:
  Update multilib support in ustr with many thanks to Arfrever
  
  (Portage version: 2.2.8-r1/cvs/Linux x86_64, signed Manifest commit with key 0x2EDD52403B68AF47)

Revision  Changes    Path
1.15                 dev-libs/ustr/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-libs/ustr/ChangeLog?rev=1.15&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-libs/ustr/ChangeLog?rev=1.15&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-libs/ustr/ChangeLog?r1=1.14&r2=1.15

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/dev-libs/ustr/ChangeLog,v
retrieving revision 1.14
retrieving revision 1.15
diff -u -r1.14 -r1.15
--- ChangeLog	30 May 2014 13:59:12 -0000	1.14
+++ ChangeLog	2 Jun 2014 19:17:53 -0000	1.15
@@ -1,6 +1,11 @@
 # ChangeLog for dev-libs/ustr
 # Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-libs/ustr/ChangeLog,v 1.14 2014/05/30 13:59:12 swift Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-libs/ustr/ChangeLog,v 1.15 2014/06/02 19:17:53 swift Exp $
+
+*ustr-1.0.4-r5 (02 Jun 2014)
+
+  02 Jun 2014; Sven Vermeulen <swift@g.o> +ustr-1.0.4-r5.ebuild:
+  Update multilib support in ustr with many thanks to Arfrever
 
 *ustr-1.0.4-r4 (30 May 2014)
 



1.1                  dev-libs/ustr/ustr-1.0.4-r5.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-libs/ustr/ustr-1.0.4-r5.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-libs/ustr/ustr-1.0.4-r5.ebuild?rev=1.1&content-type=text/plain

Index: ustr-1.0.4-r5.ebuild
===================================================================
# Copyright 1999-2014 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-libs/ustr/ustr-1.0.4-r5.ebuild,v 1.1 2014/06/02 19:17:53 swift Exp $

EAPI=5

inherit toolchain-funcs multilib-minimal

DESCRIPTION="Low-overhead managed string library for C"
HOMEPAGE="http://www.and.org/ustr"
SRC_URI="ftp://ftp.and.org/pub/james/ustr/${PV}/${P}.tar.bz2"

LICENSE="|| ( BSD-2 MIT LGPL-2 )"
SLOT="0"
KEYWORDS="~amd64 ~arm ~mips ~x86"
IUSE=""

DEPEND=""
RDEPEND=""

DOCS=(ChangeLog README README-DEVELOPERS AUTHORS NEWS TODO)

MULTILIB_WRAPPED_HEADERS=(
	/usr/include/ustr-conf.h
	/usr/include/ustr-conf-debug.h
)

src_prepare() {
	multilib_copy_sources
}

multilib_src_compile() {
	emake \
		AR="$(tc-getAR)" \
		CC="$(tc-getCC)" \
		CFLAGS="${CFLAGS}" \
		LDFLAGS="${LDFLAGS}" \
		prefix="${EPREFIX}/usr" \
		SHRDIR="/usr/share/${P}" \
		HIDE= \
		all-shared
}

multilib_src_install() {
	emake \
		DESTDIR="${D}" \
		prefix="${EPREFIX}/usr" \
		libdir="${EPREFIX}/usr/$(get_libdir)" \
		mandir="/usr/share/man" \
		SHRDIR="/usr/share/${P}" \
		DOCSHRDIR="/usr/share/doc/${PF}" \
		HIDE= \
		install
}

multilib_src_test() {
	emake \
		AR="$(tc-getAR)" \
		CC="$(tc-getCC)" \
		CFLAGS="${CFLAGS}" \
		LDFLAGS="${LDFLAGS}" \
		prefix="${EPREFIX}/usr" \
		SHRDIR="/usr/share/${P}" \
		HIDE= \
		check
}