[gentoo-commits] repo/gentoo:master commit in: sci-electronics/pulseview/

[Sven Wegener]

commit:     2d6715cd9bf62f28d1ad730db7d7bbc71a1906b3
Author:     Sven Wegener <swegener <AT> gentoo <DOT> org>
AuthorDate: Sat Nov  3 11:00:26 2018 +0000
Commit:     Sven Wegener <swegener <AT> gentoo <DOT> org>
CommitDate: Sat Nov  3 11:02:17 2018 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=2d6715cd

sci-electronics/pulseview: Version bump

Signed-off-by: Sven Wegener <swegener <AT> gentoo.org>
Package-Manager: Portage-2.3.49, Repoman-2.3.11

 sci-electronics/pulseview/Manifest               |  1 +
 sci-electronics/pulseview/pulseview-0.4.1.ebuild | 61 ++++++++++++++++++++++++
 2 files changed, 62 insertions(+)

diff --git a/sci-electronics/pulseview/Manifest b/sci-electronics/pulseview/Manifest
index aefa9dd63d3..c469f58b832 100644
--- a/sci-electronics/pulseview/Manifest
+++ b/sci-electronics/pulseview/Manifest
@@ -1 +1,2 @@
 DIST pulseview-0.4.0.tar.gz 226656 BLAKE2B 308026926484daa1c414c1f1fe40b06882a3ae9f63df076e8431550d9666bbcc46bb9184fceae94dd2aa5786d08d32b0313167df6800a3849e5383ccb4be67a4 SHA512 833a86681925fb4fb2118bb9d0044fc80174aef299b7e6ba2df83bff490511b91cd18f63f45e9a63f21c0df5d8aad3ec27ab35f45cd9959a42831b0b8a71da33
+DIST pulseview-0.4.1.tar.gz 1342532 BLAKE2B 759779d4024df8f972fbed515764f17557014972abcb39d3942b411bfa78c6f97a89ee98b706adb51d240bdb738925546cec073f98ba829f1e325acaac892c01 SHA512 0bae4357be312bf6e997885270887a5bcc0a8dfb6914e63bb0d5abb35389b6681748e0e4667556ad432c5432c861185bcdd8da7815fb570fc8a2fbbf5eed3801

diff --git a/sci-electronics/pulseview/pulseview-0.4.1.ebuild b/sci-electronics/pulseview/pulseview-0.4.1.ebuild
new file mode 100644
index 00000000000..61c3fc56308
--- /dev/null
+++ b/sci-electronics/pulseview/pulseview-0.4.1.ebuild
@@ -0,0 +1,61 @@
+# Copyright 1999-2018 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI="6"
+
+PYTHON_COMPAT=( python3_{4,5,6} )
+
+inherit cmake-utils gnome2-utils python-single-r1 xdg-utils
+
+if [[ ${PV} == "9999" ]]; then
+	EGIT_REPO_URI="git://sigrok.org/${PN}"
+	inherit git-r3
+else
+	SRC_URI="https://sigrok.org/download/source/${PN}/${P}.tar.gz"
+	KEYWORDS="~amd64 ~x86"
+fi
+
+DESCRIPTION="Qt based logic analyzer GUI for sigrok"
+HOMEPAGE="https://sigrok.org/wiki/PulseView"
+
+LICENSE="GPL-3"
+SLOT="0"
+IUSE="+decode static"
+REQUIRED_USE="decode? ( ${PYTHON_REQUIRED_USE} )"
+
+RDEPEND="
+	>=dev-libs/boost-1.55:=
+	>=dev-libs/glib-2.28.0:2
+	>=dev-cpp/glibmm-2.28.0:2
+	>=sci-libs/libsigrok-0.5.1:=[cxx]
+	dev-qt/qtcore:5
+	dev-qt/qtgui:5
+	dev-qt/qtwidgets:5
+	dev-qt/qtsvg:5
+	decode? (
+		>=sci-libs/libsigrokdecode-0.5.2:=[${PYTHON_USEDEP}]
+		${PYTHON_DEPS}
+	)"
+DEPEND="${RDEPEND}
+	virtual/pkgconfig"
+
+DOCS=( HACKING NEWS README )
+
+src_configure() {
+	local mycmakeargs=(
+		-DDISABLE_WERROR=TRUE
+		-DENABLE_DECODE=$(usex decode)
+		-DSTATIC_PKGDEPS_LIBS=$(usex static)
+	)
+	cmake-utils_src_configure
+}
+
+pkg_postinst() {
+	gnome2_icon_cache_update
+	xdg_desktop_database_update
+}
+
+pkg_postrm() {
+	gnome2_icon_cache_update
+	xdg_desktop_database_update
+}