[gentoo-commits] repo/gentoo:master commit in: xfce-base/xfce4-settings/

[Michał Górny]

commit:     c437e0c42348b3de5b44922bf412c0d5be26e2f4
Author:     Michał Górny <mgorny <AT> gentoo <DOT> org>
AuthorDate: Tue Nov  1 12:23:08 2022 +0000
Commit:     Michał Górny <mgorny <AT> gentoo <DOT> org>
CommitDate: Tue Nov  1 12:35:52 2022 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=c437e0c4

xfce-base/xfce4-settings: Bump to 4.17.0

Signed-off-by: Michał Górny <mgorny <AT> gentoo.org>

 xfce-base/xfce4-settings/Manifest                  |  1 +
 .../xfce4-settings/xfce4-settings-4.17.0.ebuild    | 74 ++++++++++++++++++++++
 2 files changed, 75 insertions(+)

diff --git a/xfce-base/xfce4-settings/Manifest b/xfce-base/xfce4-settings/Manifest
index 8e3d97c27312..33cfc1fb19c6 100644
--- a/xfce-base/xfce4-settings/Manifest
+++ b/xfce-base/xfce4-settings/Manifest
@@ -1 +1,2 @@
 DIST xfce4-settings-4.16.3.tar.bz2 1462300 BLAKE2B 64bd149eea6afa4054e59b7ffa29327298aae4584d4b4a17dff12480bd0e3b017c152efc2e06201d39397f27c3bedc633715383473a8bc3c32aff4a97091e683 SHA512 62183e500d97625c079cc95c900fb6afae8e08a24d5e0574fcfd0a803eb4e7e10095a527a76a0cd4b5f2abb944203650ccbbb78ab21e024df6b4da670159896b
+DIST xfce4-settings-4.17.0.tar.bz2 1516111 BLAKE2B 73534c638977eade7a35ff02f804e822fc48df46f798ef542c9d4a19545c66eea532f8a09ea5595ba84ded188375213b2f4f31254c86851449411f472a5afce3 SHA512 23d49daa8be7b9cb4ce4bbdf1153001bf93e6ab35efcc7273f264f0c23e3f3fe8d1875d43853cc895d2db1baa7d0d0f49d748ebff61d113c79b497a832e19a8f

diff --git a/xfce-base/xfce4-settings/xfce4-settings-4.17.0.ebuild b/xfce-base/xfce4-settings/xfce4-settings-4.17.0.ebuild
new file mode 100644
index 000000000000..1408aab9e199
--- /dev/null
+++ b/xfce-base/xfce4-settings/xfce4-settings-4.17.0.ebuild
@@ -0,0 +1,74 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{8..11} )
+
+inherit python-single-r1 xdg-utils
+
+DESCRIPTION="Configuration system for the Xfce desktop environment"
+HOMEPAGE="
+	https://docs.xfce.org/xfce/xfce4-settings/start
+	https://gitlab.xfce.org/xfce/xfce4-settings/
+"
+SRC_URI="https://archive.xfce.org/src/xfce/${PN}/${PV%.*}/${P}.tar.bz2"
+
+LICENSE="GPL-2+"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~mips ~ppc ~ppc64 ~riscv ~sparc ~x86 ~amd64-linux ~x86-linux"
+IUSE="colord input_devices_libinput libcanberra libnotify upower +xklavier"
+REQUIRED_USE=${PYTHON_REQUIRED_USE}
+
+RDEPEND="
+	${PYTHON_DEPS}
+	>=dev-libs/glib-2.50
+	media-libs/fontconfig
+	>=x11-libs/gtk+-3.20:3
+	x11-libs/libX11
+	>=x11-libs/libXcursor-1.1
+	>=x11-libs/libXi-1.3
+	>=x11-libs/libXrandr-1.2
+	>=xfce-base/garcon-0.2:=
+	>=xfce-base/exo-4.15.1:=
+	>=xfce-base/libxfce4ui-4.17.0:=
+	>=xfce-base/libxfce4util-4.17.2:=
+	>=xfce-base/xfconf-4.13:=
+	colord? ( x11-misc/colord:= )
+	libcanberra? ( >=media-libs/libcanberra-0.25[sound] )
+	input_devices_libinput? ( x11-drivers/xf86-input-libinput )
+	libnotify? ( >=x11-libs/libnotify-0.7 )
+	upower? ( >=sys-power/upower-0.9.23 )
+	xklavier? ( >=x11-libs/libxklavier-5 )
+	!<xfce-base/exo-4.15.1
+"
+DEPEND="
+	${RDEPEND}
+	x11-base/xorg-proto
+"
+BDEPEND="
+	dev-util/gdbus-codegen
+	dev-util/intltool
+	virtual/pkgconfig
+	sys-devel/gettext
+"
+
+src_configure() {
+	local myconf=(
+		$(use_enable upower upower-glib)
+		$(use_enable input_devices_libinput xorg-libinput)
+		$(use_enable libnotify)
+		$(use_enable colord)
+		$(use_enable xklavier libxklavier)
+		$(use_enable libcanberra sound-settings)
+	)
+	econf "${myconf[@]}"
+}
+
+pkg_postinst() {
+	xdg_icon_cache_update
+}
+
+pkg_postrm() {
+	xdg_icon_cache_update
+}