[gentoo-commits] repo/gentoo:master commit in: media-sound/bluez-alsa/

[Lars Wendler]

commit:     b247f4a85507927f503664fda9ac9ff3bc9888c2
Author:     Lars Wendler <polynomial-c <AT> gentoo <DOT> org>
AuthorDate: Fri Apr 14 10:12:28 2017 +0000
Commit:     Lars Wendler <polynomial-c <AT> gentoo <DOT> org>
CommitDate: Fri Apr 14 10:12:45 2017 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=b247f4a8

media-sound/bluez-alsa: Bump to version 1.2.0 (bug #615526).

Package-Manager: Portage-2.3.5, Repoman-2.3.2

 media-sound/bluez-alsa/Manifest                |  1 +
 media-sound/bluez-alsa/bluez-alsa-1.2.0.ebuild | 58 ++++++++++++++++++++++++++
 2 files changed, 59 insertions(+)

diff --git a/media-sound/bluez-alsa/Manifest b/media-sound/bluez-alsa/Manifest
index 17dfe12c623..e76eb7c9212 100644
--- a/media-sound/bluez-alsa/Manifest
+++ b/media-sound/bluez-alsa/Manifest
@@ -1 +1,2 @@
 DIST bluez-alsa-1.1.0.tar.gz 73676 SHA256 93396e581c196f9283d5907c7b8059ded21f5ec75a58f1c96f01d9ba295f5179 SHA512 167fa45994b57b0b44d5827762638d36ef782d7789c229e5c1ca99b59c13636dc53161cd45bec41e61890acd38b44d20778bc2085385582329a1c666530b21f1 WHIRLPOOL 2faba9fbd57fac2a519fe382c8a98654159a51819fea11da93ea3e198d31e51d3357bf2effa9df31713c2f201717dbd395a721efa81c9000a4da15df7e542a70
+DIST bluez-alsa-1.2.0.tar.gz 63662 SHA256 0a7a27e8cf135ec6bb30ea1a2365736681ced7d8293003c274fa78319f936838 SHA512 a6bf0068b3fb88acaa11990db411f1d3be7ad19219e7bdfd091fe81acc2ba5d5992dfb377e4fcc332ac330bb7e5ab5e4f4a9cee3e700e366fd983e81a272a5b4 WHIRLPOOL 5f4e3469b72dd375b946bb551edf318ec20e47490ec93d5fd54b0980a49a3b54f66f59f3bd65c65ce019d00f6808aa306025f0f0c045049d8fb62d7ff25f5f51

diff --git a/media-sound/bluez-alsa/bluez-alsa-1.2.0.ebuild b/media-sound/bluez-alsa/bluez-alsa-1.2.0.ebuild
new file mode 100644
index 00000000000..8b3787db68d
--- /dev/null
+++ b/media-sound/bluez-alsa/bluez-alsa-1.2.0.ebuild
@@ -0,0 +1,58 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+inherit autotools eutils multilib-minimal
+
+DESCRIPTION="Bluetooth Audio ALSA Backend"
+HOMEPAGE="https://github.com/Arkq/bluez-alsa"
+
+if [[ ${PV} == "9999" ]] ; then
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/Arkq/${PN}"
+else
+	SRC_URI="https://github.com/Arkq/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+	KEYWORDS="~amd64 ~x86"
+fi
+
+LICENSE="MIT"
+SLOT="0"
+IUSE="aac debug hcitop"
+
+RDEPEND=">=dev-libs/glib-2.16[dbus,${MULTILIB_USEDEP}]
+	>=media-libs/alsa-lib-1.0[${MULTILIB_USEDEP}]
+	>=media-libs/sbc-1.2[${MULTILIB_USEDEP}]
+	>=net-wireless/bluez-5[${MULTILIB_USEDEP}]
+	aac? ( >=media-libs/fdk-aac-0.1.1[${MULTILIB_USEDEP}] )
+	hcitop? (
+		dev-libs/libbsd
+		sys-libs/ncurses:0=
+	)"
+DEPEND="${RDEPEND}
+	net-libs/ortp
+	virtual/pkgconfig"
+
+src_prepare() {
+	default
+	eautoreconf
+}
+
+multilib_src_configure() {
+	ECONF_SOURCE="${S}" \
+	econf \
+		$(use_enable aac) \
+		$(use_enable debug) \
+		$(multilib_native_use_enable hcitop)
+}
+
+multilib_src_install_all() {
+	default
+	prune_libtool_files --modules
+
+	newinitd "${FILESDIR}"/bluealsa-init.d bluealsa
+	newconfd "${FILESDIR}"/bluealsa-conf.d bluealsa
+}
+
+pkg_postinst() {
+	elog "Users can use this service when they are members of the \"audio\" group."
+}