[gentoo-commits] repo/gentoo:master commit in: app-pda/libplist/

[Michał Górny]

commit:     24cd543b2081a54c09225e6bf7e663372305468a
Author:     Michał Górny <mgorny <AT> gentoo <DOT> org>
AuthorDate: Wed Dec  9 21:58:40 2015 +0000
Commit:     Michał Górny <mgorny <AT> gentoo <DOT> org>
CommitDate: Wed Dec  9 22:01:17 2015 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=24cd543b

app-pda/libplist: Switch to python-single-r1, disable py3

Replace the semi-broken Python support code in ebuild with
python-single-r1. The original code used python-r1 and rebuilt the whole
package (incl. C libraries) for each implementation, even when Python
support was explicitly disabled.

Furthermore, the used autoconf macros break with Python 3.2+. Therefore,
the Python 3 support has been disabled entirely until the relevant code
is fixed.

Bug: https://bugs.gentoo.org/show_bug.cgi?id=567370

 app-pda/libplist/libplist-1.11-r1.ebuild | 56 ++++++++++++++++++++++++++++++++
 1 file changed, 56 insertions(+)

diff --git a/app-pda/libplist/libplist-1.11-r1.ebuild b/app-pda/libplist/libplist-1.11-r1.ebuild
new file mode 100644
index 0000000..2fa2438
--- /dev/null
+++ b/app-pda/libplist/libplist-1.11-r1.ebuild
@@ -0,0 +1,56 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+# ac_python_devel.m4 is broken with python3
+PYTHON_COMPAT=( python2_7 )
+inherit python-single-r1
+
+DESCRIPTION="Support library to deal with Apple Property Lists (Binary & XML)"
+HOMEPAGE="http://www.libimobiledevice.org/"
+SRC_URI="http://www.libimobiledevice.org/downloads/${P}.tar.bz2"
+
+LICENSE="GPL-2 LGPL-2.1"
+SLOT="0/2" # based on SONAME of libplist.so
+KEYWORDS="~amd64 ~arm ~ppc ~ppc64 ~x86 ~amd64-fbsd"
+IUSE="python static-libs"
+
+RDEPEND=">=dev-libs/libxml2-2.7.8"
+DEPEND="${RDEPEND}
+	virtual/pkgconfig
+	python? (
+		${PYTHON_DEPS}
+		>=dev-python/cython-0.17[${PYTHON_USEDEP}]
+		)"
+
+REQUIRED_USE="python? ( ${PYTHON_REQUIRED_USE} )"
+
+DOCS=( AUTHORS NEWS README )
+
+RESTRICT="test" # TODO: src_test() was dropped from 1.10 (cmake) -> 1.11 (autotools)
+
+pkg_setup() {
+	use python && python-single-r1_pkg_setup
+}
+
+src_configure() {
+	local myeconfargs=( $(use_enable static-libs static) )
+	use python || myeconfargs+=( --without-cython )
+
+	econf "${myeconfargs[@]}"
+}
+
+src_compile() {
+	emake -j1 #406365
+}
+
+src_install() {
+	default
+	find "${D}" -name '*.la' -delete || die
+
+	if use python; then
+		insinto /usr/include/plist/cython
+		doins cython/plist.pxd
+	fi
+}