[gentoo-commits] gentoo-x86 commit in dev-libs/gmime: metadata.xml gmime-2.6.19-r1.ebuild ChangeLog gmime-2.6.18-r1.ebuild

[Pacho Ramos (pacho)]

pacho       14/01/01 21:06:25

  Modified:             metadata.xml ChangeLog
  Added:                gmime-2.6.19-r1.ebuild
  Removed:              gmime-2.6.18-r1.ebuild
  Log:
  Apply upstream patches fixing a memory leak and the addition of an extra space in References (#496692 by Amadeusz Zolnowski), drop old. Gmime is only being maintained by us for years.
  
  (Portage version: 2.2.7/cvs/Linux x86_64, signed Manifest commit with key A188FBD4)

Revision  Changes    Path
1.3                  dev-libs/gmime/metadata.xml

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-libs/gmime/metadata.xml?rev=1.3&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-libs/gmime/metadata.xml?rev=1.3&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-libs/gmime/metadata.xml?r1=1.2&r2=1.3

Index: metadata.xml
===================================================================
RCS file: /var/cvsroot/gentoo-x86/dev-libs/gmime/metadata.xml,v
retrieving revision 1.2
retrieving revision 1.3
diff -u -r1.2 -r1.3
--- metadata.xml	20 Sep 2008 22:10:38 -0000	1.2
+++ metadata.xml	1 Jan 2014 21:06:25 -0000	1.3
@@ -1,6 +1,5 @@
 <?xml version="1.0" encoding="UTF-8"?>
 <!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
 <pkgmetadata>
-<herd>net-mail</herd>
 <herd>gnome</herd>
 </pkgmetadata>



1.236                dev-libs/gmime/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-libs/gmime/ChangeLog?rev=1.236&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-libs/gmime/ChangeLog?rev=1.236&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-libs/gmime/ChangeLog?r1=1.235&r2=1.236

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/dev-libs/gmime/ChangeLog,v
retrieving revision 1.235
retrieving revision 1.236
diff -u -r1.235 -r1.236
--- ChangeLog	22 Dec 2013 15:50:54 -0000	1.235
+++ ChangeLog	1 Jan 2014 21:06:25 -0000	1.236
@@ -1,6 +1,19 @@
 # ChangeLog for dev-libs/gmime
-# Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-libs/gmime/ChangeLog,v 1.235 2013/12/22 15:50:54 jer Exp $
+# Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/dev-libs/gmime/ChangeLog,v 1.236 2014/01/01 21:06:25 pacho Exp $
+
+*gmime-2.6.19-r1 (01 Jan 2014)
+
+  01 Jan 2014; Pacho Ramos <pacho@g.o>
+  +files/gmime-2.6.19-extra-spaces.patch, +files/gmime-2.6.19-memory-leak.patch,
+  +gmime-2.6.19-r1.ebuild, -files/gmime-2.6.18-close-reference.patch,
+  -files/gmime-2.6.18-code-cleanup.patch,
+  -files/gmime-2.6.18-custom-headers.patch,
+  -files/gmime-2.6.18-mutexes-earlier.patch, -gmime-2.6.18-r1.ebuild,
+  metadata.xml:
+  Apply upstream patches fixing a memory leak and the addition of an extra space
+  in References (#496692 by Amadeusz Zolnowski), drop old. Gmime is only being
+  maintained by us for years.
 
   22 Dec 2013; Jeroen Roovers <jer@g.o> gmime-2.4.33.ebuild,
   gmime-2.6.19.ebuild:



1.1                  dev-libs/gmime/gmime-2.6.19-r1.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-libs/gmime/gmime-2.6.19-r1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-libs/gmime/gmime-2.6.19-r1.ebuild?rev=1.1&content-type=text/plain

Index: gmime-2.6.19-r1.ebuild
===================================================================
# Copyright 1999-2014 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-libs/gmime/gmime-2.6.19-r1.ebuild,v 1.1 2014/01/01 21:06:25 pacho Exp $

EAPI="5"
GCONF_DEBUG="no"
VALA_USE_DEPEND="vapigen"

inherit eutils mono-env gnome2 vala

DESCRIPTION="Utilities for creating and parsing messages using MIME"
HOMEPAGE="http://spruce.sourceforge.net/gmime/ http://developer.gnome.org/gmime/stable/"

SLOT="2.6"
LICENSE="LGPL-2.1"
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~ppc ~ppc64 ~sparc ~x86 ~x86-fbsd ~amd64-linux ~x86-linux ~ppc-macos ~x86-macos ~x86-solaris"
IUSE="doc mono static-libs vala"

RDEPEND="
	>=dev-libs/glib-2.18:2
	sys-libs/zlib
	>=app-crypt/gpgme-1.1.6
	mono? (
		dev-lang/mono
		>=dev-dotnet/glib-sharp-2.4.0:2 )
"
DEPEND="${RDEPEND}
	>=dev-util/gtk-doc-am-1.8
	virtual/pkgconfig
	doc? ( app-text/docbook-sgml-utils )
	mono? ( dev-dotnet/gtk-sharp-gapi:2 )
	vala? (
		$(vala_depend)
		>=dev-libs/gobject-introspection-1.30.0 )
"

pkg_setup() {
	use mono && mono-env_pkg_setup
}

src_prepare() {
	# Don't write out extra spaces in the References header (from 'master')
	epatch "${FILESDIR}/${P}-extra-spaces.patch"

	# Fixed a memory leak in g_mime_object_set_content_disposition_parameter (from 'master')
	epatch "${FILESDIR}/${P}-memory-leak.patch"

	gnome2_src_prepare
	use vala && vala_src_prepare
}

src_configure() {
	gnome2_src_configure \
		--enable-cryptography \
		--disable-strict-parser \
		$(use_enable mono) \
		$(use_enable static-libs static) \
		$(use_enable vala)
}

src_compile() {
	MONO_PATH="${S}" gnome2_src_compile
	if use doc; then
		emake -C docs/tutorial html
	fi
}

src_install() {
	GACUTIL_FLAGS="/root '${ED}/usr/$(get_libdir)' /gacdir '${EPREFIX}/usr/$(get_libdir)' /package ${PN}" \
		gnome2_src_install

	if use doc ; then
		docinto tutorial
		dodoc docs/tutorial/html/*
	fi
}