[gentoo-commits] gentoo-x86 commit in net-irc/limnoria: limnoria-20150318.ebuild ChangeLog limnoria-20150208.ebuild

[Ian Delaney (idella4)]

idella4     15/03/30 06:45:21

  Modified:             ChangeLog
  Added:                limnoria-20150318.ebuild
  Removed:              limnoria-20150208.ebuild
  Log:
  bump; add ssl support, temporarily set mock to be built for all python_targets until upstream fixes mock import, rm old by maintainer's discretion
  
  (Portage version: 2.2.18/cvs/Linux x86_64, signed Manifest commit with key 0xB8072B0D)

Revision  Changes    Path
1.2                  net-irc/limnoria/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-irc/limnoria/ChangeLog?rev=1.2&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-irc/limnoria/ChangeLog?rev=1.2&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-irc/limnoria/ChangeLog?r1=1.1&r2=1.2

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-irc/limnoria/ChangeLog,v
retrieving revision 1.1
retrieving revision 1.2
diff -u -r1.1 -r1.2
--- ChangeLog	4 Mar 2015 09:13:38 -0000	1.1
+++ ChangeLog	30 Mar 2015 06:45:21 -0000	1.2
@@ -1,6 +1,13 @@
 # ChangeLog for net-irc/limnoria
 # Copyright 1999-2015 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-irc/limnoria/ChangeLog,v 1.1 2015/03/04 09:13:38 idella4 Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-irc/limnoria/ChangeLog,v 1.2 2015/03/30 06:45:21 idella4 Exp $
+
+*limnoria-20150318 (30 Mar 2015)
+
+  30 Mar 2015; Ian Delaney <idella4@g.o> +limnoria-20150318.ebuild,
+  -limnoria-20150208.ebuild:
+  bump; add ssl support, temporarily set mock to be built for all python_targets
+  until upstream fixes mock import, rm old by maintainer's discretion
 
 *limnoria-20150208 (04 Mar 2015)
 *limnoria-99999999 (04 Mar 2015)



1.1                  net-irc/limnoria/limnoria-20150318.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-irc/limnoria/limnoria-20150318.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-irc/limnoria/limnoria-20150318.ebuild?rev=1.1&content-type=text/plain

Index: limnoria-20150318.ebuild
===================================================================
# Copyright 1999-2015 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-irc/limnoria/limnoria-20150318.ebuild,v 1.1 2015/03/30 06:45:21 idella4 Exp $

EAPI="5"
PYTHON_COMPAT=( python{2_7,3_3,3_4} )

inherit distutils-r1

MY_PV="${PV:0:4}-${PV:4:2}-${PV:6:2}"
MY_PN="Limnoria"
MY_P="${MY_PN}-${MY_PV}"

if [[ ${PV} == "99999999" ]]; then
	EGIT_REPO_URI="git://github.com/ProgVal/Limnoria.git"
	EGIT_BRANCH="master"
	inherit git-r3
	SRC_URI=""
else
	SRC_URI="https://github.com/ProgVal/${MY_PN}/archive/master-${MY_PV}.tar.gz -> ${P}.tar.gz"
	KEYWORDS="~amd64 ~x86"
	S="${WORKDIR}/${MY_PN}-master-${MY_PV}"
fi

DESCRIPTION="Python based extensible IRC infobot and channel bot"
HOMEPAGE="http://supybot.aperio.fr/"
LICENSE="BSD"
SLOT="0"
IUSE="crypt ssl test"

RDEPEND="
	dev-python/charade[${PYTHON_USEDEP}]
	dev-python/ecdsa[${PYTHON_USEDEP}]
	dev-python/feedparser[${PYTHON_USEDEP}]
	dev-python/python-dateutil[${PYTHON_USEDEP}]
	dev-python/pytz[${PYTHON_USEDEP}]
	dev-python/socksipy[${PYTHON_USEDEP}]
	dev-python/sqlalchemy[${PYTHON_USEDEP}]
	crypt? ( dev-python/python-gnupg[${PYTHON_USEDEP}] )
	ssl? ( dev-python/pyopenssl[${PYTHON_USEDEP}] )
	!net-irc/supybot
	!net-irc/supybot-plugins
	"
DEPEND="${RDEPEND}
	test? ( dev-python/mock[${PYTHON_USEDEP}] )"

src_unpack() {
	if [[ ${PV} == "99999999" ]]; then
		git-r3_src_unpack
	else
		unpack ${P}.tar.gz
	fi
}

python_prepare(){
	distutils-r1_python_prepare
	if python_is_python3; then
		einfo "Removing the RSS plugin because of clashes between libxml2's Python3"
		einfo "bindings and feedparser."
		rm -rf "plugins/RSS" || die
	fi
}

python_install_all() {
	distutils-r1_python_install_all
	doman man/*
}

python_test() {
	pushd "${T}" > /dev/null
	PLUGINS_DIR="${BUILD_DIR}/lib/supybot/plugins"
	# recommended by upstream, unknown random failure
	EXCLUDE_PLUGINS=( --exclude="${PLUGINS_DIR}/Scheduler" )
	# recommended by upstream, unknown random failure
	EXCLUDE_PLUGINS+=( --exclude="${PLUGINS_DIR}/Filter" )
	# intermittent failure due to issues loading libsandbox.so from LD_PRELOAD
	# runs successfully when running the tests on the installed system
	EXCLUDE_PLUGINS+=( --exclude="${PLUGINS_DIR}/Unix" )
	"${PYTHON}" "${BUILD_DIR}"/scripts/supybot-test "${BUILD_DIR}/../test" \
		--plugins-dir="${PLUGINS_DIR}" --no-network \
		--disable-multiprocessing "${EXCLUDE_PLUGINS[@]}" \
		|| die "Tests failed under ${EPYTHON}"
	popd > /dev/null
}

pkg_postinst() {
	elog "Complete user documentation is available at https://limnoria-doc.readthedocs.org/"
	elog ""
	elog "Use supybot-wizard to create a configuration file."
	elog "Run supybot </path/to/config> to use the bot."
}