[gentoo-commits] gentoo-x86 commit in dev-util/coccigrep: coccigrep-1.13.ebuild ChangeLog

[Tim Harder (radhermit)]

radhermit    14/02/11 04:30:34

  Modified:             ChangeLog
  Added:                coccigrep-1.13.ebuild
  Log:
  Version bump.
  
  (Portage version: 2.2.8-r1/cvs/Linux x86_64, signed Manifest commit with key 4AB3E85B4F064CA3)

Revision  Changes    Path
1.16                 dev-util/coccigrep/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-util/coccigrep/ChangeLog?rev=1.16&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-util/coccigrep/ChangeLog?rev=1.16&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-util/coccigrep/ChangeLog?r1=1.15&r2=1.16

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/dev-util/coccigrep/ChangeLog,v
retrieving revision 1.15
retrieving revision 1.16
diff -u -r1.15 -r1.16
--- ChangeLog	5 Sep 2013 18:40:35 -0000	1.15
+++ ChangeLog	11 Feb 2014 04:30:34 -0000	1.16
@@ -1,6 +1,11 @@
 # ChangeLog for dev-util/coccigrep
-# Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-util/coccigrep/ChangeLog,v 1.15 2013/09/05 18:40:35 mgorny Exp $
+# Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/dev-util/coccigrep/ChangeLog,v 1.16 2014/02/11 04:30:34 radhermit Exp $
+
+*coccigrep-1.13 (11 Feb 2014)
+
+  11 Feb 2014; Tim Harder <radhermit@g.o> +coccigrep-1.13.ebuild:
+  Version bump.
 
   05 Sep 2013; Michał Górny <mgorny@g.o> coccigrep-1.12.ebuild:
   Clean up PYTHON_COMPAT from old implementations.



1.1                  dev-util/coccigrep/coccigrep-1.13.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-util/coccigrep/coccigrep-1.13.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-util/coccigrep/coccigrep-1.13.ebuild?rev=1.1&content-type=text/plain

Index: coccigrep-1.13.ebuild
===================================================================
# Copyright 1999-2014 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-util/coccigrep/coccigrep-1.13.ebuild,v 1.1 2014/02/11 04:30:34 radhermit Exp $

EAPI=5
PYTHON_COMPAT=( python{2_6,2_7} )

inherit distutils-r1 elisp-common

DESCRIPTION="A semantic grep for the C language"
HOMEPAGE="http://home.regit.org/software/coccigrep/"
SRC_URI="https://github.com/regit/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"

LICENSE="GPL-3"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="doc emacs vim"

RDEPEND="dev-util/coccinelle[python]
	virtual/python-argparse[${PYTHON_USEDEP}]
	emacs? ( virtual/emacs )
	vim? ( || ( app-editors/vim app-editors/gvim ) )"
DEPEND="doc? ( dev-python/sphinx )
	emacs? ( virtual/emacs )"

SITEFILE="50${PN}-gentoo.el"

python_compile_all() {
	use doc && emake -C doc html

	if use emacs ; then
		elisp-compile editors/*.el || die
	fi
}

python_install_all() {
	distutils-r1_python_install_all

	doman ${PN}.1

	use doc && dohtml -r doc/_build/html/*

	if use emacs ; then
		elisp-install ${PN} editors/*.{el,elc} || die
		elisp-site-file-install "${FILESDIR}"/${SITEFILE} || die
	fi

	if use vim ; then
		insinto /usr/share/vim/vimfiles/plugin
		doins editors/cocci-grep.vim
	fi
}

pkg_postinst() {
	use emacs && elisp-site-regen

	einfo "Syntax highlighting is supported through dev-python/pygments."
	einfo "Install it if you want colorized output formats."
}

pkg_postrm() {
	use emacs && elisp-site-regen
}