[gentoo-commits] gentoo-x86 commit in app-backup/cyphertite: cyphertite-2.0.2-r5.ebuild ChangeLog cyphertite-2.0.2-r4.ebuild

[Brian Evans (grknight)]

grknight    14/09/28 16:20:39

  Modified:             ChangeLog
  Added:                cyphertite-2.0.2-r5.ebuild
  Removed:              cyphertite-2.0.2-r4.ebuild
  Log:
  Revbump to adjust dependency USE flags. Thanks to atomic_ on IRC for pointing this out
  
  (Portage version: 2.2.8-r2/cvs/Linux x86_64, signed Manifest commit with key 67C78E1D)

Revision  Changes    Path
1.7                  app-backup/cyphertite/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-backup/cyphertite/ChangeLog?rev=1.7&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-backup/cyphertite/ChangeLog?rev=1.7&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-backup/cyphertite/ChangeLog?r1=1.6&r2=1.7

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/app-backup/cyphertite/ChangeLog,v
retrieving revision 1.6
retrieving revision 1.7
diff -u -r1.6 -r1.7
--- ChangeLog	21 Sep 2014 20:04:40 -0000	1.6
+++ ChangeLog	28 Sep 2014 16:20:39 -0000	1.7
@@ -1,6 +1,13 @@
 # ChangeLog for app-backup/cyphertite
 # Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-backup/cyphertite/ChangeLog,v 1.6 2014/09/21 20:04:40 grknight Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-backup/cyphertite/ChangeLog,v 1.7 2014/09/28 16:20:39 grknight Exp $
+
+*cyphertite-2.0.2-r5 (28 Sep 2014)
+
+  28 Sep 2014; Brian Evans <grknight@g.o> +cyphertite-2.0.2-r5.ebuild,
+  -cyphertite-2.0.2-r4.ebuild:
+  Revbump to adjust dependency USE flags. Thanks to atomic_ on IRC for pointing
+  this out
 
 *cyphertite-2.0.2-r4 (21 Sep 2014)
 



1.1                  app-backup/cyphertite/cyphertite-2.0.2-r5.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-backup/cyphertite/cyphertite-2.0.2-r5.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-backup/cyphertite/cyphertite-2.0.2-r5.ebuild?rev=1.1&content-type=text/plain

Index: cyphertite-2.0.2-r5.ebuild
===================================================================
# Copyright 1999-2014 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/app-backup/cyphertite/cyphertite-2.0.2-r5.ebuild,v 1.1 2014/09/28 16:20:39 grknight Exp $

EAPI=5

inherit toolchain-funcs eutils multilib

DESCRIPTION="High Security, Zero-Knowledge Online Backup"
HOMEPAGE="https://www.cyphertite.com/"
SRC_URI="https://www.cyphertite.com/snapshots/source/${PV}/${PN}-full-${PV}.tar.gz"
LICENSE="ISC"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE=""

DEPEND="
	app-arch/xz-utils:0=
	dev-db/sqlite:3=
	>=dev-libs/openssl-1.0.1g:0=[-bindist]
	dev-libs/expat:0=
	dev-libs/libbsd:0=
	dev-libs/libedit:0=
	dev-libs/libevent:0=
	>=dev-libs/lzo-2.0:2=
	>=net-misc/curl-7.15.1:0=[ssl]
	sys-libs/zlib:0=
"
RDEPEND="${DEPEND}"

src_prepare() {
	# Fix build system that assumes that modules are installed to the live system
	epatch "${FILESDIR}/${P}-fix-build.patch" "${FILESDIR}/${P}-cflags.patch"
}

src_compile() {
	# Package has a home grown Makefile system. Make it work for Gentoo
	emake INCDIR="${S}" WARNFLAGS="-Wall" OPTLEVEL="" DEBUG="" CC="$(tc-getCC)" \
		AR="$(tc-getAR)" LOCALBASE="/usr" LIB.LINKSTATIC="" LIB.LINKDYNAMIC=""
}

src_install() {
	# Only the main executable needs to be installed
	emake -C cyphertite/cyphertite DESTDIR="${D}" LOCALBASE="usr" LIBDIR="usr/$(get_libdir)" LNFORCE="-s" install

	# Fix up broken man symlinks
	rm "${D}"usr/share/man/man1/ct*.1 || die
	newman "${D}"usr/share/man/man1/cyphertite.1 ct.1
	newman "${D}"usr/share/man/man1/cyphertitectl.1 ctctl.1
	newman "${D}"usr/share/man/man1/cyphertitefb.1 ctfb.1
}