[gentoo-commits] gentoo-x86 commit in games-strategy/naev: ChangeLog naev-0.5.2.ebuild

[Samuli Suominen (ssuominen)]

ssuominen    12/04/03 10:55:01

  Modified:             ChangeLog
  Added:                naev-0.5.2.ebuild
  Log:
  Version bump.
  
  (Portage version: 2.2.0_alpha98/cvs/Linux x86_64)

Revision  Changes    Path
1.10                 games-strategy/naev/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/games-strategy/naev/ChangeLog?rev=1.10&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/games-strategy/naev/ChangeLog?rev=1.10&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/games-strategy/naev/ChangeLog?r1=1.9&r2=1.10

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/games-strategy/naev/ChangeLog,v
retrieving revision 1.9
retrieving revision 1.10
diff -u -r1.9 -r1.10
--- ChangeLog	2 Mar 2012 02:12:46 -0000	1.9
+++ ChangeLog	3 Apr 2012 10:55:01 -0000	1.10
@@ -1,6 +1,11 @@
 # ChangeLog for games-strategy/naev
 # Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/games-strategy/naev/ChangeLog,v 1.9 2012/03/02 02:12:46 ssuominen Exp $
+# $Header: /var/cvsroot/gentoo-x86/games-strategy/naev/ChangeLog,v 1.10 2012/04/03 10:55:01 ssuominen Exp $
+
+*naev-0.5.2 (03 Apr 2012)
+
+  03 Apr 2012; Samuli Suominen <ssuominen@g.o> +naev-0.5.2.ebuild:
+  Version bump.
 
 *naev-0.5.1 (02 Mar 2012)
 



1.1                  games-strategy/naev/naev-0.5.2.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/games-strategy/naev/naev-0.5.2.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/games-strategy/naev/naev-0.5.2.ebuild?rev=1.1&content-type=text/plain

Index: naev-0.5.2.ebuild
===================================================================
# Copyright 1999-2012 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/games-strategy/naev/naev-0.5.2.ebuild,v 1.1 2012/04/03 10:55:01 ssuominen Exp $

EAPI=2
inherit gnome2-utils games

DESCRIPTION="A 2D space trading and combat game, in a similar vein to Escape Velocity"
HOMEPAGE="http://code.google.com/p/naev/"
SRC_URI="mirror://sourceforge/naev/${P}.tar.bz2
	mirror://sourceforge/naev/ndata-${PV}"

LICENSE="GPL-2 GPL-3 public-domain CCPL-Attribution-3.0 CCPL-Attribution-ShareAlike-3.0"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="debug +mixer +openal"

RDEPEND="media-libs/libsdl[X,audio,video]
	dev-libs/libxml2
	>=media-libs/freetype-2
	>=media-libs/libvorbis-1.2.1
	>=media-libs/libpng-1.2:0
	media-libs/sdl-image[png]
	virtual/glu
	virtual/opengl
	mixer? ( media-libs/sdl-mixer )
	openal? ( media-libs/openal )"
DEPEND="${RDEPEND}
	dev-util/pkgconfig"

src_unpack() {
	unpack ${P}.tar.bz2
}

src_configure() {
	egamesconf \
		--docdir=/usr/share/doc/${PF} \
		--disable-dependency-tracking \
		$(use_enable debug) \
		$(use_with openal) \
		$(use_with mixer sdlmixer)
}

src_install() {
	emake \
		DESTDIR="${D}" \
		appicondir=/usr/share/pixmaps \
		Graphicsdir=/usr/share/applications \
		install || die

	insinto "${GAMES_DATADIR}"/${PN}
	newins "${DISTDIR}"/ndata-${PV} ndata || die

	local res
	for res in 16 32 64 128; do
		insinto /usr/share/icons/hicolor/${res}x${res}/apps
		newins extras/logos/logo${res}.png naev.png || die
	done

	rm -f "${D}"/usr/share/doc/${PF}/LICENSE
	prepalldocs

	prepgamesdirs
}

pkg_preinst() {
	games_pkg_preinst
	gnome2_icon_savelist
}

pkg_postinst() {
	games_pkg_postinst
	gnome2_icon_cache_update
}

pkg_postrm() {
	gnome2_icon_cache_update
}