[gentoo-commits] repo/gentoo:master commit in: dev-python/oslo-utils/

[Michał Górny]

commit:     20f9c5c94acfc8df10709c721562879b2cab3017
Author:     Michał Górny <mgorny <AT> gentoo <DOT> org>
AuthorDate: Thu Apr 28 07:10:45 2022 +0000
Commit:     Michał Górny <mgorny <AT> gentoo <DOT> org>
CommitDate: Thu Apr 28 08:13:38 2022 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=20f9c5c9

dev-python/oslo-utils: Bump to 4.13.0

Signed-off-by: Michał Górny <mgorny <AT> gentoo.org>

 dev-python/oslo-utils/Manifest                 |  1 +
 dev-python/oslo-utils/oslo-utils-4.13.0.ebuild | 63 ++++++++++++++++++++++++++
 2 files changed, 64 insertions(+)

diff --git a/dev-python/oslo-utils/Manifest b/dev-python/oslo-utils/Manifest
index db024b0c6c4a..02910c6154d0 100644
--- a/dev-python/oslo-utils/Manifest
+++ b/dev-python/oslo-utils/Manifest
@@ -1 +1,2 @@
 DIST oslo.utils-4.12.2.tar.gz 101505 BLAKE2B fb2d56c767e8ed100ba789560e6b50dfecf8528de2a2717a9660e3dc8ceb93838137d59f1c2e3f05ccb99b95ea1ec86870e22160fb670a8cfb2dd9d6783f1d0f SHA512 fa56225f1991b031e2122cf08cd0992d8a9bfacd9a83d590f87ff86c495d51763ac06f65076c746a59563a60f886601d00ea9536dfcc927fca94c5a1431bcf67
+DIST oslo.utils-4.13.0.tar.gz 101834 BLAKE2B 9d3457ee9ce1746869120bf66d83495b4e1f2b4ca005285fa121ff4c176e85148662cd1de52bdaf93dc18d85478f2cbfde9b310e748b895f01c77ef82019dc0e SHA512 1d97fdaab79cc6c4cc34efdafca7263a2679e60d446aadc46fe31d7fdda2051b37f9df79d149644d914c7274e7fa2d9ef6a1c1aeafad8a1333221dcbe65f4723

diff --git a/dev-python/oslo-utils/oslo-utils-4.13.0.ebuild b/dev-python/oslo-utils/oslo-utils-4.13.0.ebuild
new file mode 100644
index 000000000000..b991aafb859e
--- /dev/null
+++ b/dev-python/oslo-utils/oslo-utils-4.13.0.ebuild
@@ -0,0 +1,63 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{8..10} )
+
+inherit distutils-r1
+
+MY_P=${P/-/.}
+DESCRIPTION="Oslo Utility library"
+HOMEPAGE="https://launchpad.net/oslo"
+SRC_URI="mirror://pypi/${PN::1}/${PN/-/.}/${MY_P}.tar.gz"
+S="${WORKDIR}/${MY_P}"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~x86"
+
+RDEPEND="
+	>=dev-python/iso8601-0.1.11[${PYTHON_USEDEP}]
+	>=dev-python/oslo-i18n-3.15.3[${PYTHON_USEDEP}]
+	>=dev-python/pytz-2013.6[${PYTHON_USEDEP}]
+	>=dev-python/netaddr-0.7.18[${PYTHON_USEDEP}]
+	>=dev-python/netifaces-0.10.4[${PYTHON_USEDEP}]
+	>=dev-python/debtcollector-1.2.0[${PYTHON_USEDEP}]
+	>=dev-python/pyparsing-2.1.0[${PYTHON_USEDEP}]
+	>=dev-python/packaging-20.4[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	>=dev-python/pbr-2.2.0[${PYTHON_USEDEP}]
+	test? (
+		$(python_gen_cond_dep '
+			>=dev-python/eventlet-0.23.0[${PYTHON_USEDEP}]
+		' python3_{8..9})
+		>=dev-python/fixtures-3.0.0[${PYTHON_USEDEP}]
+		>=dev-python/testscenarios-0.4[${PYTHON_USEDEP}]
+		>=dev-python/testtools-2.2.0[${PYTHON_USEDEP}]
+		>=dev-python/oslotest-3.2.0[${PYTHON_USEDEP}]
+		>=dev-python/ddt-1.0.1[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests unittest
+
+src_prepare() {
+	# spurious rdep
+	sed -i -e '/pbr/d' requirements.txt || die
+	distutils-r1_src_prepare
+}
+
+python_compile() {
+	distutils-r1_python_compile
+	if ! has "${EPYTHON}" python3.{8..9}; then
+		find "${BUILD_DIR}"/install -name '*eventletutils*.py' -delete || die
+	fi
+}
+
+python_test() {
+	cd "${BUILD_DIR}/install$(python_get_sitedir)" || die
+	eunittest
+}