[gentoo-commits] gentoo-x86 commit in dev-python/jinja: jinja-2.8.ebuild ChangeLog

[Patrick Lauer (patrick)]

patrick     15/07/30 08:06:05

  Modified:             ChangeLog
  Added:                jinja-2.8.ebuild
  Log:
  Bump
  
  (Portage version: 2.2.20/cvs/Linux x86_64, unsigned Manifest commit)

Revision  Changes    Path
1.129                dev-python/jinja/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/jinja/ChangeLog?rev=1.129&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/jinja/ChangeLog?rev=1.129&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/jinja/ChangeLog?r1=1.128&r2=1.129

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/dev-python/jinja/ChangeLog,v
retrieving revision 1.128
retrieving revision 1.129
diff -u -r1.128 -r1.129
--- ChangeLog	3 Jun 2015 19:48:04 -0000	1.128
+++ ChangeLog	30 Jul 2015 08:06:05 -0000	1.129
@@ -1,6 +1,11 @@
 # ChangeLog for dev-python/jinja
 # Copyright 1999-2015 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-python/jinja/ChangeLog,v 1.128 2015/06/03 19:48:04 jlec Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-python/jinja/ChangeLog,v 1.129 2015/07/30 08:06:05 patrick Exp $
+
+*jinja-2.8 (30 Jul 2015)
+
+  30 Jul 2015; Patrick Lauer <patrick@g.o> +jinja-2.8.ebuild:
+  Bump
 
   03 Jun 2015; Justin Lecher <jlec@g.o> metadata.xml:
   Add pypi to remote-id in metadata.xml



1.1                  dev-python/jinja/jinja-2.8.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/jinja/jinja-2.8.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/jinja/jinja-2.8.ebuild?rev=1.1&content-type=text/plain

Index: jinja-2.8.ebuild
===================================================================
# Copyright 1999-2015 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-python/jinja/jinja-2.8.ebuild,v 1.1 2015/07/30 08:06:05 patrick Exp $

EAPI=5

PYTHON_COMPAT=( python{2_7,3_3,3_4} pypy pypy3 )

inherit eutils distutils-r1

MY_PN=Jinja2
MY_P=${MY_PN}-${PV}

DESCRIPTION="A small but fast and easy to use stand-alone template engine written in pure Python"
HOMEPAGE="http://jinja.pocoo.org/ http://pypi.python.org/pypi/Jinja2"
SRC_URI="mirror://pypi/${MY_PN:0:1}/${MY_PN}/${MY_P}.tar.gz"

LICENSE="BSD"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~amd64-fbsd ~x86-fbsd ~x86-interix ~amd64-linux ~x86-linux ~x64-macos ~x86-macos ~sparc-solaris ~sparc64-solaris"
IUSE="doc examples"

RDEPEND="dev-python/markupsafe[${PYTHON_USEDEP}]
	dev-python/setuptools[${PYTHON_USEDEP}]
	!dev-python/jinja:compat"
DEPEND="${RDEPEND}
	doc? ( dev-python/sphinx[${PYTHON_USEDEP}] )"

# XXX: handle Babel better?

S=${WORKDIR}/${MY_P}

wrap_opts() {
	local mydistutilsargs=()

	if [[ ${EPYTHON} == python* ]]; then
		mydistutilargs+=( --with-debugsupport )
	fi

	"${@}"
}

python_compile() {
	wrap_opts distutils-r1_python_compile
	if [[ ${EPYTHON} == python3.2 ]]; then
		2to3 --no-diffs -n -w -f unicode "${BUILD_DIR}/lib" || die
	fi
}

python_compile_all() {
	use doc && emake -C docs html
}

python_test() {
	esetup.py test
}

python_install_all() {
	use doc && local HTML_DOCS=( docs/_build/html/. )
	use examples && local EXAMPLES=( examples/. )

	distutils-r1_python_install_all

	insinto /usr/share/vim/vimfiles/syntax
	doins ext/Vim/*
}

pkg_postinst() {
	if ! has_version dev-python/Babel; then
		elog "For i18n support, please emerge dev-python/Babel."
	fi
}