[gentoo-commits] gentoo-x86 commit in mail-client/claws-mail: ChangeLog claws-mail-3.7.5-r1.ebuild

[Christian Faulhammer (fauli)]

fauli       10/04/20 19:05:11

  Modified:             ChangeLog
  Added:                claws-mail-3.7.5-r1.ebuild
  Log:
  revision bump to fix compilation with libetpan 1.0, see bug 314181.  Also incorporate EAPI 2 fixes and cleaner ebuild structure provided by Tim Harder <radhermit AT gmail DOT com> in the same bug
  (Portage version: 2.1.8.3/cvs/Linux i686)

Revision  Changes    Path
1.148                mail-client/claws-mail/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/mail-client/claws-mail/ChangeLog?rev=1.148&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/mail-client/claws-mail/ChangeLog?rev=1.148&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/mail-client/claws-mail/ChangeLog?r1=1.147&r2=1.148

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/mail-client/claws-mail/ChangeLog,v
retrieving revision 1.147
retrieving revision 1.148
diff -u -r1.147 -r1.148
--- ChangeLog	18 Apr 2010 14:30:55 -0000	1.147
+++ ChangeLog	20 Apr 2010 19:05:11 -0000	1.148
@@ -1,6 +1,15 @@
 # ChangeLog for mail-client/claws-mail
 # Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/mail-client/claws-mail/ChangeLog,v 1.147 2010/04/18 14:30:55 nixnut Exp $
+# $Header: /var/cvsroot/gentoo-x86/mail-client/claws-mail/ChangeLog,v 1.148 2010/04/20 19:05:11 fauli Exp $
+
+*claws-mail-3.7.5-r1 (20 Apr 2010)
+
+  20 Apr 2010; Christian Faulhammer <fauli@g.o>
+  +claws-mail-3.7.5-r1.ebuild,
+  +files/claws-mail-3.7.5-fix-libetpan-check.patch:
+  revision bump to fix compilation with libetpan 1.0, see bug 314181. Also
+  incorporate EAPI 2 fixes and cleaner ebuild structure provided by Tim
+  Harder <radhermit AT gmail DOT com> in the same bug
 
   18 Apr 2010; <nixnut@g.o> claws-mail-3.7.5.ebuild:
   ppc stable #304353



1.1                  mail-client/claws-mail/claws-mail-3.7.5-r1.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/mail-client/claws-mail/claws-mail-3.7.5-r1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/mail-client/claws-mail/claws-mail-3.7.5-r1.ebuild?rev=1.1&content-type=text/plain

Index: claws-mail-3.7.5-r1.ebuild
===================================================================
# Copyright 1999-2010 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/mail-client/claws-mail/claws-mail-3.7.5-r1.ebuild,v 1.1 2010/04/20 19:05:11 fauli Exp $

EAPI="2"

inherit eutils multilib autotools

DESCRIPTION="An email client (and news reader) based on GTK+"
HOMEPAGE="http://www.claws-mail.org/"

SRC_URI="mirror://sourceforge/sylpheed-claws/${P}.tar.bz2"

SLOT="0"
LICENSE="GPL-3"
KEYWORDS="~alpha ~amd64 ~hppa ~ppc ~ppc64 ~sparc ~x86 ~x86-fbsd"
IUSE="bogofilter crypt dbus dillo doc gnome +gnutls +imap ipv6 ldap nntp pda session smime spamassassin spell ssl startup-notification xface"

COMMONDEPEND=">=x11-libs/gtk+-2.6
	pda? ( >=app-pda/jpilot-0.99 )
	ssl? ( >=net-libs/gnutls-2.0.3 )
	ldap? ( >=net-nds/openldap-2.0.7 )
	crypt? ( >=app-crypt/gpgme-0.4.5 )
	dbus? ( >=dev-libs/dbus-glib-0.60 )
	dillo? ( www-client/dillo )
	spell? ( >=app-text/enchant-1.0.0 )
	imap? ( >=net-libs/libetpan-0.57 )
	nntp? ( >=net-libs/libetpan-0.57 )
	gnome? ( >=gnome-base/libgnomeprintui-2.2 )
	gnutls? ( >=net-libs/gnutls-2.0.3 )
	startup-notification? ( x11-libs/startup-notification )
	bogofilter? ( mail-filter/bogofilter )
	session? ( x11-libs/libSM
			x11-libs/libICE )
	smime? ( >=app-crypt/gpgme-0.4.5 )"

DEPEND="${COMMONDEPEND}
	xface? ( >=media-libs/compface-1.4 )
	dev-util/pkgconfig"

RDEPEND="${COMMONDEPEND}
	app-misc/mime-types
	x11-misc/shared-mime-info"

PLUGIN_NAMES="acpi-notifier archive att-remover attachwarner bsfilter cachesaver fancy fetchinfo gtkhtml mailmbox newmail notification perl rssyl spam_report tnef_parse vcalendar"

src_prepare() {
	# fix configure check for >libetpan-0.57 (bug #314181, fixed upstream)
	epatch "${FILESDIR}"/${P}-fix-libetpan-check.patch
	eautoreconf
}

src_configure() {
	local myconf
	# libetpan is needed if user wants nntp or imap functionality
	if use imap || use nntp; then
		myconf="--enable-libetpan"
	else
		myconf="--disable-libetpan"
	fi

	# The usage of openssl was discarded once and USE=ssl is mapped to
	# USE=gnutls now.  Maybe USE=ssl can fade out sometime
	if use ssl || use gnutls; then
		myconf="${myconf} --enable-gnutls"
	else
		myconf="${myconf} --disable-gnutls"
	fi

	econf \
		$(use_enable gnome gnomeprint) \
		$(use_enable ipv6) \
		$(use_enable ldap) \
		$(use_enable dbus) \
		$(use_enable pda jpilot) \
		$(use_enable spell enchant) \
		$(use_enable xface compface) \
		$(use_enable doc manual) \
		$(use_enable startup-notification) \
		$(use_enable session libsm) \
		$(use_enable crypt pgpmime-plugin) \
		$(use_enable crypt pgpinline-plugin) \
		$(use_enable crypt pgpcore-plugin) \
		$(use_enable dillo dillo-viewer-plugin) \
		$(use_enable spamassassin spamassassin-plugin) \
		$(use_enable bogofilter bogofilter-plugin) \
		$(use_enable smime smime-plugin) \
		--docdir=/usr/share/doc/${PF} \
		--enable-trayicon-plugin \
		--disable-maemo ${myconf}
}

src_install() {
	emake DESTDIR="${D}" install || die

	# Makefile install claws-mail.png in /usr/share/icons/hicolor/48x48/apps
	# => also install it in /usr/share/pixmaps for other desktop envs
	# => also install higher resolution icons in /usr/share/icons/hicolor/...
	insinto /usr/share/pixmaps
	doins ${PN}.png || die
	local res resdir
	for res in 64x64 128x128 ; do
		resdir="/usr/share/icons/hicolor/${res}/apps"
		insinto ${resdir}
		newins ${PN}-${res}.png ${PN}.png || die
	done

	dodoc AUTHORS ChangeLog* INSTALL* NEWS README* TODO*
	docinto tools
	dodoc tools/README*

	insinto /usr/share/applications
	doins ${PN}.desktop

	einfo "Installing extra tools"
	cd "${S}"/tools
	exeinto /usr/$(get_libdir)/${PN}/tools
	doexe *.pl *.py *.conf *.sh || die
	doexe tb2claws-mail update-po uudec uuooffice || die

	# kill useless plugin files
	rm -f "${D}"/usr/lib*/${PN}/plugins/*.{la,a}
}

pkg_postinst() {
	gtk-update-icon-cache -f -t "${ROOT}"/usr/share/icons/hicolor

	UPDATE_PLUGINS=""
	RENAME_PLUGINS=""
	for x in ${PLUGIN_NAMES}; do
		has_version mail-client/${PN}-$x && UPDATE_PLUGINS="${UPDATE_PLUGINS} $x"
		has_version mail-client/sylpheed-claws-$x && RENAME_PLUGINS="${RENAME_PLUGINS} $x"
	done
	if [ -n "${RENAME_PLUGINS}" ]; then
		elog
		elog "The following sylpheed-claws plugins were found on your system:"
		elog
		for x in ${RENAME_PLUGINS}; do
			elog "    mail-client/sylpheed-claws-$x"
		done
		elog
		elog "If you want to continue using those you need to merge their "
		elog "renamed counterparts:"
		elog
		for x in ${RENAME_PLUGINS}; do
			elog "    mail-client/${PN}-$x"
		done
		elog
	fi
	if [ -n "${UPDATE_PLUGINS}" ]; then
		elog
		elog "You have to re-emerge or update the following plugins:"
		elog
		for x in ${UPDATE_PLUGINS}; do
			elog "    mail-client/${PN}-$x"
		done
		elog
	fi
}

pkg_postrm() {
	gtk-update-icon-cache -f -t "${ROOT}"/usr/share/icons/hicolor
}