[gentoo-commits] gentoo-x86 commit in mate-base/mate-session-manager: metadata.xml mate-session-manager-1.6.1-r1.ebuild ChangeLog

[Tom Wijsman (tomwij)]

tomwij      14/02/27 18:41:22

  Added:                metadata.xml mate-session-manager-1.6.1-r1.ebuild
                        ChangeLog
  Log:
  New ebuild for mate-base/mate-session-manager, MATE session manager; imported from the mate-overlay, reviewed and adjusted.
  
  (Portage version: HEAD/cvs/Linux x86_64, signed Manifest commit with key 6D34E57D)

Revision  Changes    Path
1.1                  mate-base/mate-session-manager/metadata.xml

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/mate-base/mate-session-manager/metadata.xml?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/mate-base/mate-session-manager/metadata.xml?rev=1.1&content-type=text/plain

Index: metadata.xml
===================================================================
<?xml version="1.0" encoding="UTF-8"?>
<!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
<pkgmetadata>
	<maintainer>
		<email>TomWij@g.o</email>
		<name>Tom Wijsman</name>
	</maintainer>
</pkgmetadata>



1.1                  mate-base/mate-session-manager/mate-session-manager-1.6.1-r1.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/mate-base/mate-session-manager/mate-session-manager-1.6.1-r1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/mate-base/mate-session-manager/mate-session-manager-1.6.1-r1.ebuild?rev=1.1&content-type=text/plain

Index: mate-session-manager-1.6.1-r1.ebuild
===================================================================
# Copyright 1999-2014 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/mate-base/mate-session-manager/mate-session-manager-1.6.1-r1.ebuild,v 1.1 2014/02/27 18:41:22 tomwij Exp $

EAPI="5"

GCONF_DEBUG="yes"

inherit autotools gnome2 versionator

MATE_BRANCH="$(get_version_component_range 1-2)"

SRC_URI="http://pub.mate-desktop.org/releases/${MATE_BRANCH}/${P}.tar.xz"
DESCRIPTION="MATE session manager"
HOMEPAGE="http://mate-desktop.org/"

LICENSE="GPL-2 LGPL-2 FDL-1.1"
SLOT="0"
KEYWORDS="~amd64"

IUSE="ipv6 elibc_FreeBSD gnome-keyring systemd"

# x11-misc/xdg-user-dirs{,-gtk} are needed to create the various XDG_*_DIRs, and
# create .config/user-dirs.dirs which is read by glib to get G_USER_DIRECTORY_*
# xdg-user-dirs-update is run during login (see 10-user-dirs-update-gnome below).

RDEPEND=">=dev-libs/dbus-glib-0.76:0
	>=dev-libs/glib-2.25:2
	sys-apps/dbus:0
	sys-libs/glibc:2.2
	>=sys-power/upower-0.9.0:0

	x11-apps/xdpyinfo:0
	x11-libs/gdk-pixbuf:2
	>=x11-libs/gtk+-2.14:2
	x11-libs/libICE:0
	x11-libs/libSM:0
	x11-libs/libX11:0
	x11-libs/libXau:0
	x11-libs/libXext:0
	x11-libs/libXrender:0
	x11-libs/libXtst:0
	x11-libs/pango:0
	x11-libs/xtrans:0
	x11-misc/xdg-user-dirs:0
	x11-misc/xdg-user-dirs-gtk:0

	virtual/libintl:0

	elibc_FreeBSD? ( dev-libs/libexecinfo:0 )
	gnome-keyring? ( gnome-base/gnome-keyring:0 )"

DEPEND="${RDEPEND}
	dev-libs/libxslt:0
	>=dev-util/intltool-0.40:0
	>=dev-lang/perl-5:0
	>=mate-base/mate-common-1.2.2:0
	>=sys-devel/gettext-0.10.40:0
	virtual/pkgconfig:0
	!<gnome-base/gdm-2.20.4:0
	systemd? ( sys-apps/systemd:0 )"

src_prepare() {
	# Add "session saving" button back,
	# see https://bugzilla.gnome.org/show_bug.cgi?id=575544
	epatch "${FILESDIR}"/${PN}-1.5.2-save-session-ui.patch

	# Fix race condition in idle monitor, GNOME bug applies to MATE too,
	# see https://bugzilla.gnome.org/show_bug.cgi?id=627903
	epatch "${FILESDIR}"/${PN}-1.2.0-idle-transition.patch

	# Fix suspend support with systemd.
	if use systemd ; then
		epatch "${FILESDIR}"/${P}-login1.patch
	fi

	# Use gnome-keyring.
	if use gnome-keyring ; then
		epatch "${FILESDIR}"/${PN}-1.6-gnome-keyring.patch
	fi

	eautoreconf
	gnome2_src_prepare
}

src_configure() {
	gnome2_src_configure \
		--docdir="${EPREFIX}/usr/share/doc/${PF}" \
		--with-default-wm=mate-wm \
		--with-gtk=2.0 \
		$(use_enable ipv6) \
		$(use_with systemd)
}

DOCS="AUTHORS ChangeLog NEWS README"

src_install() {
	gnome2_src_install

	dodir /etc/X11/Sessions/
	exeinto /etc/X11/Sessions/
	doexe "${FILESDIR}"/MATE

	dodir /usr/share/mate/applications/
	insinto /usr/share/mate/applications/
	doins "${FILESDIR}"/defaults.list

	dodir /etc/X11/xinit/xinitrc.d/
	exeinto /etc/X11/xinit/xinitrc.d/
	doexe "${FILESDIR}"/15-xdg-data-mate

	# This should be done in MATE too, see Gentoo bug #270852
	doexe "${FILESDIR}"/10-user-dirs-update-mate
}



1.1                  mate-base/mate-session-manager/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/mate-base/mate-session-manager/ChangeLog?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/mate-base/mate-session-manager/ChangeLog?rev=1.1&content-type=text/plain

Index: ChangeLog
===================================================================
# ChangeLog for mate-base/mate-session-manager
# Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
# $Header: /var/cvsroot/gentoo-x86/mate-base/mate-session-manager/ChangeLog,v 1.1 2014/02/27 18:41:22 tomwij Exp $

*mate-session-manager-1.6.1-r1 (27 Feb 2014)

  27 Feb 2014; Tom Wijsman <TomWij@g.o> +files/10-user-dirs-update-mate,
  +files/15-xdg-data-mate, +files/MATE, +files/defaults.list,
  +files/mate-session-manager-1.2.0-idle-transition.patch,
  +files/mate-session-manager-1.5.2-save-session-ui.patch,
  +files/mate-session-manager-1.6-gnome-keyring.patch,
  +files/mate-session-manager-1.6.1-login1.patch,
  +mate-session-manager-1.6.1-r1.ebuild, +metadata.xml:
  New ebuild for mate-base/mate-session-manager, MATE session manager; imported
  from the mate-overlay, reviewed and adjusted.