[gentoo-commits] gentoo-x86 commit in media-libs/libgpod: libgpod-0.8.0.ebuild ChangeLog libgpod-0.7.94.ebuild libgpod-0.7.95.ebuild

[Samuli Suominen (ssuominen)]

ssuominen    10/10/31 16:07:46

  Modified:             ChangeLog
  Added:                libgpod-0.8.0.ebuild
  Removed:              libgpod-0.7.94.ebuild libgpod-0.7.95.ebuild
  Log:
  Version bump.
  
  (Portage version: 2.2.0_alpha1/cvs/Linux x86_64)

Revision  Changes    Path
1.79                 media-libs/libgpod/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-libs/libgpod/ChangeLog?rev=1.79&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-libs/libgpod/ChangeLog?rev=1.79&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-libs/libgpod/ChangeLog?r1=1.78&r2=1.79

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/media-libs/libgpod/ChangeLog,v
retrieving revision 1.78
retrieving revision 1.79
diff -u -r1.78 -r1.79
--- ChangeLog	30 Sep 2010 09:29:55 -0000	1.78
+++ ChangeLog	31 Oct 2010 16:07:46 -0000	1.79
@@ -1,6 +1,11 @@
 # ChangeLog for media-libs/libgpod
 # Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-libs/libgpod/ChangeLog,v 1.78 2010/09/30 09:29:55 ford_prefect Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-libs/libgpod/ChangeLog,v 1.79 2010/10/31 16:07:46 ssuominen Exp $
+
+*libgpod-0.8.0 (31 Oct 2010)
+
+  31 Oct 2010; Samuli Suominen <ssuominen@g.o> +libgpod-0.8.0.ebuild:
+  Version bump.
 
   30 Sep 2010; Arun Raghavan <ford_prefect@g.o>
   -libgpod-0.7.93.ebuild:



1.1                  media-libs/libgpod/libgpod-0.8.0.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-libs/libgpod/libgpod-0.8.0.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-libs/libgpod/libgpod-0.8.0.ebuild?rev=1.1&content-type=text/plain

Index: libgpod-0.8.0.ebuild
===================================================================
# Copyright 1999-2010 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/media-libs/libgpod/libgpod-0.8.0.ebuild,v 1.1 2010/10/31 16:07:46 ssuominen Exp $

EAPI=3

PYTHON_DEPEND="python? 2:2.6"

inherit eutils mono python

DESCRIPTION="Shared library to access the contents of an iPod"
HOMEPAGE="http://www.gtkpod.org/libgpod/"
SRC_URI="mirror://sourceforge/gtkpod/${P}.tar.gz"

LICENSE="LGPL-2"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="+gtk python +udev iphone mono static-libs"

RDEPEND=">=app-pda/libplist-1.0
	>=dev-db/sqlite-3
	>=dev-libs/glib-2.16:2
	dev-libs/libxml2
	sys-apps/sg3_utils
	gtk? ( || ( x11-libs/gdk-pixbuf:2 <x11-libs/gtk+-2.22:2 ) )
	iphone? ( app-pda/libimobiledevice )
	python? ( >=media-libs/mutagen-1.8
		>=dev-python/pygobject-2.8 )
	udev? ( sys-fs/udev )
	mono? ( >=dev-lang/mono-1.9.1
		>=dev-dotnet/gtk-sharp-2.12 )"
DEPEND="${RDEPEND}
	python? ( >=dev-lang/swig-1.3.24 )
	dev-libs/libxslt
	dev-util/intltool
	dev-util/pkgconfig"

pkg_setup() {
	if use python; then
		python_set_active_version 2
		python_pkg_setup
	fi
}

src_prepare() {
	rm -f py-compile
	ln -s $(type -P true) py-compile
}

src_configure() {
	econf \
		--disable-dependency-tracking \
		$(use_enable static-libs static) \
		$(use_enable udev) \
		$(use_enable gtk gdk-pixbuf) \
		$(use_enable python pygobject) \
		--without-hal \
		$(use_with iphone libimobiledevice) \
		--with-html-dir=/usr/share/doc/${PF}/html \
		$(use_with python) \
		$(use_with mono)
}

src_install() {
	emake DESTDIR="${D}" install || die
	dodoc AUTHORS README NEWS README* TROUBLESHOOTING

	find "${D}" -name '*.la' -exec rm -f '{}' +
}

pkg_postinst() {
	use python && python_mod_optimize gpod
}

pkg_postrm() {
	use python && python_mod_cleanup gpod
}