[gentoo-commits] gentoo-x86 commit in games-strategy/glest: ChangeLog glest-2.0.1.ebuild

[Alfredo Tupone (tupone)]

tupone      07/09/26 21:55:30

  Modified:             ChangeLog
  Added:                glest-2.0.1.ebuild
  Log:
  Version bump to 2.0.1 Bug #191636
  (Portage version: 2.1.3.9)

Revision  Changes    Path
1.16                 games-strategy/glest/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/games-strategy/glest/ChangeLog?rev=1.16&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/games-strategy/glest/ChangeLog?rev=1.16&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/games-strategy/glest/ChangeLog?r1=1.15&r2=1.16

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/games-strategy/glest/ChangeLog,v
retrieving revision 1.15
retrieving revision 1.16
diff -u -r1.15 -r1.16
--- ChangeLog	27 Jun 2007 18:04:35 -0000	1.15
+++ ChangeLog	26 Sep 2007 21:55:30 -0000	1.16
@@ -1,6 +1,12 @@
 # ChangeLog for games-strategy/glest
 # Copyright 1999-2007 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/games-strategy/glest/ChangeLog,v 1.15 2007/06/27 18:04:35 nyhm Exp $
+# $Header: /var/cvsroot/gentoo-x86/games-strategy/glest/ChangeLog,v 1.16 2007/09/26 21:55:30 tupone Exp $
+
+*glest-2.0.1 (26 Sep 2007)
+
+  26 Sep 2007; Tupone Alfredo <tupone@g.o>
+  +files/glest-2.0.1-home.patch, +glest-2.0.1.ebuild:
+  Version bump to 2.0.1 Bug #191636 by Greg Fitzgerald
 
   27 Jun 2007; Tristan Heaven <nyhm@g.o> glest-2.0.0-r1.ebuild:
   Don't rely on LINGUAS being set



1.1                  games-strategy/glest/glest-2.0.1.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/games-strategy/glest/glest-2.0.1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/games-strategy/glest/glest-2.0.1.ebuild?rev=1.1&content-type=text/plain

Index: glest-2.0.1.ebuild
===================================================================
# Copyright 1999-2007 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/games-strategy/glest/glest-2.0.1.ebuild,v 1.1 2007/09/26 21:55:30 tupone Exp $

inherit autotools eutils games

L_URI="http://www.glest.org/files/contrib/translations"
DESCRIPTION="Cross-platform 3D realtime strategy game"
HOMEPAGE="http://www.glest.org/"
SRC_URI="mirror://sourceforge/${PN}/${PN}_source_${PV}.zip
	mirror://sourceforge/${PN}/${PN}_data_${PV}.zip
	linguas_de? ( ${L_URI}/deutsch_${PV}.zip )
	linguas_hu? ( ${L_URI}/magyar_${PV}.zip )"

LICENSE="GPL-2 glest-data"
SLOT="0"
KEYWORDS="~amd64 -ppc ~x86" # ppc: bug #145478
IUSE="linguas_de linguas_hu"

RDEPEND="media-libs/libsdl
	media-libs/libogg
	media-libs/libvorbis
	media-libs/openal
	dev-libs/xerces-c
	virtual/opengl
	virtual/glu
	x11-libs/libX11
	x11-libs/libXt
	media-fonts/font-adobe-utopia-75dpi"
DEPEND="${RDEPEND}
	app-arch/unzip
	dev-util/jam"

S=${WORKDIR}/mk/linux

GAMES_USE_SDL="nojoystick"

src_unpack() {
	unpack ${A}

	local file
	for file in $(find source mk -type f) ; do
		edos2unix "${file}"
	done

	epatch \
		"${FILESDIR}"/${P}-home.patch

	sed -i \
		-e "s:GENTOO_DATADIR:${GAMES_DATADIR}/${PN}:" \
		source/glest_game/main/main.cpp \
		|| die "sed main.cpp failed"

	cd "${S}"
	# sometimes they package configure, sometimes they don't
	if [[ ! -f configure ]] ; then
		chmod a+x autogen.sh
		./autogen.sh || die "autogen failed" # FIXME: use autotools.eclass
	fi

	sed -i 's:-O3 -g3::' Jamrules || die "sed Jamrules failed"
}

src_compile() {
	# Fails with wx enabled, bug #130011
	egamesconf \
		--with-vorbis=/usr \
		--with-ogg=/usr \
		--with-wx-config=disabled_wx \
		|| die
	jam -q || die "jam failed"
}

src_install() {
	dogamesbin glest || die "dogamesbin failed"

	insinto "${GAMES_DATADIR}"/${PN}
	doins glest.ini || die "doins glest.ini failed"
	dodoc ../../docs/README.linux

	cd "${WORKDIR}"/glest_game
	doins -r data maps scenarios techs tilesets || die "doins data failed"
	dodoc docs/readme.txt

	make_desktop_entry glest Glest /usr/share/pixmaps/${PN}.bmp
	newicon techs/magitech/factions/magic/units/archmage/images/archmage.bmp \
		${PN}.bmp

	dolang() {
		insinto "${GAMES_DATADIR}"/${PN}/data/lang
		doins "${WORKDIR}"/${1} || die "doins ${1} failed"
	}

	use linguas_de && dolang deutsch.lng
	use linguas_hu && dolang magyar_${PV}.lng

	prepgamesdirs
}



-- 
gentoo-commits@g.o mailing list