[gentoo-commits] gentoo-x86 commit in www-apps/cgit: cgit-0.11.1-r1.ebuild ChangeLog cgit-0.11.1.ebuild

[Manuel Rueger (mrueg)]

mrueg       15/03/05 19:16:29

  Modified:             ChangeLog
  Added:                cgit-0.11.1-r1.ebuild
  Removed:              cgit-0.11.1.ebuild
  Log:
  Use correct bundled git version.
  
  (Portage version: 2.2.18/cvs/Linux x86_64, signed Manifest commit with key )

Revision  Changes    Path
1.31                 www-apps/cgit/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/www-apps/cgit/ChangeLog?rev=1.31&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/www-apps/cgit/ChangeLog?rev=1.31&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/www-apps/cgit/ChangeLog?r1=1.30&r2=1.31

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/www-apps/cgit/ChangeLog,v
retrieving revision 1.30
retrieving revision 1.31
diff -u -r1.30 -r1.31
--- ChangeLog	5 Mar 2015 17:19:02 -0000	1.30
+++ ChangeLog	5 Mar 2015 19:16:29 -0000	1.31
@@ -1,6 +1,12 @@
 # ChangeLog for www-apps/cgit
 # Copyright 1999-2015 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/www-apps/cgit/ChangeLog,v 1.30 2015/03/05 17:19:02 robbat2 Exp $
+# $Header: /var/cvsroot/gentoo-x86/www-apps/cgit/ChangeLog,v 1.31 2015/03/05 19:16:29 mrueg Exp $
+
+*cgit-0.11.1-r1 (05 Mar 2015)
+
+  05 Mar 2015; Manuel Rüger <mrueg@g.o> +cgit-0.11.1-r1.ebuild,
+  -cgit-0.11.1.ebuild:
+  Use correct bundled git version.
 
 *cgit-0.11.1 (05 Mar 2015)
 



1.1                  www-apps/cgit/cgit-0.11.1-r1.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/www-apps/cgit/cgit-0.11.1-r1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/www-apps/cgit/cgit-0.11.1-r1.ebuild?rev=1.1&content-type=text/plain

Index: cgit-0.11.1-r1.ebuild
===================================================================
# Copyright 1999-2015 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/www-apps/cgit/cgit-0.11.1-r1.ebuild,v 1.1 2015/03/05 19:16:29 mrueg Exp $

EAPI=5

WEBAPP_MANUAL_SLOT="yes"

inherit webapp eutils multilib user toolchain-funcs

[[ -z "${CGIT_CACHEDIR}" ]] && CGIT_CACHEDIR="/var/cache/${PN}/"

GIT_V="2.3.1"

DESCRIPTION="a fast web-interface for git repositories"
HOMEPAGE="http://git.zx2c4.com/cgit/about"
SRC_URI="mirror://kernel/software/scm/git/git-${GIT_V}.tar.xz
	http://git.zx2c4.com/cgit/snapshot/${P}.tar.xz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="doc +highlight +lua +jit"

RDEPEND="
	dev-vcs/git
	sys-libs/zlib
	dev-libs/openssl:0
	virtual/httpd-cgi
	highlight? ( || ( dev-python/pygments app-text/highlight ) )
	lua? ( jit? ( dev-lang/luajit ) !jit? ( dev-lang/lua ) )
"
# ebuilds without WEBAPP_MANUAL_SLOT="yes" are broken
DEPEND="${RDEPEND}
	!<www-apps/cgit-0.8.3.3
	doc? ( app-text/docbook-xsl-stylesheets
		>=app-text/asciidoc-8.5.1 )
"

pkg_setup() {
	webapp_pkg_setup
	enewuser "${PN}"
}

src_prepare() {
	rmdir git || die
	mv "${WORKDIR}"/git-"${GIT_V}" git || die

	echo "prefix = ${EPREFIX}/usr" >> cgit.conf
	echo "libdir = ${EPREFIX}/usr/$(get_libdir)" >> cgit.conf
	echo "CGIT_SCRIPT_PATH = ${MY_CGIBINDIR}" >> cgit.conf
	echo "CGIT_DATA_PATH = ${MY_HTDOCSDIR}" >> cgit.conf
	echo "CACHE_ROOT = ${CGIT_CACHEDIR}" >> cgit.conf
	echo "DESTDIR = ${D}" >> cgit.conf
	if use lua; then
		if use jit; then
			echo "LUA_PKGCONFIG = luajit" >> cgit.conf
		else
			echo "LUA_PKGCONFIG = lua" >> cgit.conf
		fi
	else
		echo "NO_LUA = 1" >> cgit.conf
	fi
}

src_compile() {
	emake V=1 AR="$(tc-getAR)" CC="$(tc-getCC)" CFLAGS="${CFLAGS}" LDFLAGS="${LDFLAGS}"
	use doc && emake V=1 doc-man
}

src_install() {
	webapp_src_preinst

	emake V=1 AR="$(tc-getAR)" CC="$(tc-getCC)" CFLAGS="${CFLAGS}" LDFLAGS="${LDFLAGS}" install

	insinto /etc
	doins "${FILESDIR}"/cgitrc

	dodoc README
	use doc && doman cgitrc.5

	webapp_postinst_txt en "${FILESDIR}"/postinstall-en.txt
	webapp_src_install

	keepdir "${CGIT_CACHEDIR}"
	fowners ${PN}:${PN} "${CGIT_CACHEDIR}"
	fperms 700 "${CGIT_CACHEDIR}"
}

pkg_postinst() {
	webapp_pkg_postinst
	ewarn "If you intend to run cgit using web server's user"
	ewarn "you should change ${CGIT_CACHEDIR} permissions."
}