[gentoo-commits] gentoo-x86 commit in dev-ruby/webmock: ChangeLog webmock-1.19.0.ebuild

[Hans de Graaff (graaff)]

graaff      14/10/04 06:58:47

  Modified:             ChangeLog
  Added:                webmock-1.19.0.ebuild
  Log:
  Version bump.
  
  (Portage version: 2.2.8-r2/cvs/Linux x86_64, signed Manifest commit with key 0x8883FA56A308A8D7!)

Revision  Changes    Path
1.31                 dev-ruby/webmock/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-ruby/webmock/ChangeLog?rev=1.31&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-ruby/webmock/ChangeLog?rev=1.31&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-ruby/webmock/ChangeLog?r1=1.30&r2=1.31

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/dev-ruby/webmock/ChangeLog,v
retrieving revision 1.30
retrieving revision 1.31
diff -u -r1.30 -r1.31
--- ChangeLog	15 Aug 2014 14:32:50 -0000	1.30
+++ ChangeLog	4 Oct 2014 06:58:47 -0000	1.31
@@ -1,6 +1,11 @@
 # ChangeLog for dev-ruby/webmock
 # Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-ruby/webmock/ChangeLog,v 1.30 2014/08/15 14:32:50 blueness Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-ruby/webmock/ChangeLog,v 1.31 2014/10/04 06:58:47 graaff Exp $
+
+*webmock-1.19.0 (04 Oct 2014)
+
+  04 Oct 2014; Hans de Graaff <graaff@g.o> +webmock-1.19.0.ebuild:
+  Version bump.
 
   15 Aug 2014; Anthony G. Basile <blueness@g.o> webmock-1.18.0.ebuild,
   webmock-1.7.4.ebuild:



1.1                  dev-ruby/webmock/webmock-1.19.0.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-ruby/webmock/webmock-1.19.0.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-ruby/webmock/webmock-1.19.0.ebuild?rev=1.1&content-type=text/plain

Index: webmock-1.19.0.ebuild
===================================================================
# Copyright 1999-2014 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-ruby/webmock/webmock-1.19.0.ebuild,v 1.1 2014/10/04 06:58:47 graaff Exp $

EAPI=5

USE_RUBY="ruby19 ruby20 ruby21 jruby"

RUBY_FAKEGEM_TASK_TEST="test spec NO_CONNECTION=true"

RUBY_FAKEGEM_RECIPE_DOC="rdoc"
RUBY_FAKEGEM_EXTRADOC="CHANGELOG.md README.md"

inherit ruby-fakegem

DESCRIPTION="Allows stubbing HTTP requests and setting expectations on HTTP requests"
HOMEPAGE="http://github.com/bblimke/webmock"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~ppc ~ppc64 ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~x64-solaris ~x86-solaris"
IUSE=""

ruby_add_rdepend ">=dev-ruby/addressable-2.3.6 >=dev-ruby/crack-0.3.2"

ruby_add_bdepend "test? (
	dev-ruby/rspec:2
	>=dev-ruby/httpclient-2.2.4
	)"

# These are not supported for jruby.
USE_RUBY="ruby19 ruby20" ruby_add_bdepend "test? ( >=dev-ruby/patron-0.4.18 >=dev-ruby/http-0.5.0 )"

all_ruby_prepare() {
	# Remove bundler support
	rm Gemfile || die
	sed -i -e '/[Bb]undler/d' Rakefile || die

	# There is now optional support for curb and typhoeus which we don't
	# have in Gentoo yet. em_http_request is available in Gentoo but its
	# version is too old.
	sed -i -e '/\(curb\|typhoeus\|em-http\)/d' spec/spec_helper.rb || die
	rm spec/acceptance/{typhoeus,curb,excon,em_http_request}/* || die
}

each_ruby_prepare() {
	case ${RUBY} in
		*jruby)
			sed -i -e '/http_gem/d' spec/spec_helper.rb || die
			rm spec/acceptance/http_gem/* || die
			;;
	esac
}

each_ruby_test() {
	each_fakegem_test

	einfo "Delay to allow the test server to stop"
	sleep 10
}