[gentoo-commits] dev/dev-zero:master commit in: dev-python/flask-admin/

[Tiziano Müller]

commit:     eb7c53370d2da0b7d204e1015c2e57da0a95ad0f
Author:     Tiziano Müller <dev-zero <AT> gentoo <DOT> org>
AuthorDate: Mon Dec 14 10:37:19 2015 +0000
Commit:     Tiziano Müller <dev-zero <AT> gentoo <DOT> org>
CommitDate: Mon Dec 14 10:37:19 2015 +0000
URL:        https://gitweb.gentoo.org/dev/dev-zero.git/commit/?id=eb7c5337

dev-python/flask-admin: version bump

 dev-python/flask-admin/Manifest                 |  1 +
 dev-python/flask-admin/flask-admin-1.3.0.ebuild | 55 +++++++++++++++++++++++++
 dev-python/flask-admin/metadata.xml             |  8 ++++
 3 files changed, 64 insertions(+)

diff --git a/dev-python/flask-admin/Manifest b/dev-python/flask-admin/Manifest
new file mode 100644
index 0000000..8bd709b
--- /dev/null
+++ b/dev-python/flask-admin/Manifest
@@ -0,0 +1 @@
+DIST Flask-Admin-1.3.0.tar.gz 892104 SHA256 750d2e72670a6f0cac82fa4185998cd3fa4146dde3b647002ee03a65242248a6 SHA512 53c0b61a555ba5de3f0dd2cb0c844797b4855d9d6c6b325ebefba90193b0b7f16604c9c906a0675bfcdeacf693942e6ff745061143f17770ee9862d70b373a16 WHIRLPOOL ed39a7b9c9935e428f1671aacf4101862dab80cb558aa9c80ddc4e5df9e1de8264d8f757ed8aca531ff1e70c4d08a922fccf1dfc7e9e54d74e3b1bd12561e766

diff --git a/dev-python/flask-admin/flask-admin-1.3.0.ebuild b/dev-python/flask-admin/flask-admin-1.3.0.ebuild
new file mode 100644
index 0000000..6425906
--- /dev/null
+++ b/dev-python/flask-admin/flask-admin-1.3.0.ebuild
@@ -0,0 +1,55 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+PYTHON_COMPAT=( python{2_7,3_4} )
+
+inherit distutils-r1
+
+#RESTRICT="test" # we're still missing some of the dependencies
+
+MY_PN="Flask-Admin"
+MY_P="${MY_PN}-${PV}"
+
+DESCRIPTION="Simple and extensible admin interface framework for Flask"
+HOMEPAGE="https://pypi.python.org/pypi/Flask-Admin"
+SRC_URI="mirror://pypi/${MY_P:0:1}/${MY_PN}/${MY_P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="examples test"
+
+RDEPEND="
+	>=dev-python/flask-0.7[${PYTHON_USEDEP}]
+	dev-python/wtforms[${PYTHON_USEDEP}]"
+DEPEND="${RDEPEND}
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	test? (
+		dev-python/nose[${PYTHON_USEDEP}]
+		dev-python/flask-wtf[${PYTHON_USEDEP}]
+		dev-python/flask-pymongo[${PYTHON_USEDEP}]
+		dev-python/flask-peewee[${PYTHON_USEDEP}]
+		dev-python/flask-mongoengine[${PYTHON_USEDEP}]
+		dev-python/flask-sqlalchemy[${PYTHON_USEDEP}]
+		dev-python/pillow[${PYTHON_USEDEP}]
+	)"
+
+S="${WORKDIR}/${MY_P}"
+
+python_prepare_all() {
+	sed \
+		-e 's:find_packages():find_packages(exclude=["*.examples", "*.examples.*", "examples.*", "examples"]):g' \
+		-i setup.py || die
+	distutils-r1_python_prepare_all
+}
+
+python_test() {
+	nosetests || die "Testing failed with ${EPYTHON}"
+}
+
+python_install_all() {
+	use examples && local EXAMPLES=( examples/. )
+	distutils-r1_python_install_all
+}

diff --git a/dev-python/flask-admin/metadata.xml b/dev-python/flask-admin/metadata.xml
new file mode 100644
index 0000000..1c2961d
--- /dev/null
+++ b/dev-python/flask-admin/metadata.xml
@@ -0,0 +1,8 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+  <herd>python</herd>
+  <upstream>
+    <remote-id type="pypi">Flask-Admin</remote-id>
+  </upstream>
+</pkgmetadata>