[gentoo-commits] repo/gentoo:master commit in: media-video/qmplay2/

[Arthur Zamarin]

commit:     9ca50f1a7fda02e16931c44094daf556f24b8a90
Author:     Arthur Zamarin <arthurzam <AT> gentoo <DOT> org>
AuthorDate: Sun Aug 22 17:35:16 2021 +0000
Commit:     Arthur Zamarin <arthurzam <AT> gentoo <DOT> org>
CommitDate: Sun Aug 22 17:39:21 2021 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=9ca50f1a

media-video/qmplay2: add 21.06.07

Closes: https://bugs.gentoo.org/771918
Closes: https://bugs.gentoo.org/766027
Signed-off-by: Arthur Zamarin <arthurzam <AT> gentoo.org>

 media-video/qmplay2/Manifest                |   1 +
 media-video/qmplay2/qmplay2-21.06.07.ebuild | 134 ++++++++++++++++++++++++++++
 2 files changed, 135 insertions(+)

diff --git a/media-video/qmplay2/Manifest b/media-video/qmplay2/Manifest
index 4f6103c9d86..0bdf5fd10af 100644
--- a/media-video/qmplay2/Manifest
+++ b/media-video/qmplay2/Manifest
@@ -1,2 +1,3 @@
 DIST QMPlay2-src-20.07.04.tar.xz 1552680 BLAKE2B cc53ef842f91312f72e8d347a2d6d2e4239fe9435d0b7ac39e47e9f1f48a9a570ce614dd496512079d3701e1823ab75123b40ad752fdd2348cdb7bc8de425225 SHA512 4a6316f03d1b77bcd6c08de0daefc3f29b4c8c575eae9f901951e2b43f2739904136b9455f567b66fc9a4e4c64fe92584608f1878dd8c30c0352ea9ee1e2e314
 DIST QMPlay2-src-21.03.09.tar.xz 1568600 BLAKE2B da3a185ae2e372b0bad697e4ad7d836647c5b4bb376f0ee3f7e85e387c10b86f1a3fdaf8eb13a2c9a8d3b7d56105e282cc82f22d31043e9e418ee907776f1db2 SHA512 311fe45a9ee237556faeee29633be6161407a31b19fd3bceca5a164e92ff1757824094d20f6b556c0a4beaac07a14179e812faafc5e41ee904cf1ce1827fb138
+DIST QMPlay2-src-21.06.07.tar.xz 1579640 BLAKE2B f687cf19ce8d4a606b5271c2e5789d5194233bd300f29d165354cc8784808a148e02536ea8a593c036cd75d1e40a335177f1b9db33016008bbb2f9516daf7e61 SHA512 41558e2df09a188cef05c2a24393e67ce4d1ef1268ff1bdd1ac97ec666d9f8f849817b0c64e384624403a8f6f60cb985dde188cb3c75afd731e42f776076d282

diff --git a/media-video/qmplay2/qmplay2-21.06.07.ebuild b/media-video/qmplay2/qmplay2-21.06.07.ebuild
new file mode 100644
index 00000000000..d6a9054ddf1
--- /dev/null
+++ b/media-video/qmplay2/qmplay2-21.06.07.ebuild
@@ -0,0 +1,134 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit cmake xdg
+
+DESCRIPTION="A Qt-based video player, which can play most formats and codecs"
+HOMEPAGE="https://github.com/zaps166/QMPlay2"
+
+if [[ ${PV} == *9999 ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/zaps166/QMPlay2"
+else
+	SRC_URI="https://github.com/zaps166/QMPlay2/releases/download/${PV}/QMPlay2-src-${PV}.tar.xz"
+	KEYWORDS="~amd64 ~x86"
+	S="${WORKDIR}/QMPlay2-src-${PV}"
+fi
+
+LICENSE="LGPL-3"
+SLOT="0"
+
+IUSE="avdevice +audiofilters +alsa cdio cuvid dbus extensions
+	gme inputs libass modplug notifications opengl pipewire portaudio
+	pulseaudio sid shaders vaapi vdpau +videofilters visualizations vulkan xv"
+
+REQUIRED_USE="
+	audiofilters? ( || ( alsa pipewire portaudio pulseaudio ) )
+	extensions? ( dbus )
+	shaders? ( vulkan )"
+
+RDEPEND="
+	dev-qt/qtcore:5
+	dev-qt/qtsvg:5
+	dev-qt/qtwidgets:5
+	dev-qt/qtx11extras:5
+	media-video/ffmpeg
+	|| (
+		dev-qt/qtgui:5[X(-)]
+		dev-qt/qtgui:5[xcb(-)]
+	)
+	alsa? ( media-libs/alsa-lib )
+	cdio? ( dev-libs/libcdio[cddb] )
+	dbus? ( dev-qt/qtdbus:5 )
+	extensions? (
+		dev-qt/qtdeclarative:5
+		media-libs/taglib
+	)
+	gme? ( media-libs/game-music-emu )
+	libass? ( media-libs/libass )
+	opengl? ( virtual/opengl )
+	pipewire? ( media-video/pipewire )
+	portaudio? ( media-libs/portaudio )
+	pulseaudio? ( media-sound/pulseaudio )
+	sid? ( media-libs/libsidplayfp )
+	shaders? ( >=media-libs/shaderc-2020.1 )
+	vaapi? (
+		>=media-video/ffmpeg-4.1.3[vaapi]
+		x11-libs/libva[drm,opengl]
+	)
+	vdpau? ( media-video/ffmpeg[vdpau] )
+	videofilters? ( dev-qt/qtconcurrent:5 )
+	vulkan? (
+		>=dev-qt/qtgui-5.14.1:5[vulkan]
+		>=media-libs/vulkan-loader-1.2.133
+	)
+	xv? ( x11-libs/libXv )"
+
+DEPEND="${RDEPEND}"
+BDEPEND="
+	dev-qt/linguist-tools:5
+	virtual/pkgconfig"
+
+src_prepare() {
+	# disable compress man pages
+	sed -r \
+		-e 's/if\(GZIP\)/if\(TRUE\)/' \
+		-e 's/(install.+QMPlay2\.1)\.gz/\1/' \
+		-i src/gui/CMakeLists.txt || die
+
+	cmake_src_prepare
+}
+
+src_configure() {
+	local mycmakeargs=(
+		# core
+		-DUSE_LINK_TIME_OPTIMIZATION=false
+		-DUSE_ALSA=$(usex alsa)
+		-DUSE_AUDIOCD=$(usex cdio)
+		-DUSE_FREEDESKTOP_NOTIFICATIONS=$(usex dbus) # https://github.com/zaps166/QMPlay2/issues/134
+		-DUSE_LIBASS=$(usex libass)
+		-DUSE_NOTIFY=$(usex notifications)
+		-DUSE_OPENGL=$(usex opengl)
+		-DUSE_VULKAN=$(usex vulkan)
+		-DUSE_GLSLC=$(usex shaders)
+		-DUSE_XVIDEO=$(usex xv)
+
+		# ffmpeg
+		-DUSE_FFMPEG_AVDEVICE=$(usex avdevice)
+		-DUSE_FFMPEG_VAAPI=$(usex vaapi)
+		-DUSE_FFMPEG_VDPAU=$(usex vdpau)
+
+		# chiptune
+		-DUSE_CHIPTUNE_GME=$(usex gme)
+		-DUSE_CHIPTUNE_SID=$(usex sid)
+
+		# modules
+		-DUSE_AUDIOFILTERS=$(usex audiofilters)
+		-DUSE_CUVID=$(usex cuvid)
+		-DUSE_INPUTS=$(usex inputs)
+		-DUSE_MODPLUG=$(usex modplug)
+		-DUSE_PIPEWIRE=$(usex pipewire)
+		-DUSE_PORTAUDIO=$(usex portaudio)
+		-DUSE_PULSEAUDIO=$(usex pulseaudio)
+		-DUSE_VIDEOFILTERS=$(usex videofilters)
+		-DUSE_VISUALIZATIONS=$(usex visualizations)
+
+		# extensions
+		-DUSE_EXTENSIONS=$(usex extensions)
+		-DUSE_TAGLIB=$(usex extensions)
+		-DUSE_LASTFM=$(usex extensions)
+		-DUSE_LYRICS=$(usex extensions)
+		-DUSE_MEDIABROWSER=$(usex extensions)
+		-DUSE_MPRIS2=$(usex extensions)
+	)
+
+	if [[ ${PV} == *9999 ]]; then
+		mycmakeargs+=( -DUSE_GIT_VERSION=true )
+	else
+		mycmakeargs+=( -DUSE_GIT_VERSION=false )
+	fi
+
+	cmake_src_configure
+}