[gentoo-commits] repo/gentoo:master commit in: dev-python/sphinx/

[Michał Górny]

commit:     488343caa60ebacb1a4ba8a95498fe87263d120a
Author:     Michał Górny <mgorny <AT> gentoo <DOT> org>
AuthorDate: Mon Mar  2 15:32:52 2020 +0000
Commit:     Michał Górny <mgorny <AT> gentoo <DOT> org>
CommitDate: Mon Mar  2 20:22:21 2020 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=488343ca

dev-python/sphinx: Bump to 2.4.3

Closes: https://bugs.gentoo.org/683194
Signed-off-by: Michał Górny <mgorny <AT> gentoo.org>

 dev-python/sphinx/Manifest            |   1 +
 dev-python/sphinx/sphinx-2.4.3.ebuild | 106 ++++++++++++++++++++++++++++++++++
 2 files changed, 107 insertions(+)

diff --git a/dev-python/sphinx/Manifest b/dev-python/sphinx/Manifest
index eb30947ca40..1f76e63d576 100644
--- a/dev-python/sphinx/Manifest
+++ b/dev-python/sphinx/Manifest
@@ -1,2 +1,3 @@
 DIST Sphinx-1.7.5.tar.gz 4726802 BLAKE2B 8d828dcae1f3ebb813c5f2de8c096a3fac4ab88b424955c27592349c544b775a21703c904a54efa7f86e1967198f4950804904a82a7142a3499f33c5343506e3 SHA512 db2a8df2cdb2ed78ce2341175575c2b04a149451b2bc8a4f74ddc73e308a19d505874fdbae4e370ce48a9b1cdb4de47cdab489bc57c1b378e857d5b8d04a07b8
 DIST Sphinx-2.0.1.tar.gz 6017030 BLAKE2B a446aab8c7f5a4adc93477f4f60ca975690cb4c507d6e51393a4b2c4c56563b9a12e3ea3f85d214c6bdbc7834be107384fe9029d09a73da207fd9699c4b77ab8 SHA512 28430912917a8e3eb6efe6b69268e2a5ae06795c261f2a18ef62f781e365396832c4e4bcfaad7704b1c5f840e98a9dfb82e3b438a491a13cea5c10bee66bf23b
+DIST Sphinx-2.4.3.tar.gz 5711784 BLAKE2B 624bfad7bfb75f568ea28063ac909685a3f563dfff4605ea212fa53bf79b50e7743f1b642ccb1f73b899cfd33841977203ee73d7ab624d553889cd071f204535 SHA512 cafd3b185210f3f2ccab48508d3abde50178ffa30136c0302c5855780b316f976566891ad4852f246ed5ebfa95e56701ef5096ca7dc98d91f3ba4e84754c8f6e

diff --git a/dev-python/sphinx/sphinx-2.4.3.ebuild b/dev-python/sphinx/sphinx-2.4.3.ebuild
new file mode 100644
index 00000000000..2f474efa635
--- /dev/null
+++ b/dev-python/sphinx/sphinx-2.4.3.ebuild
@@ -0,0 +1,106 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+DISTUTILS_USE_SETUPTOOLS=rdepend
+PYTHON_COMPAT=( python3_{6,7,8} pypy3 )
+PYTHON_REQ_USE="threads(+)"
+
+inherit distutils-r1
+
+DESCRIPTION="Python documentation generator"
+HOMEPAGE="https://www.sphinx-doc.org/
+	https://github.com/sphinx-doc/sphinx"
+SRC_URI="mirror://pypi/S/${PN^}/${P^}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~x64-solaris"
+IUSE="doc latex test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	<dev-python/alabaster-0.8[${PYTHON_USEDEP}]
+	dev-python/Babel[${PYTHON_USEDEP}]
+	dev-python/docutils[${PYTHON_USEDEP}]
+	dev-python/imagesize[${PYTHON_USEDEP}]
+	dev-python/jinja[${PYTHON_USEDEP}]
+	dev-python/pygments[${PYTHON_USEDEP}]
+	dev-python/requests[${PYTHON_USEDEP}]
+	dev-python/snowballstemmer[${PYTHON_USEDEP}]
+	dev-python/sphinxcontrib-applehelp[${PYTHON_USEDEP}]
+	dev-python/sphinxcontrib-devhelp[${PYTHON_USEDEP}]
+	dev-python/sphinxcontrib-jsmath[${PYTHON_USEDEP}]
+	dev-python/sphinxcontrib-htmlhelp[${PYTHON_USEDEP}]
+	dev-python/sphinxcontrib-serializinghtml[${PYTHON_USEDEP}]
+	dev-python/sphinxcontrib-qthelp[${PYTHON_USEDEP}]
+	dev-python/sphinx_rtd_theme[${PYTHON_USEDEP}]
+	dev-python/packaging[${PYTHON_USEDEP}]
+	latex? (
+		dev-texlive/texlive-latexextra
+		dev-texlive/texlive-luatex
+		app-text/dvipng
+	)"
+DEPEND="${RDEPEND}
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	doc? (
+		dev-python/sphinxcontrib-websupport[${PYTHON_USEDEP}]
+	)
+	test? (
+		dev-python/html5lib[${PYTHON_USEDEP}]
+		dev-python/pytest[${PYTHON_USEDEP}]
+		virtual/imagemagick-tools[jpeg,png,svg]
+		dev-texlive/texlive-latexextra
+		dev-texlive/texlive-luatex
+		app-text/dvipng
+	)"
+
+S="${WORKDIR}/${P^}"
+
+python_prepare_all() {
+	# remove tests that fail due to network-sandbox
+	rm tests/test_build_linkcheck.py || die "Failed to remove web tests"
+	sed -i -e 's:test_latex_images:_&:' tests/test_build_latex.py || die
+
+	# fail under pypy3
+	sed -i -e '/def test_partialfunction/i\
+@×××××××××××.skipif(hasattr(sys, "pypy_version_info"), reason="broken on pypy3")' \
+		-e '/def test_autodoc_typed_instance_variables/i\
+@×××××××××××.skipif(hasattr(sys, "pypy_version_info"), reason="broken on pypy3")' \
+		tests/test_autodoc.py || die
+	sed -i -e '11aimport sys' \
+		-e '/def test_autodoc_typehints_signature/i\
+@×××××××××××.skipif(hasattr(sys, "pypy_version_info"), reason="broken on pypy3")' \
+		tests/test_ext_autodoc_configs.py || die
+	sed -i -e '/def test_annotated_assignment_py36/i\
+@×××××××××××.skipif(hasattr(sys, "pypy_version_info"), reason="broken on pypy3")' \
+		tests/test_pycode_parser.py || die
+
+	distutils-r1_python_prepare_all
+}
+
+python_compile() {
+	distutils-r1_python_compile
+
+	# Generate the grammar. It will be caught by install somehow.
+	# Note that the tests usually do it for us. However, I don't want
+	# to trust USE=test really running all the tests, especially
+	# with FEATURES=test-fail-continue.
+	pushd "${BUILD_DIR}"/lib >/dev/null || die
+	"${EPYTHON}" -m sphinx.pycode.__init__ || die "Grammar generation failed."
+	popd >/dev/null || die
+}
+
+python_compile_all() {
+	if use doc; then
+		esetup.py build_sphinx
+		HTML_DOCS=( "${BUILD_DIR}"/sphinx/html/. )
+	fi
+}
+
+python_test() {
+	mkdir -p "${BUILD_DIR}/sphinx_tempdir" || die
+	local -x SPHINX_TEST_TEMPDIR="${BUILD_DIR}/sphinx_tempdir"
+	pytest -vv || die "Tests fail with ${EPYTHON}"
+}