[gentoo-commits] gentoo-x86 commit in app-misc/lcdproc: ChangeLog lcdproc-0.5.2-r1.ebuild lcdproc-0.5.1-r4.ebuild lcdproc-0.5.2-r2.ebuild

[Robert Buchholz (rbu)]

rbu         08/09/12 23:58:55

  Modified:             ChangeLog lcdproc-0.5.2-r1.ebuild
                        lcdproc-0.5.1-r4.ebuild
  Added:                lcdproc-0.5.2-r2.ebuild
  Log:
    Add imonlcd to support Antec iMON LCD modules (bug #232328), lcdproc init
    script should start after ntp-client (bug #234084), fix quoting.
  (Portage version: 2.2_rc8/cvs/Linux 2.6.27-rc6 x86_64)

Revision  Changes    Path
1.64                 app-misc/lcdproc/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-misc/lcdproc/ChangeLog?rev=1.64&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-misc/lcdproc/ChangeLog?rev=1.64&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-misc/lcdproc/ChangeLog?r1=1.63&r2=1.64

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/app-misc/lcdproc/ChangeLog,v
retrieving revision 1.63
retrieving revision 1.64
diff -u -r1.63 -r1.64
--- ChangeLog	31 Jul 2008 16:31:50 -0000	1.63
+++ ChangeLog	12 Sep 2008 23:58:55 -0000	1.64
@@ -1,6 +1,14 @@
 # ChangeLog for app-misc/lcdproc
 # Copyright 2002-2008 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-misc/lcdproc/ChangeLog,v 1.63 2008/07/31 16:31:50 ulm Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-misc/lcdproc/ChangeLog,v 1.64 2008/09/12 23:58:55 rbu Exp $
+
+*lcdproc-0.5.2-r2 (12 Sep 2008)
+
+  12 Sep 2008; Robert Buchholz <rbu@g.o>
+  +files/0.5.2-r2-lcdproc.initd, lcdproc-0.5.1-r4.ebuild,
+  lcdproc-0.5.2-r1.ebuild, +lcdproc-0.5.2-r2.ebuild:
+  Add imonlcd to support Antec iMON LCD modules (bug #232328), lcdproc init
+  script should start after ntp-client (bug #234084), fix quoting.
 
   31 Jul 2008; Ulrich Mueller <ulm@g.o> metadata.xml:
   Add USE flag description to metadata wrt GLEP 56.



1.8                  app-misc/lcdproc/lcdproc-0.5.2-r1.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-misc/lcdproc/lcdproc-0.5.2-r1.ebuild?rev=1.8&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-misc/lcdproc/lcdproc-0.5.2-r1.ebuild?rev=1.8&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-misc/lcdproc/lcdproc-0.5.2-r1.ebuild?r1=1.7&r2=1.8

Index: lcdproc-0.5.2-r1.ebuild
===================================================================
RCS file: /var/cvsroot/gentoo-x86/app-misc/lcdproc/lcdproc-0.5.2-r1.ebuild,v
retrieving revision 1.7
retrieving revision 1.8
diff -u -r1.7 -r1.8
--- lcdproc-0.5.2-r1.ebuild	14 Aug 2007 21:08:27 -0000	1.7
+++ lcdproc-0.5.2-r1.ebuild	12 Sep 2008 23:58:55 -0000	1.8
@@ -1,6 +1,6 @@
-# Copyright 1999-2007 Gentoo Foundation
+# Copyright 1999-2008 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/app-misc/lcdproc/lcdproc-0.5.2-r1.ebuild,v 1.7 2007/08/14 21:08:27 dertobi123 Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-misc/lcdproc/lcdproc-0.5.2-r1.ebuild,v 1.8 2008/09/12 23:58:55 rbu Exp $
 
 WANT_AUTOMAKE="1.9"
 inherit eutils autotools multilib
@@ -131,12 +131,12 @@
 
 	if use doc; then
 		ebegin "Creating user documentation"
-		cd ${S}/docs/lcdproc-user
+		cd "${S}"/docs/lcdproc-user
 		xmlto html lcdproc-user.docbook
 		eend $?
 
 		ebegin "Creating dev documentation"
-		cd ${S}/docs/lcdproc-dev
+		cd "${S}"/docs/lcdproc-dev
 		xmlto html lcdproc-dev.docbook
 		eend $?
 	fi



1.7                  app-misc/lcdproc/lcdproc-0.5.1-r4.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-misc/lcdproc/lcdproc-0.5.1-r4.ebuild?rev=1.7&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-misc/lcdproc/lcdproc-0.5.1-r4.ebuild?rev=1.7&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-misc/lcdproc/lcdproc-0.5.1-r4.ebuild?r1=1.6&r2=1.7

Index: lcdproc-0.5.1-r4.ebuild
===================================================================
RCS file: /var/cvsroot/gentoo-x86/app-misc/lcdproc/lcdproc-0.5.1-r4.ebuild,v
retrieving revision 1.6
retrieving revision 1.7
diff -u -r1.6 -r1.7
--- lcdproc-0.5.1-r4.ebuild	6 May 2007 21:26:27 -0000	1.6
+++ lcdproc-0.5.1-r4.ebuild	12 Sep 2008 23:58:55 -0000	1.7
@@ -1,6 +1,6 @@
-# Copyright 1999-2007 Gentoo Foundation
+# Copyright 1999-2008 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/app-misc/lcdproc/lcdproc-0.5.1-r4.ebuild,v 1.6 2007/05/06 21:26:27 rbu Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-misc/lcdproc/lcdproc-0.5.1-r4.ebuild,v 1.7 2008/09/12 23:58:55 rbu Exp $
 
 WANT_AUTOCONF="latest"
 WANT_AUTOMAKE="latest"
@@ -135,12 +135,12 @@
 
 	if use doc; then
 		ebegin "Creating user documentation"
-		cd ${S}/docs/lcdproc-user
+		cd "${S}"/docs/lcdproc-user
 		xmlto html lcdproc-user.docbook
 		eend $?
 
 		ebegin "Creating dev documentation"
-		cd ${S}/docs/lcdproc-dev
+		cd "${S}"/docs/lcdproc-dev
 		xmlto html lcdproc-dev.docbook
 		eend $?
 	fi



1.1                  app-misc/lcdproc/lcdproc-0.5.2-r2.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-misc/lcdproc/lcdproc-0.5.2-r2.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-misc/lcdproc/lcdproc-0.5.2-r2.ebuild?rev=1.1&content-type=text/plain

Index: lcdproc-0.5.2-r2.ebuild
===================================================================
# Copyright 1999-2008 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/app-misc/lcdproc/lcdproc-0.5.2-r2.ebuild,v 1.1 2008/09/12 23:58:55 rbu Exp $

WANT_AUTOMAKE="1.9"
inherit eutils autotools multilib

DESCRIPTION="Client/Server suite to drive all kinds of LCD (-like) devices"
HOMEPAGE="http://lcdproc.org/"
SRC_URI="mirror://sourceforge/${PN}/${P}.tar.gz
	mirror://gentoo/${PF}-patches.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~ppc ~ppc64 ~sparc ~x86"

IUSE="doc debug nfs samba seamless-hbars usb lirc irman joystick"

# The following array holds the USE_EXPANDed keywords
IUSE_LCD_DEVICES=(ncurses bayrad cfontz cfontz633 cfontzpacket
	cwlinux eyeboxone g15 graphlcd glk
	hd44780 icpa106 imon imonlcd iowarrior
	lb216 lcdm001 lcterm
	md8800 ms6931 mtcs16209x mtxorb noritakevfd
	pyramid sed1330 sed1520 serialvfd sli
	stv5730 svga t6963 text tyan
	ula200 xosd ea65 picolcd serialpos )

# Iterate through the array and add the lcd_devices_* that we support
NUM_DEVICES=${#IUSE_LCD_DEVICES[@]}
index=0
while [ "${index}" -lt "${NUM_DEVICES}" ] ; do
	IUSE="${IUSE} lcd_devices_${IUSE_LCD_DEVICES[${index}]}"
	let "index = ${index} + 1"
done

RDEPEND="
	usb?      ( dev-libs/libusb )
	lirc?     ( app-misc/lirc )
	irman?    ( media-libs/libirman )

	lcd_devices_graphlcd?  ( app-misc/graphlcd-base  app-misc/glcdprocdriver )
	lcd_devices_g15?      ( dev-libs/libg15  >=dev-libs/libg15render-1.1.1 )
	lcd_devices_ncurses?   ( sys-libs/ncurses )
	lcd_devices_svga?     ( media-libs/svgalib )
	lcd_devices_ula200?   ( >=dev-embedded/libftdi-0.7  dev-libs/libusb )
	lcd_devices_xosd?     ( x11-libs/xosd  x11-libs/libX11  x11-libs/libXext )
	lcd_devices_cfontzpacket? ( dev-libs/libusb )
	lcd_devices_cwlinux?    ( dev-libs/libusb )
	lcd_devices_pyramid?  ( dev-libs/libusb )
	lcd_devices_picolcd?  ( dev-libs/libusb )"
DEPEND="${RDEPEND}
	doc?      ( app-text/xmlto )"
RDEPEND="${RDEPEND}
	lcd_devices_g15?      ( app-misc/g15daemon )"

pkg_setup() {
	if [ -n "${LCDPROC_DRIVERS}" ] ; then
		ewarn "Setting the drivers to compile via LCDPROC_DRIVERS is not supported anymore."
		ewarn "Please use LCD_DEVICES now and see emerge -pv output for the options."
	fi
}

src_unpack() {
	unpack ${A}
	cd "${S}"

	epatch "${WORKDIR}"/${PF}-patches/${PV}-imonlcd-0.3.patch

	epatch "${WORKDIR}"/${PF}-patches/${PV}-picolcd.patch

	sed -i "79s:server/drivers:/usr/$(get_libdir)/lcdproc:" LCDd.conf
	einfo "Patching LCDd.conf to use DriverPath=/usr/$(get_libdir)/lcdproc/"

	eautoreconf
}

src_compile() {
	# This array contains the driver names required by configure --with-drivers=
	# The positions must be the same as the corresponding use_expand flags
	local DEVICE_DRIVERS=(curses bayrad CFontz CFontz633 CFontzPacket
		CwLnx EyeboxOne g15 glcdlib glk
		hd44780 icp_a106 imon imonlcd IOWarrior
		lb216 lcdm001 lcterm
		MD8800 ms6931 mtc_s16209x MtxOrb NoritakeVFD
		pyramid sed1330 sed1520 serialVFD sli
		stv5730 svga t6963 text tyan
		ula200 xosd ea65 picolcd serialPOS)

	# Generate comma separated list of drivers
	COMMA_DRIVERS=""
	FIRST_DRIVER=""
	local index=0

	while [ "${index}" -lt "${NUM_DEVICES}" ] ; do
		if use "lcd_devices_${IUSE_LCD_DEVICES[${index}]}" ; then
			append-driver "${DEVICE_DRIVERS[${index}]}"
		fi
		let "index = ${index} + 1"
	done

	# Append the not-lcd-drivers (input)
	use lirc && append-driver "lirc"
	use irman && append-driver "irman"
	use joystick && append-driver "joy"

	if [ -z "${COMMA_DRIVERS}" ] ; then
		ewarn "You are compiling LCDd without support for any LCD drivers at all."
	else
		# Patch the config to contain a driver that is actually installed instead of the default
		elog "Compiling the following drivers for LCDd: ${COMMA_DRIVERS}"
		elog "Setting Driver=${FIRST_DRIVER} in LCDd.conf"
		sed -i "44s:curses:${FIRST_DRIVER}:" LCDd.conf
	fi

	local ENABLEUSB
	if use lcd_devices_cfontzpacket || use lcd_devices_cwlinux || use lcd_devices_pyramid; then
		ENABLEUSB="--enable-libusb"
	else
		ENABLEUSB="$(use_enable usb libusb)"
	fi

	econf \
		$(use_enable debug) \
		$(use_enable nfs stat-nfs) \
		$(use_enable samba stat-smbfs ) \
		$(use_enable seamless-hbars) \
		${ENABLEUSB} \
		"--enable-drivers=${COMMA_DRIVERS}"  \
		|| die "configure failed"

	emake || die "make failed"

	if use doc; then
		ebegin "Creating user documentation"
		cd "${S}"/docs/lcdproc-user
		xmlto html lcdproc-user.docbook
		eend $?

		ebegin "Creating dev documentation"
		cd "${S}"/docs/lcdproc-dev
		xmlto html lcdproc-dev.docbook
		eend $?
	fi
}

append-driver() {
	[[ -z $* ]] && return 0
	if [ -z "${COMMA_DRIVERS}" ] ; then
		# First in the list
		COMMA_DRIVERS="$*"
		FIRST_DRIVER="$*"
	else
		# Second, third, ... include a comma at the front
		COMMA_DRIVERS="${COMMA_DRIVERS},$*"
	fi
	return 0
}

src_install() {
	emake DESTDIR="${D}" install || die "make install failed"

	# move example clients installed to /usr/bin
	rm -f "${D}"/usr/bin/{tail,lcdmetar,iosock,fortune,x11amp}.pl
	insinto /usr/share/lcdproc/clients
	doins clients/examples/*.pl
	doins clients/metar/

	newinitd "${FILESDIR}/0.5.1-LCDd.initd" LCDd
	newinitd "${FILESDIR}/0.5.2-r2-lcdproc.initd" lcdproc

	dodoc README CREDITS ChangeLog INSTALL TODO
	dodoc docs/README.* docs/*.txt

	if use doc; then
		insinto /usr/share/doc/${PF}/lcdproc-user
		doins docs/lcdproc-user/*.html
		insinto /usr/share/doc/${PF}/lcdproc-dev
		doins docs/lcdproc-dev/*.html
	fi
}

pkg_postinst() {
	ewarn "IMPORTANT: Please update your /etc/LCDd.conf"
	ewarn "As of lcdproc-0.5.1-r2, the DriverPath changed from /usr/share/lcdproc to /usr/$(get_libdir)/lcdproc ."
}