[gentoo-commits] repo/gentoo:master commit in: dev-python/requests-cache/

[Michał Górny]

commit:     230222f2d4a953b35c6e028afbdd78b84ef5f3f1
Author:     Michał Górny <mgorny <AT> gentoo <DOT> org>
AuthorDate: Thu Jun 30 03:21:50 2022 +0000
Commit:     Michał Górny <mgorny <AT> gentoo <DOT> org>
CommitDate: Thu Jun 30 04:26:54 2022 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=230222f2

dev-python/requests-cache: Bump to 0.9.5

Signed-off-by: Michał Górny <mgorny <AT> gentoo.org>

 dev-python/requests-cache/Manifest                 |  1 +
 dev-python/requests-cache/metadata.xml             |  1 +
 .../requests-cache/requests-cache-0.9.5.ebuild     | 71 ++++++++++++++++++++++
 3 files changed, 73 insertions(+)

diff --git a/dev-python/requests-cache/Manifest b/dev-python/requests-cache/Manifest
index 6e8e1ee627e8..1c63fb6def33 100644
--- a/dev-python/requests-cache/Manifest
+++ b/dev-python/requests-cache/Manifest
@@ -1 +1,2 @@
 DIST requests-cache-0.9.4.gh.tar.gz 1541821 BLAKE2B 90f3ffe8f4213a47d19c1190f1201bb484473a4ee2fae82dff59c9e80bc8c154739e99f5024aa55b436f9e620d5594441df61e2db44e3cbb381d394c1b6b4a0b SHA512 66023dc8b153070a532f160af58ac2102f6b9d536a0045c4c62ad1d4175f59df6e7db5a25422f5610a2f17049270ad0b63c6023ddddf64235432a63d2cce9b91
+DIST requests-cache-0.9.5.gh.tar.gz 1542034 BLAKE2B 01996e7536ce967dee2b909091d1eb08501b3882b6171a5460b2196666eed848dec89a85ef8ea0c892b2fd153f90107948239de04b973e7766d3acfad7b10059 SHA512 de1481ff609f3ff36ed662d986fb86a500a8d26755832478a9a4396f2c71934b5f65540137b92365eb36f66087b3fbc1cd72c63d37546d09c86bbee7340fd8eb

diff --git a/dev-python/requests-cache/metadata.xml b/dev-python/requests-cache/metadata.xml
index 809ce0ce78ae..dc99a675de0c 100644
--- a/dev-python/requests-cache/metadata.xml
+++ b/dev-python/requests-cache/metadata.xml
@@ -11,6 +11,7 @@
   </maintainer>
   <stabilize-allarches/>
   <upstream>
+    <remote-id type="github">requests-cache/requests-cache</remote-id>
     <remote-id type="pypi">requests-cache</remote-id>
   </upstream>
 </pkgmetadata>

diff --git a/dev-python/requests-cache/requests-cache-0.9.5.ebuild b/dev-python/requests-cache/requests-cache-0.9.5.ebuild
new file mode 100644
index 000000000000..a05212c9f27b
--- /dev/null
+++ b/dev-python/requests-cache/requests-cache-0.9.5.ebuild
@@ -0,0 +1,71 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=poetry
+PYTHON_COMPAT=( python3_{8..10} )
+PYTHON_REQ_USE="sqlite"
+
+inherit distutils-r1 optfeature
+
+HOMEPAGE="
+	https://pypi.org/project/requests-cache/
+	https://github.com/requests-cache/requests-cache/
+"
+DESCRIPTION="Persistent cache for requests library"
+SRC_URI="
+	https://github.com/requests-cache/requests-cache/archive/v${PV}.tar.gz
+		-> ${P}.gh.tar.gz
+"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+
+RDEPEND="
+	dev-python/attrs[${PYTHON_USEDEP}]
+	dev-python/appdirs[${PYTHON_USEDEP}]
+	<dev-python/cattrs-22.2[${PYTHON_USEDEP}]
+	>=dev-python/requests-2.0.0[${PYTHON_USEDEP}]
+	dev-python/urllib3[${PYTHON_USEDEP}]
+	>=dev-python/url-normalize-1.4[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		dev-python/itsdangerous[${PYTHON_USEDEP}]
+		dev-python/pytest-httpbin[${PYTHON_USEDEP}]
+		dev-python/requests-mock[${PYTHON_USEDEP}]
+		dev-python/responses[${PYTHON_USEDEP}]
+		dev-python/timeout-decorator[${PYTHON_USEDEP}]
+		dev-python/ujson[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+
+python_test() {
+	local EPYTEST_IGNORE=(
+		# These require extra servers running
+		tests/integration/test_dynamodb.py
+		tests/integration/test_gridfs.py
+		tests/integration/test_mongodb.py
+		tests/integration/test_redis.py
+	)
+	local EPYTEST_DESELECT=(
+		# Requires Internet access
+		tests/integration/test_compat.py::test_version_upgrade
+	)
+
+	local -x USE_PYTEST_HTTPBIN=true
+	epytest
+}
+
+pkg_postinst() {
+	optfeature "redis backend" "dev-python/redis-py"
+	optfeature "MongoDB backend" "dev-python/pymongo"
+
+	optfeature "JSON serialization" "dev-python/ujson"
+	optfeature "YAML serialization" "dev-python/pyyaml"
+	optfeature "signing serialized data" "dev-python/itsdangerous"
+}