[gentoo-commits] gentoo-x86 commit in app-crypt/eid-mw: metadata.xml eid-mw-4.0.2_p1188.ebuild ChangeLog

[Diego Petteno (flameeyes)]

flameeyes    12/04/07 22:58:18

  Added:                metadata.xml eid-mw-4.0.2_p1188.ebuild ChangeLog
  Log:
  Initial import of eid-mw by Vincent Hardy.
  
  (Portage version: 2.2.0_alpha100/cvs/Linux x86_64)

Revision  Changes    Path
1.1                  app-crypt/eid-mw/metadata.xml

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-crypt/eid-mw/metadata.xml?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-crypt/eid-mw/metadata.xml?rev=1.1&content-type=text/plain

Index: metadata.xml
===================================================================
<?xml version="1.0" encoding="UTF-8"?>
<!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
<pkgmetadata>
<maintainer>
  <email>vincent.hardy.be@×××××.com</email>
</maintainer>
<maintainer>
  <email>flameeyes@g.o</email>
</maintainer>
<longdescription>
eid-mw is Belgian Electronic Identity Card (eID) middleware supplied by the Belgian Federal Government.

With your eID, you can:
- identify yourself when necessary. All you have to do is insert the card in the reader. All your details then appear automatically on the PC screen.
- authenticate yourself. This is a way of checking that you are who you say you are. That can be handy on the internet or to enable your children to chat in safety.
- place a legally binding electronic signature on electronic documents.

These three functions form the basis of the countless applications for your eID. Go to http://welcome-to-e-belgium.be/en/ and check out what can you do with it? and discover all the things you can use the eID for.
</longdescription>
<use>
  <flag name="gtk">
    Enable the dialog pages, by using <pkg>x11-libs/gtk:2</pkg>
  </flag>
  <flag name="xpi">
    Build and install an extension for Mozilla browsers.
  </flag>
</use>
</pkgmetadata>



1.1                  app-crypt/eid-mw/eid-mw-4.0.2_p1188.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-crypt/eid-mw/eid-mw-4.0.2_p1188.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-crypt/eid-mw/eid-mw-4.0.2_p1188.ebuild?rev=1.1&content-type=text/plain

Index: eid-mw-4.0.2_p1188.ebuild
===================================================================
# Copyright 1999-2012 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/app-crypt/eid-mw/eid-mw-4.0.2_p1188.ebuild,v 1.1 2012/04/07 22:58:18 flameeyes Exp $

EAPI=4

inherit eutils versionator mozextension

if [[ ${PV} == "9999" ]] ; then
	ESVN_REPO_URI="http://eid-mw.googlecode.com/svn/trunk/"
	inherit subversion autotools
	SRC_URI=""
else
	MY_P="${PN}-${PV/_p/-}"
	SRC_URI="http://eid-mw.googlecode.com/files/${MY_P}.tar.gz"
	KEYWORDS="~x86 ~amd64"
	S="${WORKDIR}/eid-mw-$(get_version_component_range 1-3)"
fi

SLOT="0"
LICENSE="GPL-3"
DESCRIPTION="Belgian Electronic Identity Card middleware supplied by the Belgian Federal Government."

HOMEPAGE="http://code.google.com/p/eid-mw"

IUSE="+gtk +xpi"

RDEPEND="gtk? ( x11-libs/gtk+:2 )
	>=sys-apps/pcsc-lite-1.2.9
	xpi? ( || ( >=www-client/firefox-bin-3.6.24
		>=www-client/firefox-3.6.20 ) )
	!app-misc/beid-runtime"

DEPEND="${RDEPEND}
	app-arch/zip
	dev-util/pkgconfig"

if [[ ${PV} == "9999" ]]; then
	src_prepare() {
		eautoreconf
	}
fi

src_configure() {
	econf $(use_enable gtk dialogs) --disable-static
}

src_install() {
	emake DESTDIR="${D}" install
	if use xpi; then
		declare MOZILLA_FIVE_HOME
		if has_version '>=www-client/firefox-3.6.20'; then
			MOZILLA_FIVE_HOME="/usr/$(get_libdir)/firefox"
			xpi_install	"${D}/usr/share/mozilla/extensions/{ec8030f7-c20a-464f-9b0e-13a3a9e97384}/belgiumeid@×××××××××××.be"
		fi
		if has_version '>=www-client/firefox-bin-3.6.24'; then
			MOZILLA_FIVE_HOME="/opt/firefox"
			xpi_install	"${D}/usr/share/mozilla/extensions/{ec8030f7-c20a-464f-9b0e-13a3a9e97384}/belgiumeid@×××××××××××.be"
		fi
	fi
	rm -r "${D}/usr/share" "${D}"/usr/lib*/*.la
}



1.1                  app-crypt/eid-mw/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-crypt/eid-mw/ChangeLog?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-crypt/eid-mw/ChangeLog?rev=1.1&content-type=text/plain

Index: ChangeLog
===================================================================
# ChangeLog for app-crypt/eid-mw
# Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
# $Header: /var/cvsroot/gentoo-x86/app-crypt/eid-mw/ChangeLog,v 1.1 2012/04/07 22:58:18 flameeyes Exp $

*eid-mw-4.0.2_p1188 (07 Apr 2012)

  07 Apr 2012; Diego E. Pettenò <flameeyes@g.o>
  +eid-mw-4.0.2_p1188.ebuild, +metadata.xml:
  Initial import of eid-mw by Vincent Hardy.