[gentoo-commits] gentoo-x86 commit in sys-fs/udev: udev-196.ebuild ChangeLog udev-9999.ebuild

[Samuli Suominen (ssuominen)]

ssuominen    12/12/02 02:03:22

  Modified:             ChangeLog udev-9999.ebuild
  Added:                udev-196.ebuild
  Log:
  Version bump.
  
  (Portage version: 2.2.0_alpha142/cvs/Linux x86_64, signed Manifest commit with key 4868F14D)

Revision  Changes    Path
1.747                sys-fs/udev/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-fs/udev/ChangeLog?rev=1.747&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-fs/udev/ChangeLog?rev=1.747&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-fs/udev/ChangeLog?r1=1.746&r2=1.747

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/sys-fs/udev/ChangeLog,v
retrieving revision 1.746
retrieving revision 1.747
diff -u -r1.746 -r1.747
--- ChangeLog	1 Dec 2012 15:59:53 -0000	1.746
+++ ChangeLog	2 Dec 2012 02:03:22 -0000	1.747
@@ -1,6 +1,12 @@
 # ChangeLog for sys-fs/udev
 # Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/sys-fs/udev/ChangeLog,v 1.746 2012/12/01 15:59:53 williamh Exp $
+# $Header: /var/cvsroot/gentoo-x86/sys-fs/udev/ChangeLog,v 1.747 2012/12/02 02:03:22 ssuominen Exp $
+
+*udev-196 (02 Dec 2012)
+
+  02 Dec 2012; Samuli Suominen <ssuominen@g.o> +udev-196.ebuild,
+  udev-9999.ebuild:
+  Version bump.
 
   01 Dec 2012; William Hubbs <williamh@g.o> -udev-189.ebuild,
   -udev-190.ebuild, -udev-191.ebuild, -udev-192.ebuild, -udev-193.ebuild,



1.120                sys-fs/udev/udev-9999.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-fs/udev/udev-9999.ebuild?rev=1.120&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-fs/udev/udev-9999.ebuild?rev=1.120&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-fs/udev/udev-9999.ebuild?r1=1.119&r2=1.120

Index: udev-9999.ebuild
===================================================================
RCS file: /var/cvsroot/gentoo-x86/sys-fs/udev/udev-9999.ebuild,v
retrieving revision 1.119
retrieving revision 1.120
diff -u -r1.119 -r1.120
--- udev-9999.ebuild	29 Nov 2012 23:16:08 -0000	1.119
+++ udev-9999.ebuild	2 Dec 2012 02:03:22 -0000	1.120
@@ -1,6 +1,6 @@
 # Copyright 1999-2012 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/sys-fs/udev/udev-9999.ebuild,v 1.119 2012/11/29 23:16:08 williamh Exp $
+# $Header: /var/cvsroot/gentoo-x86/sys-fs/udev/udev-9999.ebuild,v 1.120 2012/12/02 02:03:22 ssuominen Exp $
 
 EAPI=4
 
@@ -28,23 +28,23 @@
 
 LICENSE="LGPL-2.1 MIT GPL-2"
 SLOT="0"
-IUSE="acl doc gudev hwdb introspection keymap +openrc selinux static-libs"
+IUSE="acl doc gudev introspection keymap +openrc selinux static-libs"
 
 RESTRICT="test"
 
-COMMON_DEPEND="acl? ( sys-apps/acl )
-	gudev? ( dev-libs/glib:2 )
+COMMON_DEPEND=">=sys-apps/kmod-11-r3
+	>=sys-apps/util-linux-2.20
+	acl? ( sys-apps/acl )
+	gudev? ( >=dev-libs/glib-2 )
 	introspection? ( >=dev-libs/gobject-introspection-1.31.1 )
 	selinux? ( sys-libs/libselinux )
-	>=sys-apps/kmod-5
-	>=sys-apps/util-linux-2.20
 	!<sys-libs/glibc-2.11"
 
 DEPEND="${COMMON_DEPEND}
 	dev-util/gperf
-	>=dev-util/intltool-0.40.0
-	virtual/pkgconfig
+	>=dev-util/intltool-0.50
 	virtual/os-headers
+	virtual/pkgconfig
 	!<sys-kernel/linux-headers-${KV_min}
 	doc? ( dev-util/gtk-doc )"
 
@@ -56,11 +56,9 @@
 fi
 
 RDEPEND="${COMMON_DEPEND}
-	hwdb? ( sys-apps/hwids )
 	openrc? ( >=sys-fs/udev-init-scripts-16
 		!<sys-apps/openrc-0.9.9 )
 	!sys-apps/coldplug
-	!=sys-apps/systemd-188
 	!<sys-fs/lvm2-2.02.45
 	!sys-fs/device-mapper
 	!<sys-fs/udev-init-scripts-16
@@ -69,7 +67,7 @@
 
 PDEPEND=">=virtual/udev-180"
 
-S="${WORKDIR}/systemd-${PV}"
+S=${WORKDIR}/systemd-${PV}
 
 QA_MULTILIB_PATHS="usr/lib/systemd/systemd-udevd"
 
@@ -86,8 +84,8 @@
 {
 	# Make sure there are no sudden changes to upstream rules file
 	# (more for my own needs than anything else ...)
-	local udev_rules_md5=f742230cf0c2075adfba9e6b517c7095
-	MD5=$(md5sum < "${S}/rules/50-udev-default.rules")
+	local udev_rules_md5=66bb698deeae64ab444b710baf54a412
+	MD5=$(md5sum < "${S}"/rules/50-udev-default.rules)
 	MD5=${MD5/  -/}
 	if [[ ${MD5} != ${udev_rules_md5} ]]
 	then
@@ -164,10 +162,8 @@
 		--with-distro=gentoo
 		--with-firmware-path=/usr/lib/firmware/updates:/usr/lib/firmware:/lib/firmware/updates:/lib/firmware
 		--with-html-dir=/usr/share/doc/${PF}/html
-		--with-pci-ids-path=/usr/share/misc/pci.ids
 		--with-rootlibdir=/usr/$(get_libdir)
 		--with-rootprefix=/usr
-		--with-usb-ids-path=/usr/share/misc/usb.ids
 		--disable-audit
 		--disable-coredump
 		--disable-hostnamed
@@ -347,38 +343,8 @@
 			einfo "Removed unneeded file 64-device-mapper.rules"
 	fi
 
-	# http://bugs.gentoo.org/440462
-	if [[ ${REPLACING_VERSIONS} ]] && [[ ${REPLACING_VERSIONS} < 141 ]]; then
-		ewarn
-		ewarn "If you build an initramfs including udev, please make sure the"
-		ewarn "/usr/bin/udevadm binary gets included, Also, change your scripts to"
-		ewarn "use it, as it replaces the old udevinfo and udevtrigger helpers."
-
-		ewarn
-		ewarn "mount options for /dev are no longer set in /etc/udev/udev.conf."
-		ewarn "Instead, /etc/fstab should be used. This matches other mount points."
-	fi
-
-	if [[ ${REPLACING_VERSIONS} ]] && [[ ${REPLACING_VERSIONS} < 151 ]]; then
-		ewarn
-		ewarn "Rules for /dev/hd* devices have been removed."
-		ewarn "Please migrate to libata."
-	fi
-
 	if [[ ${REPLACING_VERSIONS} ]] && [[ ${REPLACING_VERSIONS} < 189 ]]; then
 		ewarn
-		ewarn "action_modeswitch has been removed by upstream."
-		ewarn "Please use sys-apps/usb_modeswitch."
-
-		if use acl; then
-			ewarn
-			ewarn "The udev-acl functionality has been moved."
-			ewarn "If you are not using systemd, this is handled by ConsoleKit."
-			ewarn "Otherwise, you need to make sure that systemd is emerged with"
-			ewarn "the acl use flag active."
-		fi
-
-		ewarn
 		ewarn "Upstream has removed the persistent-net and persistent-cd rules"
 		ewarn "generator. If you need persistent names for these devices,"
 		ewarn "place udev rules for them in ${ROOT}etc/udev/rules.d."



1.1                  sys-fs/udev/udev-196.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-fs/udev/udev-196.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-fs/udev/udev-196.ebuild?rev=1.1&content-type=text/plain

Index: udev-196.ebuild
===================================================================
# Copyright 1999-2012 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/sys-fs/udev/udev-196.ebuild,v 1.1 2012/12/02 02:03:22 ssuominen Exp $

EAPI=4

KV_min=2.6.39

inherit autotools eutils linux-info

if [[ ${PV} = 9999* ]]
then
	EGIT_REPO_URI="git://anongit.freedesktop.org/systemd/systemd"
	inherit git-2
else
	patchset=1
	SRC_URI="http://www.freedesktop.org/software/systemd/systemd-${PV}.tar.xz"
	if [[ -n "${patchset}" ]]
		then
				SRC_URI="${SRC_URI}
					mirror://gentoo/${PN}-195-patches-${patchset}.tar.bz2"
			fi
	KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86"
fi

DESCRIPTION="Linux dynamic and persistent device naming support (aka userspace devfs)"
HOMEPAGE="http://www.freedesktop.org/wiki/Software/systemd"

LICENSE="LGPL-2.1 MIT GPL-2"
SLOT="0"
IUSE="acl doc gudev introspection keymap +openrc selinux static-libs"

RESTRICT="test"

COMMON_DEPEND=">=sys-apps/kmod-11-r3
	>=sys-apps/util-linux-2.20
	acl? ( sys-apps/acl )
	gudev? ( >=dev-libs/glib-2 )
	introspection? ( >=dev-libs/gobject-introspection-1.31.1 )
	selinux? ( sys-libs/libselinux )
	!<sys-libs/glibc-2.11"

DEPEND="${COMMON_DEPEND}
	dev-util/gperf
	>=dev-util/intltool-0.50
	virtual/os-headers
	virtual/pkgconfig
	!<sys-kernel/linux-headers-${KV_min}
	doc? ( dev-util/gtk-doc )"

if [[ ${PV} = 9999* ]]
then
	DEPEND="${DEPEND}
		app-text/docbook-xsl-stylesheets
		dev-libs/libxslt"
fi

RDEPEND="${COMMON_DEPEND}
	openrc? ( >=sys-fs/udev-init-scripts-16
		!<sys-apps/openrc-0.9.9 )
	!sys-apps/coldplug
	!<sys-fs/lvm2-2.02.45
	!sys-fs/device-mapper
	!<sys-fs/udev-init-scripts-16
	!<sys-kernel/dracut-017-r1
	!<sys-kernel/genkernel-3.4.25"

PDEPEND=">=virtual/udev-180"

S=${WORKDIR}/systemd-${PV}

QA_MULTILIB_PATHS="usr/lib/systemd/systemd-udevd"

udev_check_KV()
{
	if kernel_is lt ${KV_min//./ }
	then
		return 1
	fi
	return 0
}

check_default_rules()
{
	# Make sure there are no sudden changes to upstream rules file
	# (more for my own needs than anything else ...)
	local udev_rules_md5=66bb698deeae64ab444b710baf54a412
	MD5=$(md5sum < "${S}"/rules/50-udev-default.rules)
	MD5=${MD5/  -/}
	if [[ ${MD5} != ${udev_rules_md5} ]]
	then
		eerror "50-udev-default.rules has been updated, please validate!"
		eerror "md5sum: ${MD5}"
		die "50-udev-default.rules has been updated, please validate!"
	fi
}

pkg_setup()
{
	# required kernel options
	CONFIG_CHECK="~DEVTMPFS"
	ERROR_DEVTMPFS="DEVTMPFS is not set in this kernel. Udev will not run."

	linux-info_pkg_setup

	if ! udev_check_KV
	then
		eerror "Your kernel version (${KV_FULL}) is too old to run ${P}"
		eerror "It must be at least ${KV_min}!"
	fi

	KV_FULL_SRC=${KV_FULL}
	get_running_version
	if ! udev_check_KV
	then
		eerror
		eerror "Your running kernel version (${KV_FULL}) is too old"
		eerror "for this version of udev."
		eerror "You must upgrade your kernel or downgrade udev."
	fi
}

src_prepare()
{
	# backport some patches
	if [[ -n "${patchset}" ]]
	then
		EPATCH_SUFFIX=patch EPATCH_FORCE=yes epatch
	fi

	# change rules back to group uucp instead of dialout for now
	sed -e 's/GROUP="dialout"/GROUP="uucp"/' \
		-i rules/*.rules \
	|| die "failed to change group dialout to uucp"

	if [[ ! -e configure ]]
	then
		if use doc
		then
			gtkdocize --docdir docs || die "gtkdocize failed"
		else
			echo 'EXTRA_DIST =' > docs/gtk-doc.make
		fi
		eautoreconf
	else
		check_default_rules
		elibtoolize
	fi
}

src_configure()
{
	local econf_args

	econf_args=(
		ac_cv_search_cap_init=
		ac_cv_header_sys_capability_h=yes
		DBUS_CFLAGS=' '
		DBUS_LIBS=' '
		--docdir=/usr/share/doc/${PF}
		--libdir=/usr/$(get_libdir)
		--with-distro=gentoo
		--with-firmware-path=/usr/lib/firmware/updates:/usr/lib/firmware:/lib/firmware/updates:/lib/firmware
		--with-html-dir=/usr/share/doc/${PF}/html
		--with-rootlibdir=/usr/$(get_libdir)
		--with-rootprefix=/usr
		--disable-audit
		--disable-coredump
		--disable-hostnamed
		--disable-ima
		--disable-libcryptsetup
		--disable-localed
		--disable-logind
		--disable-nls
		--disable-pam
		--disable-quotacheck
		--disable-readahead
		--enable-split-usr
		--disable-tcpwrap
		--disable-timedated
		--disable-xz
		$(use_enable acl)
		$(use_enable doc gtk-doc)
		$(use_enable gudev)
		$(use_enable introspection)
		$(use_enable keymap)
		$(use_enable selinux)
		$(use_enable static-libs static)
	)
	econf "${econf_args[@]}"
}

src_compile()
{
	echo 'BUILT_SOURCES: $(BUILT_SOURCES)' > "${T}"/Makefile.extra
	emake -f Makefile -f "${T}"/Makefile.extra BUILT_SOURCES
	local targets=(
		systemd-udevd
		udevadm
		libudev.la
		ata_id
		cdrom_id
		collect
		scsi_id
		v4l_id
		accelerometer
		mtd_probe
		man/udev.7
		man/udevadm.8
		man/systemd-udevd.8
		man/systemd-udevd.service.8
	)
	use keymap && targets+=( keymap )
	use gudev && targets+=( libgudev-1.0.la )

	emake "${targets[@]}"
	if use doc
	then
		emake -C docs/libudev
		use gudev && emake -C docs/gudev
	fi
}

src_install()
{
	local lib_LTLIBRARIES=libudev.la \
		pkgconfiglib_DATA=src/libudev/libudev.pc

	local targets=(
		install-libLTLIBRARIES
		install-includeHEADERS
		install-libgudev_includeHEADERS
		install-binPROGRAMS
		install-rootlibexecPROGRAMS
		install-udevlibexecPROGRAMS
		install-dist_systemunitDATA
		install-dist_udevconfDATA
		install-dist_udevhomeSCRIPTS
		install-dist_udevkeymapDATA
		install-dist_udevkeymapforcerelDATA
		install-dist_udevrulesDATA
		install-girDATA
		install-man7
		install-man8
		install-nodist_systemunitDATA
		install-pkgconfiglibDATA
		install-sharepkgconfigDATA
		install-typelibsDATA
		install-dist_docDATA
		udev-confdirs
		systemd-install-hook
	)

	if use gudev
	then
		lib_LTLIBRARIES+=" libgudev-1.0.la"
		pkgconfiglib_DATA+=" src/gudev/gudev-1.0.pc"
	fi

	# add final values of variables:
	targets+=(
		rootlibexec_PROGRAMS=systemd-udevd
		bin_PROGRAMS=udevadm
		lib_LTLIBRARIES="${lib_LTLIBRARIES}"
		MANPAGES="man/udev.7 man/udevadm.8 man/systemd-udevd.service.8"
		MANPAGES_ALIAS="man/systemd-udevd.8"
		dist_systemunit_DATA="units/systemd-udevd-control.socket \
			units/systemd-udevd-kernel.socket"
		nodist_systemunit_DATA="units/systemd-udevd.service \
				units/systemd-udev-trigger.service \
				units/systemd-udev-settle.service"
		pkgconfiglib_DATA="${pkgconfiglib_DATA}"
	)
	emake DESTDIR="${D}" "${targets[@]}"
	if use doc
	then
		emake -C docs/libudev DESTDIR="${D}" install
		use gudev && emake -C docs/gudev DESTDIR="${D}" install
	fi
	dodoc TODO

	prune_libtool_files --all
	rm -f "${D}"/usr/lib/udev/rules.d/99-systemd.rules
	rm -rf "${D}"/usr/share/doc/${PF}/LICENSE.*

	# install gentoo-specific rules
	insinto /usr/lib/udev/rules.d
	doins "${FILESDIR}"/40-gentoo.rules

	# install udevadm symlink
	dosym ../usr/bin/udevadm /sbin/udevadm
}

pkg_preinst()
{
	local htmldir
	for htmldir in gudev libudev; do
		if [[ -d ${ROOT}usr/share/gtk-doc/html/${htmldir} ]]
		then
			rm -rf "${ROOT}"usr/share/gtk-doc/html/${htmldir}
		fi
		if [[ -d ${D}/usr/share/doc/${PF}/html/${htmldir} ]]
		then
			dosym ../../doc/${PF}/html/${htmldir} \
				/usr/share/gtk-doc/html/${htmldir}
		fi
	done
	preserve_old_lib /$(get_libdir)/libudev.so.0
}

# This function determines if a directory is a mount point.
# It was lifted from dracut.
ismounted()
{
	while read a m a; do
		[[ $m = $1 ]] && return 0
	done < "${ROOT}"/proc/mounts
	return 1
}

pkg_postinst()
{
	mkdir -p "${ROOT}"/run

	# "losetup -f" is confused if there is an empty /dev/loop/, Bug #338766
	# So try to remove it here (will only work if empty).
	rmdir "${ROOT}"/dev/loop 2>/dev/null
	if [[ -d ${ROOT}/dev/loop ]]
	then
		ewarn "Please make sure your remove /dev/loop,"
		ewarn "else losetup may be confused when looking for unused devices."
	fi

	# people want reminders, I'll give them reminders.  Odds are they will
	# just ignore them anyway...

	# 64-device-mapper.rules now gets installed by sys-fs/device-mapper
	# remove it if user don't has sys-fs/device-mapper installed, 27 Jun 2007
	if [[ -f ${ROOT}/etc/udev/rules.d/64-device-mapper.rules ]] &&
		! has_version sys-fs/device-mapper
	then
			rm -f "${ROOT}"/etc/udev/rules.d/64-device-mapper.rules
			einfo "Removed unneeded file 64-device-mapper.rules"
	fi

	if [[ ${REPLACING_VERSIONS} ]] && [[ ${REPLACING_VERSIONS} < 189 ]]; then
		ewarn
		ewarn "Upstream has removed the persistent-net and persistent-cd rules"
		ewarn "generator. If you need persistent names for these devices,"
		ewarn "place udev rules for them in ${ROOT}etc/udev/rules.d."
		ewarn "Be aware that you cannot directly swap device names, so persistent"
		ewarn "rules for network devices should be like the ones at the following"
		ewarn "URL:"
		ewarn "http://bugs.gentoo.org/show_bug.cgi?id=433746#c1"
	fi

	if ismounted /usr
	then
		ewarn
		ewarn "Your system has /usr on a separate partition. This means"
		ewarn "you will need to use an initramfs to pre-mount /usr before"
		ewarn "udev runs."
		ewarn "This must be set up before your next reboot, or you may"
		ewarn "experience failures which are very difficult to troubleshoot."
		ewarn "For a more detailed explanation, see the following URL:"
		ewarn "http://www.freedesktop.org/wiki/Software/systemd/separate-usr-is-broken"
		ewarn
		ewarn "For more information on setting up an initramfs, see the"
		ewarn "following URL:"
		ewarn "http://www.gentoo.org/doc/en/initramfs-guide.xml"
	fi

	if [[ -d ${ROOT}lib/udev ]]
	then
		ewarn
		ewarn "This version of udev moves the files which were installed in"
		ewarn "/lib/udev to /usr/lib/udev. We include a backward compatibility"
		ewarn "patch for gentoo to allow the rules in /lib/udev/rules.d to be"
		ewarn "read; however, bugs should be filed against packages which are"
		ewarn "installing things in /lib/udev so they can be fixed."
	fi

	ewarn
	ewarn "You need to restart udev as soon as possible to make the upgrade go"
	ewarn "into effect."
	ewarn "The method you use to do this depends on your init system."

	preserve_old_lib_notify /$(get_libdir)/libudev.so.0

	elog
	elog "For more information on udev on Gentoo, writing udev rules, and"
	elog "         fixing known issues visit:"
	elog "         http://www.gentoo.org/doc/en/udev-guide.xml"
}