[gentoo-commits] repo/gentoo:master commit in: dev-python/more-itertools/

[Ian Delaney]

commit:     34d71f577292207f33d3dd0dfab772ff525ec5e2
Author:     Ian Delaney <idella4 <AT> gentoo <DOT> org>
AuthorDate: Mon Dec 28 16:38:22 2015 +0000
Commit:     Ian Delaney <idella4 <AT> gentoo <DOT> org>
CommitDate: Mon Dec 28 16:39:09 2015 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=34d71f57

dev-python/more-itertools: revbump; add IUSE doc, test

working test phase added as well as a doc build and install,
deps for each added accordingly, patches and testing done thx to
user 'drwx' via devs of the proxy-maintainers project

Package-Manager: portage-2.2.24

 .../more-itertools/more-itertools-2.2-r1.ebuild    | 35 ++++++++++++++++++++++
 1 file changed, 35 insertions(+)

diff --git a/dev-python/more-itertools/more-itertools-2.2-r1.ebuild b/dev-python/more-itertools/more-itertools-2.2-r1.ebuild
new file mode 100644
index 0000000..7dd508d
--- /dev/null
+++ b/dev-python/more-itertools/more-itertools-2.2-r1.ebuild
@@ -0,0 +1,35 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+PYTHON_COMPAT=( python{2_7,3_3,3_4,3_5} )
+
+inherit distutils-r1
+
+DESCRIPTION="More routines for operating on iterables, beyond itertools"
+HOMEPAGE="https://pypi.python.org/pypi/more-itertools"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="doc test"
+
+DEPEND="dev-python/setuptools[${PYTHON_USEDEP}]
+		test? ( dev-python/nose[${PYTHON_USEDEP}] )
+		doc? ( dev-python/sphinx[${PYTHON_USEDEP}] )"
+
+python_compile_all() {
+	use doc && emake -C docs html
+}
+
+python_test() {
+	nosetests -w "${BUILD_DIR}" more_itertools --with-doctest \
+		|| die "tests fail with ${EPYTHON}"
+}
+
+python_install_all() {
+	use doc && local HTML_DOCS=( docs/_build/html/. )
+	distutils-r1_python_install_all
+}