[gentoo-commits] gentoo-x86 commit in kde-base/pykde: ChangeLog pykde-3.5.9.ebuild

[Wulf Krueger (philantrop)]

philantrop    08/02/20 23:34:38

  Modified:             ChangeLog
  Added:                pykde-3.5.9.ebuild
  Log:
  Version bump to KDE 3.5.9.
  (Portage version: 2.1.4.4)

Revision  Changes    Path
1.38                 kde-base/pykde/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/kde-base/pykde/ChangeLog?rev=1.38&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/kde-base/pykde/ChangeLog?rev=1.38&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/kde-base/pykde/ChangeLog?r1=1.37&r2=1.38

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/kde-base/pykde/ChangeLog,v
retrieving revision 1.37
retrieving revision 1.38
diff -u -r1.37 -r1.38
--- ChangeLog	17 Feb 2008 02:40:22 -0000	1.37
+++ ChangeLog	20 Feb 2008 23:34:37 -0000	1.38
@@ -1,6 +1,11 @@
 # ChangeLog for kde-base/pykde
 # Copyright 1999-2008 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/kde-base/pykde/ChangeLog,v 1.37 2008/02/17 02:40:22 ingmar Exp $
+# $Header: /var/cvsroot/gentoo-x86/kde-base/pykde/ChangeLog,v 1.38 2008/02/20 23:34:37 philantrop Exp $
+
+*pykde-3.5.9 (20 Feb 2008)
+
+  20 Feb 2008; Wulf C. Krueger <philantrop@g.o> +pykde-3.5.9.ebuild:
+  Version bump to KDE 3.5.9.
 
   16 Feb 2008; Ingmar Vanhassel <ingmar@g.o> -pykde-3.5.5-r1.ebuild,
   -pykde-3.5.6.ebuild:



1.1                  kde-base/pykde/pykde-3.5.9.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/kde-base/pykde/pykde-3.5.9.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/kde-base/pykde/pykde-3.5.9.ebuild?rev=1.1&content-type=text/plain

Index: pykde-3.5.9.ebuild
===================================================================
# Copyright 1999-2008 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/kde-base/pykde/pykde-3.5.9.ebuild,v 1.1 2008/02/20 23:34:37 philantrop Exp $

KMNAME=kdebindings
KMMODULE=python
KM_MAKEFILESREV=1

EAPI="1"
inherit kde-meta distutils

DESCRIPTION="PyKDE is a set of Python bindings for kdelibs."

SLOT="0"
LICENSE="GPL-2"
KEYWORDS="~amd64 ~ppc ~ppc64 ~x86"
IUSE="debug doc examples"

DEPEND="~dev-python/sip-4.6
	~dev-python/PyQt-3.17.2
	kde-base/kdelibs:3.5
	|| ( kde-base/kdebase:3.5 kde-base/konsole:3.5 )
	!dev-python/pykde"
RDEPEND="${DEPEND}"

src_unpack() {
	kde-meta_src_unpack
	cd "${S}/python/pykde"
	epatch "${FILESDIR}/${PN}-3.5.8-python-2.5-compat.diff"

	mkdir -p kparts
	ln -s "${PREFIX}"/$(get_libdir)/kde3/libkonsolepart* ./kparts/
}

src_compile() {
	cd "${S}/python/pykde"
	distutils_python_version

	local myconf="-d /usr/$(get_libdir)/python${PYVER}/site-packages \
			-v /usr/share/sip \
			-k $(kde-config --prefix)"

	use debug && myconf="${myconf} -u"
	myconf="${myconf} -i"

	python configure.py ${myconf} || die "configure failed"
	emake || die "emake failed"
}

src_install() {
	cd "${S}/python/pykde"
	dodir "${PREFIX}"/$(get_libdir)
	sed -i -e "s:/lib/:/$(get_libdir)/:g" Makefile

	for X in dcop kdecore kdefx kdeui kio kresources kabc kutils kfile kparts khtml kspell kdeprint kmdi ; do
		sed -i -e '/strip $(DESTDIR).*/d' ${X}/Makefile
	done

	emake DESTDIR="${D}" install || die "emake install failed"
	find "${D}/usr/share/sip" -not -type d -not -iname *.sip -delete

	dodoc AUTHORS ChangeLog NEWS README THANKS
	use doc && dohtml -r doc/*
	if use examples ; then
		cp -r examples "${D}/usr/share/doc/${PF}"
		cp -r templates "${D}/usr/share/doc/${PF}"
	fi
}



-- 
gentoo-commits@l.g.o mailing list