[gentoo-commits] gentoo-x86 commit in net-firewall/sanewall: ChangeLog sanewall-1.1.6-r1.ebuild

[Tim Harder (radhermit)]

radhermit    14/11/28 17:04:05

  Modified:             ChangeLog
  Added:                sanewall-1.1.6-r1.ebuild
  Log:
  Add support to pass sanewall arguments (bug #493860).
  
  (Portage version: 2.2.14/cvs/Linux x86_64, signed Manifest commit with key 4AB3E85B4F064CA3)

Revision  Changes    Path
1.5                  net-firewall/sanewall/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-firewall/sanewall/ChangeLog?rev=1.5&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-firewall/sanewall/ChangeLog?rev=1.5&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-firewall/sanewall/ChangeLog?r1=1.4&r2=1.5

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-firewall/sanewall/ChangeLog,v
retrieving revision 1.4
retrieving revision 1.5
diff -u -r1.4 -r1.5
--- ChangeLog	6 Nov 2013 06:00:14 -0000	1.4
+++ ChangeLog	28 Nov 2014 17:04:05 -0000	1.5
@@ -1,6 +1,12 @@
 # ChangeLog for net-firewall/sanewall
-# Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-firewall/sanewall/ChangeLog,v 1.4 2013/11/06 06:00:14 radhermit Exp $
+# Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/net-firewall/sanewall/ChangeLog,v 1.5 2014/11/28 17:04:05 radhermit Exp $
+
+*sanewall-1.1.6-r1 (28 Nov 2014)
+
+  28 Nov 2014; Tim Harder <radhermit@g.o> +sanewall-1.1.6-r1.ebuild,
+  files/sanewall.confd, files/sanewall.initd:
+  Add support to pass sanewall arguments (bug #493860).
 
 *sanewall-1.1.6 (06 Nov 2013)
 



1.1                  net-firewall/sanewall/sanewall-1.1.6-r1.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-firewall/sanewall/sanewall-1.1.6-r1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-firewall/sanewall/sanewall-1.1.6-r1.ebuild?rev=1.1&content-type=text/plain

Index: sanewall-1.1.6-r1.ebuild
===================================================================
# Copyright 1999-2014 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-firewall/sanewall/sanewall-1.1.6-r1.ebuild,v 1.1 2014/11/28 17:04:05 radhermit Exp $

EAPI=5

inherit linux-info

DESCRIPTION="iptables firewall generator (fork of firehol)"
HOMEPAGE="http://www.sanewall.org/"
SRC_URI="http://download.sanewall.org/releases/${PV}/${P}.tar.xz"

LICENSE="GPL-2+"
SLOT="0"
KEYWORDS="~amd64 ~x86"

DEPEND="app-arch/xz-utils"
RDEPEND="net-firewall/iptables[ipv6]
	sys-apps/iproute2[-minimal]
	virtual/modutils
	|| (
		net-misc/wget
		net-misc/curl
	)"

pkg_setup() {
	local KCONFIG_OPTS="~NF_CONNTRACK_IPV4 ~NF_CONNTRACK_MARK ~NF_NAT ~NF_NAT_FTP ~NF_NAT_IRC \
		~IP_NF_IPTABLES ~IP_NF_FILTER ~IP_NF_TARGET_REJECT ~IP_NF_TARGET_LOG ~IP_NF_TARGET_ULOG \
		~IP_NF_TARGET_MASQUERADE ~IP_NF_TARGET_REDIRECT ~IP_NF_MANGLE \
		~NETFILTER_XT_MATCH_LIMIT ~NETFILTER_XT_MATCH_STATE ~NETFILTER_XT_MATCH_OWNER"

	get_version
	if [[ ${KV_PATCH} -ge 25 ]] ; then
		CONFIG_CHECK="~NF_CONNTRACK ${KCONFIG_OPTS}"
	else
		CONFIG_CHECK="~NF_CONNTRACK_ENABLED ${KCONFIG_OPTS}"
	fi
	linux-info_pkg_setup
}

src_configure() {
	econf --docdir="/usr/share/doc/${PF}"
}

src_install() {
	default
	newconfd "${FILESDIR}"/${PN}.confd ${PN}
	newinitd "${FILESDIR}"/${PN}.initd ${PN}
}

pkg_postinst() {
	# install default configuration if it doesn't exist
	if [[ ! -e "${ROOT}"/etc/${PN}/${PN}.conf ]] ; then
		einfo "Installing a sample configuration to ${ROOT}/etc/${PN}/${PN}.conf"
		cp "${ROOT}"/etc/${PN}/${PN}.conf.example "${ROOT}"/etc/${PN}/${PN}.conf || die
	fi
}