[gentoo-commits] repo/gentoo:master commit in: net-im/dino/

[Andrey Utkin]

commit:     55ea7779a881567b8080577759683760cbe8295a
Author:     Andrey Utkin <andrey_utkin <AT> gentoo <DOT> org>
AuthorDate: Wed Oct 13 13:35:20 2021 +0000
Commit:     Andrey Utkin <andrey_utkin <AT> gentoo <DOT> org>
CommitDate: Wed Oct 13 16:22:04 2021 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=55ea7779

net-im/dino: add new version 0.2.2

Upstream release tag says

> Maintenance release for GTK+ 3.24.30 support and bug fixes.

Package-Manager: Portage-3.0.20, Repoman-3.0.3
Signed-off-by: Andrey Utkin <andrey_utkin <AT> gentoo.org>

 net-im/dino/Manifest          |  1 +
 net-im/dino/dino-0.2.2.ebuild | 79 +++++++++++++++++++++++++++++++++++++++++++
 2 files changed, 80 insertions(+)

diff --git a/net-im/dino/Manifest b/net-im/dino/Manifest
index ba33a251e4d..800169e77e5 100644
--- a/net-im/dino/Manifest
+++ b/net-im/dino/Manifest
@@ -1 +1,2 @@
 DIST dino-0.2.1.tar.gz 514504 BLAKE2B 42fae18bb7cda276c1eadeefdea130069f9929dfde62855f00ab6b88912fe9db3374315f40ff8f53350cf38e45fe61b0fd6256ef390cdbed6a65a3f2d79ac80a SHA512 b71497ec115945eadf7d33bb973f68465a20284aa75f37f1ae25fc30c1c423ce28cb10f7e9123c47f82e77e97170b8fa72c75389dacc3a2aa3d487a9c9610d49
+DIST dino-0.2.2.tar.gz 514648 BLAKE2B 54110f3767b5d1d3d4bffc82b767d3c92114c55449ad10705ed10b8815ecc9c337016348886acc3df21d5f27be5d93bbe3c203173167146ff9859bd03f0be7a6 SHA512 6c973b0b88e2c8aecbab694b456762973c5f60217bbf6bc81f4d81226fe8124596bddfe7c190f35307ec3ad6376858ce8f686c74aaebec133124377d8a9e4898

diff --git a/net-im/dino/dino-0.2.2.ebuild b/net-im/dino/dino-0.2.2.ebuild
new file mode 100644
index 00000000000..169e9707eef
--- /dev/null
+++ b/net-im/dino/dino-0.2.2.ebuild
@@ -0,0 +1,79 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+CMAKE_MAKEFILE_GENERATOR="ninja"
+VALA_MIN_API_VERSION="0.34"
+inherit cmake vala xdg
+
+DESCRIPTION="Modern Jabber/XMPP Client using GTK+/Vala"
+HOMEPAGE="https://dino.im"
+
+LICENSE="GPL-3"
+SLOT="0"
+IUSE="+gpg +http +omemo +notification-sound test"
+RESTRICT="!test? ( test )"
+
+MY_REPO_URI="https://github.com/dino/dino"
+if [[ ${PV} == "9999" ]]; then
+	EGIT_REPO_URI="${MY_REPO_URI}.git"
+	inherit git-r3
+else
+	KEYWORDS="~amd64 ~arm64"
+	SRC_URI="${MY_REPO_URI}/releases/download/v${PV}/${P}.tar.gz"
+fi
+
+RDEPEND="
+	app-text/gspell[vala]
+	dev-db/sqlite:3
+	dev-libs/glib:2
+	dev-libs/icu
+	dev-libs/libgee:0.8
+	net-libs/glib-networking
+	net-libs/libsignal-protocol-c
+	x11-libs/cairo
+	x11-libs/gdk-pixbuf:2
+	x11-libs/gtk+:3
+	x11-libs/pango
+	gpg? ( app-crypt/gpgme:1 )
+	http? ( net-libs/libsoup:2.4 )
+	omemo? (
+		dev-libs/libgcrypt:0
+		media-gfx/qrencode
+	)
+	notification-sound? ( media-libs/libcanberra:0[sound] )
+"
+DEPEND="
+	$(vala_depend)
+	${RDEPEND}
+	sys-devel/gettext
+"
+
+src_prepare() {
+	cmake_src_prepare
+	vala_src_prepare
+}
+
+src_configure() {
+	local disabled_plugins=(
+		$(usex gpg "" "openpgp")
+		$(usex omemo "" "omemo")
+		$(usex http  "" "http-files")
+	)
+	local enabled_plugins=(
+		$(usex notification-sound "notification-sound" "")
+	)
+	local mycmakeargs+=(
+		"-DENABLED_PLUGINS=$(local IFS=";"; echo "${enabled_plugins[*]}")"
+		"-DDISABLED_PLUGINS=$(local IFS=";"; echo "${disabled_plugins[*]}")"
+		"-DVALA_EXECUTABLE=${VALAC}"
+		"-DBUILD_TESTS=$(usex test)"
+	)
+
+	cmake_src_configure
+}
+
+src_test() {
+	"${BUILD_DIR}"/xmpp-vala-test || die
+}