[gentoo-commits] repo/gentoo:master commit in: dev-util/diffoscope/

[Sam James]

commit:     13528f9ad215f461802f832277ec64ed146276c3
Author:     Sam James <sam <AT> gentoo <DOT> org>
AuthorDate: Sat May 28 05:59:18 2022 +0000
Commit:     Sam James <sam <AT> gentoo <DOT> org>
CommitDate: Sat May 28 05:59:18 2022 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=13528f9a

dev-util/diffoscope: add 214

Signed-off-by: Sam James <sam <AT> gentoo.org>

 dev-util/diffoscope/Manifest              |   1 +
 dev-util/diffoscope/diffoscope-214.ebuild | 108 ++++++++++++++++++++++++++++++
 2 files changed, 109 insertions(+)

diff --git a/dev-util/diffoscope/Manifest b/dev-util/diffoscope/Manifest
index d0dd9cf0db64..a124aa8c97b5 100644
--- a/dev-util/diffoscope/Manifest
+++ b/dev-util/diffoscope/Manifest
@@ -2,3 +2,4 @@ DIST diffoscope-207.tar.gz 2707223 BLAKE2B e20f21c9e0acc78cadfce082f874b3e3cbbbd
 DIST diffoscope-210.tar.gz 2709384 BLAKE2B 86b88dacf1d777bc63f7698197bc26abe638a25857fa43eac48051b91c07699d7beb9c0ac6bef6baf23fda895a07ca69342c9469a1853a38276f93fac11ea8fa SHA512 b0bd05ffb6112f5f6cdd7f9567ecbbda286226cc6874dfdded39b5d7221d2dbab4b01f02741f7e10a219bf03f94bc803c651963deebb67308a134b8e97fb3b05
 DIST diffoscope-211.tar.gz 2709392 BLAKE2B c3570f88bcca7193a9650d970f2d943ebe33cc428c5ce3d4c5812588cbb57ae83dd795674e364d5acbb2d1504bd218036a6b04d9431786668386f28bdd6939b7 SHA512 8d674f41e955bd7537ba0cf7df0c886ff87b017a7d756246a183d9ec5ac3b286a798d60d29aadda550de6838b264a9e27fb37cf472b6e93caab7fce2fb65a1b1
 DIST diffoscope-212.tar.gz 2710499 BLAKE2B b941e16ab4520998ddfc039f1d68cc28f60415a1d9adc462651598b0e009cfcb9c5247f05be959a4a044647823b1a4987e6a40d1c1811ba039e67056b833fa8e SHA512 85dfc4dc4fc3bf78432de1782800db5c94a0d9d1d8369071cd2cfce0b0352cfbe51c4746bb2073ade47237911f08b86a2bb22529e13c19e91935c0126e2aadb8
+DIST diffoscope-214.tar.gz 2710707 BLAKE2B 6acd7fa9c69ad831c6d362b805c2094b2f55d57fa87f69e9e153a99a71c90a67884796696df0d24d6b3c94c0b9a41736292d44208f4d8de4262eaa5f2eec6c90 SHA512 67a9b68ce5f7934747e30e41506d7e30f018673314b777ab86af89e3dd56212c442abe6e246741f7b842b5c58f14006442167cf9089823ba4ef1ba07e78eaaa7

diff --git a/dev-util/diffoscope/diffoscope-214.ebuild b/dev-util/diffoscope/diffoscope-214.ebuild
new file mode 100644
index 000000000000..154291db075f
--- /dev/null
+++ b/dev-util/diffoscope/diffoscope-214.ebuild
@@ -0,0 +1,108 @@
+# Copyright 2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{8..10} )
+PYTHON_REQ_USE="ncurses"
+inherit distutils-r1
+
+DESCRIPTION="Will try to get to the bottom of what makes files or directories different"
+HOMEPAGE="https://diffoscope.org/ https://pypi.org/project/diffoscope/"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="GPL-3+"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc64 ~x86"
+IUSE="acl binutils bzip2 libcaca colord cpio +diff docx dtc e2fsprogs file
+find gettext gif gpg haskell hdf5 hex imagemagick iso java llvm lzma
+mono opendocument pascal pdf postscript R rpm sqlite squashfs
+ssh tar test tcpdump zip zlib zstd"
+
+RESTRICT="!test? ( test )"
+
+# pull in optional tools for tests:
+# img2txt: bug #797688
+# docx2txt: bug #797688
+BDEPEND="test? (
+		app-text/docx2txt
+		media-libs/libcaca
+		virtual/imagemagick-tools[jpeg]
+	)"
+RDEPEND="dev-python/python-magic[${PYTHON_USEDEP}]
+	dev-python/libarchive-c[${PYTHON_USEDEP}]
+	dev-python/distro[${PYTHON_USEDEP}]
+	acl? ( sys-apps/acl )
+	binutils? ( sys-devel/binutils )
+	bzip2? ( app-arch/bzip2 )
+	libcaca? ( media-libs/libcaca )
+	colord? ( x11-misc/colord )
+	cpio? ( app-arch/cpio )
+	diff? ( sys-apps/diffutils )
+	docx? ( app-text/docx2txt )
+	dtc? ( sys-apps/dtc )
+	e2fsprogs? ( sys-fs/e2fsprogs )
+	file? ( sys-apps/file )
+	find? ( sys-apps/findutils )
+	gettext? ( sys-devel/gettext )
+	gif? ( media-libs/giflib )
+	gpg? ( app-crypt/gnupg )
+	haskell? ( dev-lang/ghc )
+	hdf5? ( sci-libs/hdf5 )
+	hex? ( app-editors/vim-core )
+	imagemagick? ( media-gfx/imagemagick )
+	iso? ( app-cdr/cdrtools )
+	java? ( virtual/jdk )
+	llvm? ( sys-devel/llvm )
+	lzma? ( app-arch/xz-utils )
+	mono? ( dev-lang/mono )
+	opendocument? ( app-text/odt2txt )
+	pascal? ( dev-lang/fpc )
+	pdf? (
+		app-text/pdftk
+		app-text/poppler
+		dev-python/PyPDF2[${PYTHON_USEDEP}]
+	)
+	postscript? ( app-text/ghostscript-gpl )
+	R? ( dev-lang/R )
+	rpm? ( app-arch/rpm )
+	sqlite? ( dev-db/sqlite:3 )
+	squashfs? ( sys-fs/squashfs-tools )
+	ssh? ( net-misc/openssh )
+	tar? ( app-arch/tar )
+	tcpdump? ( net-analyzer/tcpdump )
+	zip? ( app-arch/unzip )
+	zlib? ( app-arch/gzip )
+	zstd? ( app-arch/zstd )
+"
+# Presence if filemagic's magic.py breaks imports
+# of dev-python/python-magic: https://bugs.gentoo.org/716482
+RDEPEND+=" !dev-python/filemagic"
+
+EPYTEST_DESELECT=(
+	# Test seems to use different tarball
+	tests/test_presenters.py::test_text_proper_indentation
+
+	# Needs triage
+	tests/comparators/test_binary.py::test_with_compare_details_and_tool_not_found
+	tests/comparators/test_rlib.py::test_item3_deflate_llvm_bitcode
+
+	# img2txt based failures, bug #797688
+	tests/comparators/test_ico_image.py::test_diff
+	tests/comparators/test_ico_image.py::test_diff_meta
+	tests/comparators/test_ico_image.py::test_diff_meta2
+	tests/comparators/test_ico_image.py::test_has_visuals
+	tests/comparators/test_jpeg_image.py::test_diff
+	tests/comparators/test_jpeg_image.py::test_compare_non_existing
+	tests/comparators/test_jpeg_image.py::test_diff_meta
+	tests/comparators/test_jpeg_image.py::test_has_visuals
+
+	# docx2txt based falures, bug #797688
+	tests/comparators/test_docx.py::test_diff
+
+	# Formatting
+	tests/test_source.py::test_code_is_black_clean
+)
+
+distutils_enable_tests pytest