[gentoo-commits] gentoo-x86 commit in sys-boot/aboot: ChangeLog aboot-1.0_pre20040408-r3.ebuild aboot-1.0_pre20040408-r1.ebuild aboot-1.0_pre20040408.ebuild aboot-0.9-r1.ebuild

[Raul Porcel (armin76)]

armin76     10/04/04 13:50:52

  Modified:             ChangeLog
  Added:                aboot-1.0_pre20040408-r3.ebuild
  Removed:              aboot-1.0_pre20040408-r1.ebuild
                        aboot-1.0_pre20040408.ebuild aboot-0.9-r1.ebuild
  Log:
  Revision bump to add a modified Debian patch to add netboot support
  (Portage version: 2.1.7.17/cvs/Linux ia64)

Revision  Changes    Path
1.15                 sys-boot/aboot/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/sys-boot/aboot/ChangeLog?rev=1.15&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/sys-boot/aboot/ChangeLog?rev=1.15&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/sys-boot/aboot/ChangeLog?r1=1.14&r2=1.15

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/sys-boot/aboot/ChangeLog,v
retrieving revision 1.14
retrieving revision 1.15
diff -u -r1.14 -r1.15
--- ChangeLog	23 Sep 2009 20:29:43 -0000	1.14
+++ ChangeLog	4 Apr 2010 13:50:52 -0000	1.15
@@ -1,6 +1,13 @@
 # ChangeLog for sys-boot/aboot
-# Copyright 1999-2009 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/sys-boot/aboot/ChangeLog,v 1.14 2009/09/23 20:29:43 patrick Exp $
+# Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/sys-boot/aboot/ChangeLog,v 1.15 2010/04/04 13:50:52 armin76 Exp $
+
+*aboot-1.0_pre20040408-r3 (04 Apr 2010)
+
+  04 Apr 2010; Raúl Porcel <armin76@g.o> -aboot-0.9-r1.ebuild,
+  -aboot-1.0_pre20040408.ebuild, -aboot-1.0_pre20040408-r1.ebuild,
+  +aboot-1.0_pre20040408-r3.ebuild:
+  Revision bump to add a modified Debian patch to add netboot support
 
   23 Sep 2009; Patrick Lauer <patrick@g.o> aboot-0.9-r1.ebuild,
   aboot-1.0_pre20040408.ebuild:



1.1                  sys-boot/aboot/aboot-1.0_pre20040408-r3.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/sys-boot/aboot/aboot-1.0_pre20040408-r3.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/sys-boot/aboot/aboot-1.0_pre20040408-r3.ebuild?rev=1.1&content-type=text/plain

Index: aboot-1.0_pre20040408-r3.ebuild
===================================================================
# Copyright 1999-2010 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/sys-boot/aboot/aboot-1.0_pre20040408-r3.ebuild,v 1.1 2010/04/04 13:50:52 armin76 Exp $

inherit eutils

KERN_VER="2.6.22"

DESCRIPTION="Alpha Linux boot loader for SRM"
HOMEPAGE="http://aboot.sourceforge.net/"
SRC_URI="http://aboot.sourceforge.net/tarballs/${P}.tar.bz2
	mirror://gentoo/gentoo-headers-base-${KERN_VER}.tar.bz2
	mirror://gentoo/${PN}_gentoo.diff.bz2
	http://dev.gentoo.org/~armin76/dist/${PN}_gentoo.diff.bz2"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="-* ~alpha"
IUSE=""

DEPEND=""
PROVIDE="virtual/bootloader"

src_unpack() {
	unpack ${A}
	# setup local copies of kernel headers since we rely so
	# heavily on linux internals.
	mv gentoo-headers-base-${KERN_VER}/include/{linux,asm-generic,asm-alpha} "${S}"/include/ || die
	cd "${S}"/include
	ln -s asm-alpha asm || die
	touch linux/config.h || die
	cd "${S}"
	epatch "${FILESDIR}/aboot-gcc-3.4.patch"
	epatch "${FILESDIR}/aboot-pt_note.patch"
	# Modified patch from Debian to add netboot support
	epatch "${WORKDIR}"/aboot_gentoo.diff
}

src_compile() {
	# too many problems with parallel building
	emake -j1 || die "emake failed"
}

src_install() {
	dodir /boot /sbin /usr/share/man/man{1,5,8}
	make \
		root="${D}" \
		bindir="${D}"/sbin \
		bootdir="${D}"/boot \
		mandir="${D}"/usr/share/man \
		install

	insinto /boot
	doins net_aboot.nh
	dobin netabootwrap
	dodoc ChangeLog INSTALL README TODO aboot.conf

	insinto /etc
	newins "${FILESDIR}"/aboot.conf aboot.conf.example

}

pkg_postinst() {
	einfo "To make aboot install a new bootloader on your harddisk follow"
	einfo "these steps:"
	einfo ""
	einfo " - edit the file /etc/aboot.conf"
	einfo " - cd /boot"
	einfo " - swriteboot -c2 /dev/sda bootlx"
	einfo " This will install a new bootsector on /dev/sda and aboot will"
	einfo " use the second partition on this device to lookup kernel and "
	einfo " initrd (as described in the aboot.conf file)"
	einfo ""
	einfo "IMPORTANT :"
	einfo ""
	einfo "The partition table of your boot device has to contain "
	einfo "a BSD-DISKLABEL and the first 12 megabytes of your boot device"
	einfo "must not be part of a partition as aboot will write its bootloader"
	einfo "in there and not as with most x86 bootloaders into the "
	einfo "master boot sector. If your partition table does not reflect this"
	einfo "you are going to destroy your installation !"
	einfo "Also note that aboot currently only supports ext2/3 partitions"
	einfo "to boot from."
}