[gentoo-commits] gentoo-x86 commit in dev-util/mingw-runtime: mingw-runtime-4.0.3.1.ebuild ChangeLog

[Mike Frysinger (vapier)]

vapier      14/06/02 04:36:03

  Modified:             ChangeLog
  Added:                mingw-runtime-4.0.3.1.ebuild
  Log:
  Version bump #511490 by Yevgeny Filatov.
  
  (Portage version: 2.2.10/cvs/Linux x86_64, signed Manifest commit with key D2E96200)

Revision  Changes    Path
1.29                 dev-util/mingw-runtime/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-util/mingw-runtime/ChangeLog?rev=1.29&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-util/mingw-runtime/ChangeLog?rev=1.29&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-util/mingw-runtime/ChangeLog?r1=1.28&r2=1.29

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/dev-util/mingw-runtime/ChangeLog,v
retrieving revision 1.28
retrieving revision 1.29
diff -u -r1.28 -r1.29
--- ChangeLog	10 May 2013 09:38:39 -0000	1.28
+++ ChangeLog	2 Jun 2014 04:36:03 -0000	1.29
@@ -1,6 +1,11 @@
 # ChangeLog for dev-util/mingw-runtime
-# Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-util/mingw-runtime/ChangeLog,v 1.28 2013/05/10 09:38:39 patrick Exp $
+# Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/dev-util/mingw-runtime/ChangeLog,v 1.29 2014/06/02 04:36:03 vapier Exp $
+
+*mingw-runtime-4.0.3.1 (02 Jun 2014)
+
+  02 Jun 2014; Mike Frysinger <vapier@g.o> +mingw-runtime-4.0.3.1.ebuild:
+  Version bump #511490 by Yevgeny Filatov.
 
   10 May 2013; Patrick Lauer <patrick@g.o> mingw-runtime-3.18.ebuild,
   mingw-runtime-3.20.2.ebuild, mingw-runtime-3.20.ebuild:



1.1                  dev-util/mingw-runtime/mingw-runtime-4.0.3.1.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-util/mingw-runtime/mingw-runtime-4.0.3.1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-util/mingw-runtime/mingw-runtime-4.0.3.1.ebuild?rev=1.1&content-type=text/plain

Index: mingw-runtime-4.0.3.1.ebuild
===================================================================
# Copyright 1999-2014 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-util/mingw-runtime/mingw-runtime-4.0.3.1.ebuild,v 1.1 2014/06/02 04:36:03 vapier Exp $

EAPI="4"

export CBUILD=${CBUILD:-${CHOST}}
export CTARGET=${CTARGET:-${CHOST}}
if [[ ${CTARGET} == ${CHOST} ]] ; then
	if [[ ${CATEGORY/cross-} != ${CATEGORY} ]] ; then
		export CTARGET=${CATEGORY/cross-}
	fi
fi

inherit flag-o-matic toolchain-funcs versionator

MY_P="mingwrt-$(version_format_string '$1.$2.$3-$4')-mingw32"
DESCRIPTION="Free Win32 runtime and import library definitions"
HOMEPAGE="http://www.mingw.org/"
# http://sourceforge.net/projects/mingw/files/MinGW/Base/mingw-rt/
SRC_URI="mirror://sourceforge/mingw/${MY_P}-src.tar.lzma"

LICENSE="BSD"
SLOT="0"
# Collides with w32api-4.x
#KEYWORDS="~amd64 ~ppc ~sparc ~x86"
IUSE="crosscompile_opts_headers-only"
RESTRICT="strip"

DEPEND="app-arch/xz-utils"
RDEPEND=""

S=${WORKDIR}/${MY_P}-src

is_crosscompile() {
	[[ ${CHOST} != ${CTARGET} ]]
}
just_headers() {
	use crosscompile_opts_headers-only && [[ ${CHOST} != ${CTARGET} ]]
}

pkg_setup() {
	if [[ ${CBUILD} == ${CHOST} ]] && [[ ${CHOST} == ${CTARGET} ]] ; then
		die "Invalid configuration"
	fi
}

src_prepare() {
	sed -i \
		-e '/^install_dlls_host:/s:$: install-dirs:' \
		Makefile.in || die # fix parallel install
}

src_configure() {
	just_headers && return 0

	CHOST=${CTARGET} strip-unsupported-flags
	filter-flags -frecord-gcc-switches
	tc-export AR
	econf \
		--host=${CTARGET} \
		--docdir="${EPREFIX}/usr/share/doc/${PF}"
}

src_compile() {
	emake -j1
}

src_install() {
	if just_headers ; then
		insinto /usr/${CTARGET}/usr/include
		doins -r include/*
	else
		local insdir
		is_crosscompile \
			&& insdir="${D}/usr/${CTARGET}" \
			|| insdir="${D}"
		emake -j1 install DESTDIR="${insdir}"
		env -uRESTRICT CHOST=${CTARGET} prepallstrip
		rm -rf "${insdir}"/usr/doc
		docinto ${CTARGET} # Avoid collisions with other cross-compilers.
	fi
	is_crosscompile && dosym usr /usr/${CTARGET}/mingw
}